/usr/share/perl5/POE/Filter/Reference.pm is in libpoe-perl 2:1.3650-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 | # Filter::Reference partial copyright 1998 Artur Bergman
# <artur@vogon-solutions.com>. Partial copyright 1999 Philip Gwyn.
package POE::Filter::Reference;
use strict;
use POE::Filter;
use vars qw($VERSION @ISA);
$VERSION = '1.365'; # NOTE - Should be #.### (three decimal places)
@ISA = qw(POE::Filter);
use Carp qw(carp croak confess);
sub BUFFER () { 0 }
sub FREEZE () { 1 }
sub THAW () { 2 }
sub COMPRESS () { 3 }
sub NO_FATALS () { 4 }
sub MAX_BUFFER () { 5 }
sub BAD_BUFFER () { 6 }
sub FIRST_UNUSED () { 7 }
use base 'Exporter';
our @EXPORT_OK = qw( FIRST_UNUSED );
my %KNOWN_PARAMS = (
Compression => 1,
Serializer => 1,
NoFatals => 1,
MaxBuffer => 1
);
#------------------------------------------------------------------------------
# Try to require one of the default freeze/thaw packages.
use vars qw( $DEF_FREEZER $DEF_FREEZE $DEF_THAW );
BEGIN {
local $SIG{'__DIE__'} = 'DEFAULT';
my @packages = qw(Storable FreezeThaw YAML);
foreach my $package (@packages) {
eval { require "$package.pm"; import $package (); };
if ($@) {
warn $@;
next;
}
# Found a good freezer!
$DEF_FREEZER = $package;
last;
}
die "Filter::Reference requires one of @packages" unless defined $DEF_FREEZER;
}
# Some processing here
($DEF_FREEZE, $DEF_THAW) = _get_methods($DEF_FREEZER);
#------------------------------------------------------------------------------
# Try to acquire Compress::Zlib at run time.
my $zlib_status = undef;
sub _include_zlib {
local $SIG{'__DIE__'} = 'DEFAULT';
unless (defined $zlib_status) {
eval "use Compress::Zlib qw(compress uncompress)";
if ($@) {
$zlib_status = $@;
eval(
"sub compress { @_ }\n" .
"sub uncompress { @_ }"
);
}
else {
$zlib_status = '';
}
}
$zlib_status;
}
#------------------------------------------------------------------------------
sub _get_methods {
my($freezer)=@_;
my $freeze=$freezer->can('nfreeze') || $freezer->can('freeze');
my $thaw=$freezer->can('thaw');
return unless $freeze and $thaw;
return ($freeze, $thaw);
}
#------------------------------------------------------------------------------
sub new
{
my $type = shift;
# Convert from old style to new style
# $l == 1
# ->new( undef ) => (Serializer => undef)
# ->new( $class ) => (Serializer => class)
# not defined $_[0]
# ->new( undef, 1 ) => (Serializer => undef, Compression => 1)
# ->new( undef, undef, 1 ) => (Serializer => undef, Compression => undef, NoFatals =>1)
# $l == 3
# ->new( $class, 1, 1 ) => (Serializer => undef, Compression => 1, NoFatals =>1)
# ($l <= 3 and not $KNOWN_PARAMS{$_[0]})
# ->new( $class, 1 )
my %params;
my $l = scalar @_;
if( $l == 1 or $l == 3 or not defined $_[0] or
( $l<=3 and not $KNOWN_PARAMS{$_[0]}) ) {
if( 'HASH' eq ref $_[0] ) { # do we
%params = %{ $_[0] };
}
else {
%params = ( Serializer => $_[0],
Compression => $_[1],
NoFatals => $_[2]
);
}
}
else {
croak "$type requires an even number of parameters" if @_ and @_ & 1;
%params = @_;
}
my($freeze, $thaw);
my $freezer = $params{Serializer};
unless (defined $freezer) {
# Okay, load the default one!
$freezer = $DEF_FREEZER;
$freeze = $DEF_FREEZE;
$thaw = $DEF_THAW;
}
else {
# What did we get?
if (ref $freezer) {
# It's an object, create an closure
my($freezetmp, $thawtmp) = _get_methods($freezer);
$freeze = sub { $freezetmp->($freezer, @_) };
$thaw = sub { $thawtmp-> ($freezer, @_) };
}
else {
# A package name?
# First, find out if the package has the necessary methods.
($freeze, $thaw) = _get_methods($freezer);
# If not, try to reload the module.
unless ($freeze and $thaw) {
my $path = $freezer;
$path =~ s{::}{/}g;
$path .= '.pm';
# Force a reload if necessary. This is naive and can leak
# memory, so we only do it until we get the desired methods.
delete $INC{$path};
eval {
local $^W = 0;
require $path;
$freezer->import();
};
carp $@ if $@;
($freeze, $thaw) = _get_methods($freezer);
}
}
}
# Now get the methods we want
carp "$freezer doesn't have a freeze or nfreeze method" unless $freeze;
carp "$freezer doesn't have a thaw method" unless $thaw;
# Should ->new() return undef() it if fails to find the methods it
# wants?
return unless $freeze and $thaw;
# Maximum buffer
my $max_buffer = $type->__param_max( MaxBuffer => 512*1024*1024, \%params );
# Compression
my $compression = $params{Compression}||0;
if ($compression) {
my $zlib_status = _include_zlib();
if ($zlib_status ne '') {
warn "Compress::Zlib load failed with error: $zlib_status\n";
carp "Filter::Reference compression option ignored";
$compression = 0;
}
}
# No fatals
my $no_fatals = $params{NoFatals}||0;
delete @params{ keys %KNOWN_PARAMS };
carp("$type ignores unknown parameters: ", join(', ', sort keys %params))
if scalar keys %params;
my $self = bless [
'', # BUFFER
$freeze, # FREEZE
$thaw, # THAW
$compression, # COMPRESS
$no_fatals, # NO_FATALS
$max_buffer, # MAX_BUFFER
'' # BAD_BUFFER
], $type;
$self;
}
#------------------------------------------------------------------------------
sub get {
my ($self, $stream) = @_;
my @return;
$self->get_one_start($stream);
while (1) {
my $next = $self->get_one();
last unless @$next;
push @return, @$next;
}
return \@return;
}
#------------------------------------------------------------------------------
# 2001-07-27 RCC: The get_one() variant of get() allows Wheel::Xyz to
# retrieve one filtered block at a time. This is necessary for filter
# changing and proper input flow control.
sub get_one_start {
my ($self, $stream) = @_;
$self->[BUFFER] .= join('', @$stream);
if( $self->[MAX_BUFFER] < length( $self->[BUFFER] ) ) {
$self->[BAD_BUFFER] = "Framing buffer exceeds the limit";
die $self->[BAD_BUFFER] unless $self->[NO_FATALS];
}
}
sub get_one {
my $self = shift;
# Need to check lengths in octets, not characters.
BEGIN { eval { require bytes } and bytes->import; }
if( $self->[BAD_BUFFER] ) {
my $err = $self->[BAD_BUFFER];
$self->[BAD_BUFFER] = '';
return [ $err ];
}
if (
$self->[BUFFER] =~ /^(\d+)\0/ and
length($self->[BUFFER]) >= $1 + length($1) + 1
) {
substr($self->[BUFFER], 0, length($1) + 1) = "";
my $next_message = substr($self->[BUFFER], 0, $1);
substr($self->[BUFFER], 0, $1) = "";
$next_message = uncompress($next_message) if $self->[COMPRESS];
unless ($self->[NO_FATALS]) {
return [ $self->[THAW]->($next_message) ];
}
my $thawed = eval { $self->[THAW]->($next_message) };
return [ "$@" ] if $@;
return [ $thawed ];
}
return [ ];
}
#------------------------------------------------------------------------------
# freeze one or more references, and return a string representing them
sub put {
my ($self, $references) = @_;
# Need to check lengths in octets, not characters.
BEGIN { eval { require bytes } and bytes->import; }
my @raw = map {
confess "Choking on a non-reference ($_)" unless ref();
my $frozen = $self->[FREEZE]->($_);
$frozen = compress($frozen) if $self->[COMPRESS];
length($frozen) . "\0" . $frozen;
} @$references;
\@raw;
}
#------------------------------------------------------------------------------
# Return everything we have outstanding. Do not destroy our framing
# buffer, though.
sub get_pending {
my $self = shift;
return undef unless length $self->[BUFFER];
return [ $self->[BUFFER] ];
}
1;
__END__
=head1 NAME
POE::Filter::Reference - freeze and thaw arbitrary Perl data
=head1 SYNOPSIS
#!perl
use YAML;
use POE qw(Wheel::ReadWrite Filter::Reference);
POE::Session->create(
inline_states => {
_start => sub {
pipe(my($read, $write)) or die $!;
$_[HEAP]{io} = POE::Wheel::ReadWrite->new(
InputHandle => $read,
OutputHandle => $write,
Filter => POE::Filter::Reference->new(),
InputEvent => "got_perl_data",
);
$_[HEAP]{io}->put(
{ key_1 => 111, key_2 => 222 }
);
},
got_perl_data => sub {
print "Got data:\n", YAML::Dump($_[ARG0]);
print "Bye!\n";
delete $_[HEAP]{io};
}
}
);
POE::Kernel->run();
exit;
=head1 DESCRIPTION
POE::Filter::Reference allows programs to send and receive arbitrary
Perl data structures without worrying about a line protocol. Its
put() method serializes Perl data into a byte stream suitable for
transmission. get_one() parses the data structures back out of such a
stream.
By default, POE::Filter::Reference uses Storable to do its magic. A
different serializer may be specified at construction time.
=head1 PUBLIC FILTER METHODS
=head2 new
new() creates and initializes a POE::Filter::Reference object. It
accepts a list of named parameters.
=head3 Serializer
Any class that supports nfreeze() (or freeze()) and thaw() may be used
as a Serializer. If a Serializer implements both nfreeze() and
freeze(), then the "network" (nfreeze) version will be used.
Serializer may be a class name:
# Use Storable explicitly, specified by package name.
my $filter = POE::Filter::Reference->newer( Serializer=>"Storable" );
# Use YAML instead. Compress its output, as it may be verbose.
my $filter = POE::Filter::Reference->new("YAML", 1);
Serializer may also be an object:
# Use an object.
my $serializer = Data::Serializer::Something->new();
my $filter = POE::Filter::Reference->newer( Serializer => $serializer );
If Serializer is omitted or undef, the Reference filter will try to
use Storable, FreezeThaw, and YAML in that order.
POE::Filter::Reference will die if it cannot find one of these
serializers, but this rarely happens now that Storable and YAML are
bundled with Perl.
=head3 Compression
If Compression is true, Compress::Zlib will be called upon to reduce
the size of serialized data. It will also decompress the incoming
stream data.
=head3 MaxBuffer
C<MaxBuffer> sets the maximum amount of data that the filter will hold onto
while trying to build a new reference. Defaults to 512 MB.
=head3 NoFatals
If NoFatals is true, messages will be thawed inside a block eval. By
default, however, thaw() is allowed to die normally. If an error
occurs while NoFatals is in effect, POE::Filter::Reference will
return a string containing the contents of $@ at the time the eval
failed. So when using NoFatals, it's important to check whether
input is really a reference:
sub got_reference {
my $message = $_[ARG0];
if (ref $message) {
print "Got data:\n", YAML::Dump($message);
}
else {
warn "Input decode error: $message\n";
}
}
new() will try to load any classes it needs for L</Compression> or L</Serializer>.
=head2 new [SERIALIZER [, COMPRESSION [, NO_FATALS]]]
This is the old constructor synatx. It does not conform to the normal
POE::Filter constructor parameter syntax. Please use the new syntax
instead.
Calling C<new> like this is equivalent to
POE::Filter::Reference->new( Serializer => SERIALIZER,
Compression => COMPRESSION,
NoFatals => NO_FATALS );
Please note that if you have a custom serializer class called C<Serializer>
you will have to update your code to the new syntax.
=head1 SERIALIZER API
Here's what POE::Filter::Reference expects of its serializers.
=head2 thaw SERIALIZED
thaw() is required. It accepts two parameters: $self and a scalar
containing a SERIALIZED byte stream representing a single Perl data
structure. It returns a reconstituted Perl data structure.
sub thaw {
my ($self, $stream) = @_;
my $reference = $self->_deserialization_magic($stream);
return $reference;
}
=head2 nfreeze REFERENCE
Either nfreeze() or freeze() is required. They behave identically,
except that nfreeze() is guaranteed to be portable across networks and
between machine architectures.
These freezers accept two parameters: $self and a REFERENCE to Perl
data. They return a serialized version of the REFERENCEd data.
sub nfreeze {
my ($self, $reference) = @_;
my $stream = $self->_serialization_magic($reference);
return $stream;
}
=head2 freeze REFERENCE
freeze() is an alternative form of nfreeze(). It has the same call
signature as nfreeze(), but it doesn't guarantee that serialized data
will be portable across machine architectures.
If you must choose between implementing freeze() and nfreeze() for use
with POE::Filter::Reference, go with nfreeze().
=head1 SEE ALSO
Please see L<POE::Filter> for documentation regarding the base
interface.
The SEE ALSO section in L<POE> contains a table of contents covering
the entire POE distribution.
=head1 BUGS
Not so much bugs as caveats:
It's important to use identical serializers on each end of a
connection. Even different versions of the same serializer can break
data in transit.
Most (if not all) serializers will re-bless data at the destination,
but many of them will not load the necessary classes to make those
blessings work. Make sure the same classes and versions are available
on either end of the wire.
=head1 AUTHORS & COPYRIGHTS
The Reference filter was contributed by Artur Bergman, with changes
by Philip Gwyn.
Please see L<POE> for more information about authors and contributors.
=cut
# rocco // vim: ts=2 sw=2 expandtab
# TODO - Edit.
|