/usr/share/perl5/Dancer2/Core/MIME.pm is in libdancer2-perl 0.152000+dfsg-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 | # ABSTRACT: Class to ease manipulation of MIME types
package Dancer2::Core::MIME;
$Dancer2::Core::MIME::VERSION = '0.152000';
use Moo;
use MIME::Types;
use Dancer2::Core::Types;
# Initialise MIME::Types at compile time, to ensure it's done before
# the fork in a preforking webserver like mod_perl or Starman. Not
# doing this leads to all MIME types being returned as "text/plain",
# as MIME::Types fails to load its mappings from the DATA handle. See
# t/04_static_file/003_mime_types_reinit.t and GH#136.
BEGIN {
MIME::Types->new( only_complete => 1 );
}
has mime_type => (
is => 'ro',
isa => InstanceOf ['MIME::Types'],
default => sub { MIME::Types->new( only_complete => 1 ) },
lazy => 1,
);
has custom_types => (
is => 'ro',
isa => HashRef,
default => sub { +{} },
);
has default => (
is => 'rw',
isa => Str,
builder => "reset_default",
);
sub reset_default {
my ($self) = @_;
$self->default("application/data");
}
sub add_type {
my ( $self, $name, $type ) = @_;
$self->custom_types->{$name} = $type;
return;
}
sub add_alias {
my ( $self, $alias, $orig ) = @_;
my $type = $self->for_name($orig);
$self->add_type( $alias, $type );
return $type;
}
sub for_file {
my ( $self, $filename ) = @_;
my ($ext) = $filename =~ /\.([^.]+)$/;
return $self->default unless $ext;
return $self->for_name($ext);
}
sub name_or_type {
my ( $self, $name ) = @_;
return $name if $name =~ m{/}; # probably a mime type
return $self->for_name($name);
}
sub for_name {
my ( $self, $name ) = @_;
return
$self->custom_types->{ lc $name }
|| $self->mime_type->mimeTypeOf( lc $name )
|| $self->default;
}
1;
__END__
=pod
=encoding UTF-8
=head1 NAME
Dancer2::Core::MIME - Class to ease manipulation of MIME types
=head1 VERSION
version 0.152000
=head1 SYNOPSIS
use Dancer2::Core::MIME;
my $mime = Dancer::MIME->new();
# get mime type for an alias
my $type = $mime->for_name('css');
# set a new mime type
my $type = $mime->add_type( foo => 'text/foo' );
# set a mime type alias
my $alias = $mime->add_alias( f => 'foo' );
# get mime type for a file (based on extension)
my $file = $mime->for_file( "foo.bar" );
# set the $thing into a content $type.
my $type = $mime->name_or_type($thing);
# get current defined default mime type
my $type = $mime->default;
# set the default mime type using config.yml
# or using the set keyword
set default_mime_type => 'text/plain';
=head1 DESCRIPTION
Dancer::MIME is a thin wrapper around L<MIME::Types> providing helpful methods
for MIME handling.
=head1 ATTRIBUTES
=head2 mime_type
The mime_type which is found with MIME::Types.
=head2 custom_types
Custom user-defined MIME types that are added the with C<add_type>.
=head2 default
Default MIME type defined by MIME::Types, set to: B<application/data>.
=head1 METHODS
=head2 reset_default
This method resets C<mime_type> to the default type.
=head2 add_type
This method adds the new MIME type.
=head2 add_alias
The C<add_alias> sets a MIME type alias.
=head2 for_name
The method C<for_name> gets MIME type for an alias.
=head2 for_file
This method gets MIME type for a file based on extension.
=head2 name_or_type
This method sets the customized MIME name or default MIME type into a content
type.
=head1 AUTHOR
Dancer Core Developers
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2014 by Alexis Sukrieh.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut
|