/usr/share/perl5/Mixin/Linewise/Readers.pm is in libmixin-linewise-perl 0.106-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 | use strict;
use warnings;
package Mixin::Linewise::Readers;
# ABSTRACT: get linewise readers for strings and filenames
$Mixin::Linewise::Readers::VERSION = '0.106';
use 5.008001; # PerlIO
use Carp ();
use IO::File;
use PerlIO::utf8_strict;
use Sub::Exporter -setup => {
exports => { map {; "read_$_" => \"_mk_read_$_" } qw(file string) },
groups => {
default => [ qw(read_file read_string) ],
readers => [ qw(read_file read_string) ],
},
};
# =head1 SYNOPSIS
#
# package Your::Pkg;
# use Mixin::Linewise::Readers -readers;
#
# sub read_handle {
# my ($self, $handle) = @_;
#
# LINE: while (my $line = $handle->getline) {
# next LINE if $line =~ /^#/;
#
# print "non-comment: $line";
# }
# }
#
# Then:
#
# use Your::Pkg;
#
# Your::Pkg->read_file($filename);
#
# Your::Pkg->read_string($string);
#
# Your::Pkg->read_handle($fh);
#
# =head1 EXPORTS
#
# C<read_file> and C<read_string> are exported by default. Either can be
# requested individually, or renamed. They are generated by
# L<Sub::Exporter|Sub::Exporter>, so consult its documentation for more
# information.
#
# Both can be generated with the option "method" which requests that a method
# other than "read_handle" is called with the created IO::Handle.
#
# If given a "binmode" option, any C<read_file> type functions will use
# that as an IO layer, otherwise, the default is C<utf8_strict>.
#
# use Mixin::Linewise::Readers -readers => { binmode => "raw" };
# use Mixin::Linewise::Readers -readers => { binmode => "encoding(iso-8859-1)" };
#
# =head2 read_file
#
# Your::Pkg->read_file($filename);
# Your::Pkg->read_file($options, $filename);
#
# If generated, the C<read_file> export attempts to open the named file for
# reading, and then calls C<read_handle> on the opened handle.
#
# An optional hash reference may be passed before C<$filename> with options.
# The only valid option currently is C<binmode>, which overrides any
# default set from C<use> or the built-in C<utf8_strict>.
#
# Any arguments after C<$filename> are passed along after to C<read_handle>.
#
# =cut
sub _mk_read_file {
my ($self, $name, $arg) = @_;
my $method = defined $arg->{method} ? $arg->{method} : 'read_handle';
my $dflt_enc = defined $arg->{binmode} ? $arg->{binmode} : 'utf8_strict';
sub {
my ($invocant, $options, $filename);
if ( ref $_[1] eq 'HASH' ) {
# got options before filename
($invocant, $options, $filename) = splice @_, 0, 3;
}
else {
($invocant, $filename) = splice @_, 0, 2;
}
$options->{binmode} = $dflt_enc unless defined $options->{binmode};
$options->{binmode} =~ s/^://; # we add it later
# Check the file
Carp::croak "no filename specified" unless $filename;
Carp::croak "file '$filename' does not exist" unless -e $filename;
Carp::croak "'$filename' is not a plain file" unless -f _;
my $handle = IO::File->new($filename, "<:$options->{binmode}")
or Carp::croak "couldn't read file '$filename': $!";
$invocant->$method($handle, @_);
}
}
# =head2 read_string
#
# Your::Pkg->read_string($string);
#
# If generated, the C<read_string> creates a handle on the given string, and
# then calls C<read_handle> on the opened handle. Because handles on strings
# must be octet-oriented, the string B<must contain octets>. It will be opened
# in the default binmode established by importing. (See L</EXPORTS>, above.)
#
# Any arguments after C<$string> are passed along after to C<read_handle>.
#
# =cut
sub _mk_read_string {
my ($self, $name, $arg) = @_;
my $method = defined $arg->{method} ? $arg->{method} : 'read_handle';
my $dflt_enc = defined $arg->{binmode} ? $arg->{binmode} : 'utf8_strict';
sub {
my ($invocant, $string) = splice @_, 0, 2;
my $binmode = $dflt_enc;
$binmode =~ s/^://; # we add it later
Carp::croak "no string provided" unless defined $string;
open my $handle, "<:$binmode", \$string
or die "error opening string for reading: $!";
$invocant->$method($handle, @_);
}
}
1;
__END__
=pod
=encoding UTF-8
=head1 NAME
Mixin::Linewise::Readers - get linewise readers for strings and filenames
=head1 VERSION
version 0.106
=head1 SYNOPSIS
package Your::Pkg;
use Mixin::Linewise::Readers -readers;
sub read_handle {
my ($self, $handle) = @_;
LINE: while (my $line = $handle->getline) {
next LINE if $line =~ /^#/;
print "non-comment: $line";
}
}
Then:
use Your::Pkg;
Your::Pkg->read_file($filename);
Your::Pkg->read_string($string);
Your::Pkg->read_handle($fh);
=head1 EXPORTS
C<read_file> and C<read_string> are exported by default. Either can be
requested individually, or renamed. They are generated by
L<Sub::Exporter|Sub::Exporter>, so consult its documentation for more
information.
Both can be generated with the option "method" which requests that a method
other than "read_handle" is called with the created IO::Handle.
If given a "binmode" option, any C<read_file> type functions will use
that as an IO layer, otherwise, the default is C<utf8_strict>.
use Mixin::Linewise::Readers -readers => { binmode => "raw" };
use Mixin::Linewise::Readers -readers => { binmode => "encoding(iso-8859-1)" };
=head2 read_file
Your::Pkg->read_file($filename);
Your::Pkg->read_file($options, $filename);
If generated, the C<read_file> export attempts to open the named file for
reading, and then calls C<read_handle> on the opened handle.
An optional hash reference may be passed before C<$filename> with options.
The only valid option currently is C<binmode>, which overrides any
default set from C<use> or the built-in C<utf8_strict>.
Any arguments after C<$filename> are passed along after to C<read_handle>.
=head2 read_string
Your::Pkg->read_string($string);
If generated, the C<read_string> creates a handle on the given string, and
then calls C<read_handle> on the opened handle. Because handles on strings
must be octet-oriented, the string B<must contain octets>. It will be opened
in the default binmode established by importing. (See L</EXPORTS>, above.)
Any arguments after C<$string> are passed along after to C<read_handle>.
=head1 AUTHOR
Ricardo SIGNES <rjbs@cpan.org>
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2008 by Ricardo SIGNES.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut
|