/usr/share/perl5/Dist/Zilla/Plugin/MakeMaker/Runner.pm is in libdist-zilla-perl 5.020-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 | package Dist::Zilla::Plugin::MakeMaker::Runner;
# ABSTRACT: Test and build dists with a Makefile.PL
$Dist::Zilla::Plugin::MakeMaker::Runner::VERSION = '5.020';
use Moose;
with(
'Dist::Zilla::Role::BuildRunner',
'Dist::Zilla::Role::TestRunner',
);
use namespace::autoclean;
use Config;
has 'make_path' => (
isa => 'Str',
is => 'ro',
default => $Config{make} || 'make',
);
sub build {
my $self = shift;
my $make = $self->make_path;
my $makefile = $^O eq 'VMS' ? 'Descrip.MMS' : 'Makefile';
return
if -e $makefile and (stat 'Makefile.PL')[9] <= (stat $makefile)[9];
system($^X => 'Makefile.PL') and die "error with Makefile.PL\n";
system($make) and die "error running $make\n";
return;
}
sub test {
my ($self, $target, $arg) = @_;
my $make = $self->make_path;
$self->build;
my $job_count = $arg && exists $arg->{jobs}
? $arg->{jobs}
: $self->default_jobs;
my $jobs = "j$job_count";
my $ho = "HARNESS_OPTIONS";
local $ENV{$ho} = $ENV{$ho} ? "$ENV{$ho}:$jobs" : $jobs;
system($make, 'test',
( $self->zilla->logger->get_debug ? 'TEST_VERBOSE=1' : () ),
) and die "error running $make test\n";
return;
}
__PACKAGE__->meta->make_immutable;
1;
__END__
=pod
=encoding UTF-8
=head1 NAME
Dist::Zilla::Plugin::MakeMaker::Runner - Test and build dists with a Makefile.PL
=head1 VERSION
version 5.020
=head1 AUTHOR
Ricardo SIGNES <rjbs@cpan.org>
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2014 by Ricardo SIGNES.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut
|