/usr/share/perl5/Mojolicious/Validator/Validation.pm is in libmojolicious-perl 5.54+dfsg-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 | package Mojolicious::Validator::Validation;
use Mojo::Base -base;
use Carp 'croak';
use Scalar::Util 'blessed';
has [qw(csrf_token topic validator)];
has [qw(input output)] => sub { {} };
sub AUTOLOAD {
my $self = shift;
my ($package, $method) = our $AUTOLOAD =~ /^(.+)::(.+)$/;
croak "Undefined subroutine &${package}::$method called"
unless blessed $self && $self->isa(__PACKAGE__);
croak qq{Can't locate object method "$method" via package "$package"}
unless $self->validator->checks->{$method};
return $self->check($method => @_);
}
sub check {
my ($self, $check) = (shift, shift);
return $self unless $self->is_valid;
my $cb = $self->validator->checks->{$check};
my $name = $self->topic;
my $input = $self->input->{$name};
for my $value (ref $input eq 'ARRAY' ? @$input : $input) {
next unless my $result = $self->$cb($name, $value, @_);
return $self->error($name => [$check, $result, @_]);
}
return $self;
}
sub csrf_protect {
my $self = shift;
my $token = $self->input->{csrf_token};
$self->error(csrf_token => ['csrf_protect'])
unless $token && $token eq ($self->csrf_token // '');
return $self;
}
sub error {
my $self = shift;
return sort keys %{$self->{error}} unless defined(my $name = shift);
return $self->{error}{$name} unless @_;
$self->{error}{$name} = shift;
delete $self->output->{$name};
return $self;
}
sub every_param { shift->_param(@_) }
sub has_data { !!keys %{shift->input} }
sub has_error { $_[1] ? exists $_[0]{error}{$_[1]} : !!keys %{$_[0]{error}} }
sub is_valid { exists $_[0]->output->{$_[1] // $_[0]->topic} }
sub optional {
my ($self, $name) = @_;
my $input = $self->input->{$name};
my @input = ref $input eq 'ARRAY' ? @$input : $input;
$self->output->{$name} = $input
unless grep { !defined($_) || !length($_) } @input;
return $self->topic($name);
}
sub param {
my ($self, $name) = @_;
# Multiple names
return map { $self->param($_) } @$name if ref $name eq 'ARRAY';
# List names
return sort keys %{$self->output} unless defined $name;
return $self->_param($name)->[-1];
}
sub required {
my ($self, $name) = @_;
return $self if $self->optional($name)->is_valid;
return $self->error($name => ['required']);
}
sub _param {
return [] unless defined(my $value = shift->output->{shift()});
return [ref $value eq 'ARRAY' ? @$value : $value];
}
1;
=encoding utf8
=head1 NAME
Mojolicious::Validator::Validation - Perform validations
=head1 SYNOPSIS
use Mojolicious::Validator;
use Mojolicious::Validator::Validation;
my $validator = Mojolicious::Validator->new;
my $validation
= Mojolicious::Validator::Validation->new(validator => $validator);
$validation->input({foo => 'bar'});
$validation->required('foo')->in(qw(bar baz));
say $validation->param('foo');
=head1 DESCRIPTION
L<Mojolicious::Validator::Validation> performs L<Mojolicious::Validator>
validation checks.
=head1 ATTRIBUTES
L<Mojolicious::Validator::Validation> implements the following attributes.
=head2 csrf_token
my $token = $validation->csrf_token;
$validation = $validation->csrf_token('fa6a08...');
CSRF token.
=head2 input
my $input = $validation->input;
$validation = $validation->input({foo => 'bar', baz => [123, 'yada']});
Data to be validated.
=head2 output
my $output = $validation->output;
$validation = $validation->output({});
Validated data.
=head2 topic
my $topic = $validation->topic;
$validation = $validation->topic('foo');
Name of field currently being validated.
=head2 validator
my $validator = $validation->validator;
$validation = $validation->validator(Mojolicious::Validator->new);
L<Mojolicious::Validator> object this validation belongs to.
=head1 METHODS
L<Mojolicious::Validator::Validation> inherits all methods from L<Mojo::Base>
and implements the following new ones.
=head2 check
$validation = $validation->check('size', 2, 7);
Perform validation check on all values of the current L</"topic">, no more
checks will be performed on them after the first one failed.
=head2 csrf_protect
$validation = $validation->csrf_protect;
Validate C<csrf_token> and protect from cross-site request forgery.
=head2 error
my @names = $validation->error;
my $err = $validation->error('foo');
$validation = $validation->error(foo => ['custom_check']);
Get or set details for failed validation check, at any given time there can
only be one per field.
my ($check, $result, @args) = @{$validation->error('foo')};
=head2 every_param
my $values = $validation->every_param('foo');
Similar to L</"param">, but returns all values sharing the same name as an
array reference.
# Get first value
my $first = $validation->every_param('foo')->[0];
=head2 has_data
my $bool = $validation->has_data;
Check if L</"input"> is available for validation.
=head2 has_error
my $bool = $validation->has_error;
my $bool = $validation->has_error('foo');
Check if validation resulted in errors, defaults to checking all fields.
=head2 is_valid
my $bool = $validation->is_valid;
my $bool = $validation->is_valid('foo');
Check if validation was successful and field has a value, defaults to checking
the current L</"topic">.
=head2 optional
$validation = $validation->optional('foo');
Change validation L</"topic">.
=head2 param
my @names = $validation->param;
my $value = $validation->param('foo');
my ($foo, $bar) = $validation->param(['foo', 'bar']);
Access validated parameters. If there are multiple values sharing the same
name, and you want to access more than just the last one, you can use
L</"every_param">.
=head2 required
$validation = $validation->required('foo');
Change validation L</"topic"> and make sure a value is present and not an
empty string.
=head1 AUTOLOAD
In addition to the L</"ATTRIBUTES"> and L</"METHODS"> above, you can also call
validation checks provided by L</"validator"> on
L<Mojolicious::Validator::Validation> objects, similar to L</"check">.
$validation->required('foo')->size(2, 5)->like(qr/^[A-Z]/);
$validation->optional('bar')->equal_to('foo');
$validation->optional('baz')->in(qw(test 123));
=head1 SEE ALSO
L<Mojolicious>, L<Mojolicious::Guides>, L<http://mojolicio.us>.
=cut
|