/usr/share/perl5/MARC/File.pm is in libmarc-record-perl 2.0.6-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 | package MARC::File;
=head1 NAME
MARC::File - Base class for files of MARC records
=cut
use strict;
use warnings;
use integer;
use vars qw( $ERROR );
=head1 SYNOPSIS
use MARC::File::USMARC;
# If you have weird control fields...
use MARC::Field;
MARC::Field->allow_controlfield_tags('FMT', 'LDX');
my $file = MARC::File::USMARC->in( $filename );
while ( my $marc = $file->next() ) {
# Do something
}
$file->close();
undef $file;
=head1 EXPORT
None.
=head1 METHODS
=head2 in()
Opens a file for import. Ordinarily you will use C<MARC::File::USMARC>
or C<MARC::File::MicroLIF> to do this.
my $file = MARC::File::USMARC->in( 'file.marc' );
Returns a C<MARC::File> object, or C<undef> on failure. If you
encountered an error the error message will be stored in
C<$MARC::File::ERROR>.
Optionally you can also pass in a filehandle, and C<MARC::File>.
will "do the right thing".
my $handle = IO::File->new( 'gunzip -c file.marc.gz |' );
my $file = MARC::File::USMARC->in( $handle );
=cut
sub in {
my $class = shift;
my $arg = shift;
my ( $filename, $fh );
## if a valid filehandle was passed in
my $ishandle = do { no strict; defined fileno($arg); };
if ( $ishandle ) {
$filename = scalar( $arg );
$fh = $arg;
}
## otherwise check if it's a filename, and
## return undef if we weren't able to open it
else {
$filename = $arg;
$fh = eval { local *FH; open( FH, '<', $arg ) or die; *FH{IO}; };
if ( $@ ) {
$MARC::File::ERROR = "Couldn't open $filename: $@";
return;
}
}
my $self = {
filename => $filename,
fh => $fh,
recnum => 0,
warnings => [],
};
return( bless $self, $class );
} # new()
sub out {
die "Not yet written";
}
=head2 next( [\&filter_func] )
Reads the next record from the file handle passed in.
The C<$filter_func> is a reference to a filtering function. Currently,
only USMARC records support this. See L<MARC::File::USMARC>'s C<decode()>
function for details.
Returns a MARC::Record reference, or C<undef> on error.
=cut
sub next {
my $self = shift;
$self->{recnum}++;
my $rec = $self->_next() or return;
return $self->decode($rec, @_);
}
=head2 skip()
Skips over the next record in the file. Same as C<next()>,
without the overhead of parsing a record you're going to throw away
anyway.
Returns 1 or undef.
=cut
sub skip {
my $self = shift;
my $rec = $self->_next() or return;
return 1;
}
=head2 warnings()
Simlilar to the methods in L<MARC::Record> and L<MARC::Batch>,
C<warnings()> will return any warnings that have accumulated while
processing this file; and as a side-effect will clear the warnings buffer.
=cut
sub warnings {
my $self = shift;
my @warnings = @{ $self->{warnings} };
$self->{warnings} = [];
return(@warnings);
}
=head2 close()
Closes the file, both from the object's point of view, and the actual file.
=cut
sub close {
my $self = shift;
close( $self->{fh} );
delete $self->{fh};
delete $self->{filename};
return;
}
sub _unimplemented {
my $self = shift;
my $method = shift;
warn "Method $method must be overridden";
}
=head2 write()
Writes a record to the output file. This method must be overridden
in your subclass.
=head2 decode()
Decodes a record into a USMARC format. This method must be overridden
in your subclass.
=cut
sub write { $_[0]->_unimplemented("write"); }
sub decode { $_[0]->_unimplemented("decode"); }
# NOTE: _warn must be called as an object method
sub _warn {
my ($self,$warning) = @_;
push( @{ $self->{warnings} }, "$warning in record ".$self->{recnum} );
return( $self );
}
# NOTE: _gripe can be called as an object method, or not. Your choice.
# NOTE: it's use is now deprecated use _warn instead
sub _gripe {
my @parms = @_;
if ( @parms ) {
my $self = shift @parms;
if ( ref($self) =~ /^MARC::File/ ) {
push( @parms, " at byte ", tell($self->{fh}) )
if $self->{fh};
push( @parms, " in file ", $self->{filename} ) if $self->{filename};
} else {
unshift( @parms, $self );
}
$ERROR = join( "", @parms );
warn $ERROR;
}
return;
}
1;
__END__
=head1 RELATED MODULES
L<MARC::Record>
=head1 TODO
=over 4
=item * C<out()> method
We only handle files for input right now.
=back
=cut
=head1 LICENSE
This code may be distributed under the same terms as Perl itself.
Please note that these modules are not products of or supported by the
employers of the various contributors to the code.
=head1 AUTHOR
Andy Lester, C<< <andy@petdance.com> >>
=cut
|