hobbit-plugins 20141201 / usr / lib / xymon / client / ext / backuppc

#!/usr/bin/perl -w

# a Hobbit/Xymon plugin to check the status of BackupPC
#
# Based on http://n-backuppc.cvs.sf.net/viewvc/n-backuppc/check_backuppc/check_backuppc?revision=1.21
#
# Tested against BackupPC 2.1.2 and 3.1.0
#   <http://backuppc.sourceforge.net>
#
# Copyright (C) 2006, 2007 Seneca Cunningham <tetragon@users.sourceforge.net>
# Copyright (C) 2011 Axel Beckert <abe@debian.org>
#
#   This program is free software; you can redistribute it and/or modify
#   it under the terms of the GNU General Public License as published by
#   the Free Software Foundation; either version 2 of the License, or
#   (at your option) any later version.
#
#   This program is distributed in the hope that it will be useful,
#   but WITHOUT ANY WARRANTY; without even the implied warranty of
#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#   GNU General Public License for more details.
#
#   You should have received a copy of the GNU General Public License
#   along with this program; if not, write to the Free Software
#   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
#

my $config = "/etc/backuppc/TODO";
use strict;
use lib '/usr/share/backuppc/lib/';
use BackupPC::Lib;
use Hobbit;

$ENV{'PATH'} = '/bin:/sbin:/usr/bin:/usr/sbin';
$ENV{'LC_ALL'} = 'C';
delete @ENV{'IFS', 'CDPATH', 'ENV', 'BASH_ENV'};

my $bb = new Hobbit({ test => 'bkpc', dont_moan => 1});

#no utf8;

my %ERRORS = ( OK => 0,
	       UNKNOWN => 1,
	       WARNING => 1,
	       CRITICAL => 2 );

use POSIX qw(strftime difftime);
use Getopt::Long;
Getopt::Long::Configure('bundling');

# BackupPC
my $version = '1.1.0';
my $warnLevel = 0;
my $daysOld = 7;
my $verbose = 1;
my $opt_V = 0;
my $opt_h = 0;
my $goodOpt = 0;
my $reduce = 0;
my $backupOnly = 0;
my $archiveOnly = 0;
my $statusOnly = 0;
my @hostsDesired;
my @hostsExcluded;

# Process options
$goodOpt = GetOptions(
	'v+' => \$verbose, 'verbose+' => \$verbose,
	'c=f' => \$daysOld, 'critical=f' => \$daysOld,
	'w=f' => \$warnLevel, 'warning=f' => \$warnLevel,
	'V' => \$opt_V, 'version' => \$opt_V,
	'h' => \$opt_h, 'help' => \$opt_h,
	'r=i' => \$reduce, 'reduce' => \$reduce,
	'b' => \$backupOnly, 'backup-only' => \$backupOnly,
	'a' => \$archiveOnly, 'archive-only' => \$archiveOnly,
	's' => \$statusOnly, 'status-only' => \$statusOnly,
	'H=s' => \@hostsDesired, 'hostname=s' => \@hostsDesired,
	'x=s' => \@hostsExcluded, 'exclude=s' => \@hostsExcluded);

@hostsDesired = () if $#hostsDesired < 0;
@hostsExcluded = () if $#hostsExcluded < 0;

if ($opt_V)
{
	print "check_backuppc - " . $version . "\n";
	exit $ERRORS{'OK'};
}
if ($backupOnly and $archiveOnly)
{
	$goodOpt = 0;
	print "Cannot apply both --backup-only and --archive-only, contradictory\n\n";
}
if ($opt_h or not $goodOpt)
{
	print "check_backuppc - " . $version . "\n";
	print "A Hobbit plugin to check on BackupPC backup status.\n\n";
	print "Options:\n";
	print "  --hostname,-H      only check the specified host\n";
	print "  --exclude,-x       do not check the specified host\n";
	print "  --archive-only,-a  only check the archive hosts\n";
	print "  --backup-only,-b   only check the backup hosts\n";
	print "  --status-only,-s   only check backup status, omit connection failures that are\n";
	print "                     less than \$Conf{FullPeriod} old\n";
	print "  --warning,-w       days old an errored host must be to cause a warning\n";
	print "  --critical,-c      number of days old an errored backup must be to be critical\n";
	print "  --reduce,-r        maximum number of failed hosts for severity reduction\n";
	print "  --verbose,-v       increase verbosity\n";
	print "  --version,-V       display plugin version\n";
	print "  --help,-h          display this message\n\n";
	exit $ERRORS{'OK'} if $goodOpt;
	exit $ERRORS{'UNKNOWN'};
}
if ($warnLevel > $daysOld)
{
	$bb->color_line('red', "CONFIGURATION ERROR - Warning threshold must be <= critical\n");
}

# Connect to BackupPC
my $server;
if (!($server = BackupPC::Lib->new))
{
	$bb->color_line('red', "Couldn't connect to BackupPC\n");
	$bb->send;
	exit $ERRORS{'CRITICAL'};
}
my %Conf = $server->Conf();

$server->ChildInit();

my $err = $server->ServerConnect($Conf{ServerHost}, $Conf{ServerPort});
if ($err)
{
	$bb->color_line('red', "Can't connect to server ($err)\n");
	$bb->send;
	exit $ERRORS{'UNKNOWN'};
}

# hashes that BackupPC uses for varios status info
my %Status;
my %Jobs;
my %Info;

# query the BackupPC server for host, job, and server info
my $info_raw = $server->ServerMesg('status info');
my $jobs_raw = $server->ServerMesg('status jobs');
my $status_raw = $server->ServerMesg('status hosts');

# undump the output... BackupPC uses Data::Dumper
eval $info_raw;
eval $jobs_raw;
eval $status_raw;

# check the dumped output
my $hostCount = 0;
my @goodHost;
my @badHost;
my @tooOld;
my @notTooOld;

# host status checks
foreach my $host (sort(keys(%Status)))
{
	next if $host =~ /^ /;
	next if (@hostsDesired and not grep {/$host/} @hostsDesired);
	next if (@hostsExcluded and grep {/$host/} @hostsExcluded);
	next if ($backupOnly and $Status{$host}{'type'} eq 'archive');
	next if ($archiveOnly and $Status{$host}{'type'} ne 'archive');
	$hostCount++;
	# Debug
	if ($verbose == 3)
	{
		$bb->print("Host $host state " . $Status{$host}{'state'});
		$bb->print(" with error: " . $Status{$host}{'error'} . "\n");
	}
	if ($Status{$host}{'error'})
	{
		# Check connectivity errors with greater care
		if ($statusOnly && (
		    $Status{$host}{'error'} eq 'ping too slow' ||
		    $Status{$host}{'error'} eq 'no ping response' ||
		    $Status{$host}{'error'} eq 'host not found')) {
			if ($Status{$host}{'lastGoodBackupTime'} - $Status{$host}{'startTime'} <= $Conf{FullPeriod} * 3600 * 24) {
				push @goodHost, $host;
				next;
			}
		}
		push @badHost, $host;
		# Check bad host ages
		$Status{$host}{'lastGoodBackupTime'} = $Status{$host}{'startTime'} if (not $Status{$host}{'lastGoodBackupTime'});
		if (difftime(time(), $Status{$host}{'lastGoodBackupTime'}) > ($daysOld * 3600 * 24))
		{
			push @tooOld, $host;
		}
		elsif (difftime(time(), $Status{$host}{'lastGoodBackupTime'}) > ($warnLevel * 3600 * 24))
		{
			push @notTooOld, $host;
		}
		else
		{
			push @goodHost, $host;
			pop @badHost;
		}
		# Debug
		if ($verbose == 2)
		{
			$bb->print("Host $host state " . $Status{$host}{'state'});
			$bb->print(" with error: " . $Status{$host}{'error'} . "\n");
		}
	}
	else
	{
		push @goodHost, $host;
	}
}

if ($hostCount == @goodHost or $#badHost < $reduce and not @tooOld)
{
	$bb->color_line('green', "BackupPC OK - (" . @badHost . "/" . $hostCount . ") failures\n");
	&list_unknown_hosts;
	$bb->send;
	exit $ERRORS{'OK'};
}

&list_unknown_hosts;

# Only failures reach this far
# WARNING
if ($#tooOld < 0 or $#badHost < $reduce)
{
	#print "BACKUPPC WARNING - (";
	if ($verbose)
	{
		foreach my $host (@badHost)
		{
			$bb->color_line('yellow', $host . " (" . $Status{$host}{'error'} . ")\n");
		}
		#print ")\n";
	}
	else
	{
		$bb->color_line('yellow', $#badHost + 1  . "/" . $hostCount . ") failures\n");
	}
	$bb->send;
	exit $ERRORS{'WARNING'};
}

# CRITICAL
#print "BACKUPPC CRITICAL - (";
if ($#notTooOld >= 0 and $verbose)
{
	foreach my $host (@notTooOld)
	{
		$bb->color_line('red', $host . " (" . $Status{$host}{'error'} . ")\n");
	}
	#print "), (";
}
if ($verbose)
{
	foreach my $host (@tooOld)
	{
		$bb->color_line('red', $host . " (" . $Status{$host}{'error'} . ")\n");
	}
	#print ") critical\n";
}
else
{
	$bb->print($#badHost + 1 . "/" . $hostCount . ") failures, ");
	$bb->print(print $#tooOld + 1 . " critical\n");
}
$bb->send;
exit $ERRORS{'CRITICAL'};

sub list_unknown_hosts {
    foreach my $host (@hostsDesired, @hostsExcluded)
    {
	if (not grep {/$host/} keys(%Status))
	{
		$bb->color_line('clear', "Host expected but not configured ($host)\n");
		#exit $ERRORS{'UNKNOWN'};
	}
    }
}