/usr/share/polygen/ita/insulti.grm is in polygen-data 1.0.6.ds2-13.1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 | I ::= "title: Insulti d'autore\n"
^ "author: Manta\n"
^ "language: italian\n"
^ "status: mature\n"
^ "topic: misc\n"
^ "audience: tutti quanti\n"
^ "disclaim: si serba rancore solamente nei confronti"
(+ di "Vision-X" | dei >(down | mongoloidi | tetraplegici | gay)
| degli >(handicappati | spastici)
) ^"\n"
^ "created: 01/08/2002"
;
S ::= [(vecchio^"," | (- [la] madonna | [p^]orcoddue) se)]
(Frase.(rifl|NOrifl) [2: Virgola | 3: Quello].NOindet.(rifl|NOrifl)).(2|-3)
^ (+ "!" | "?")
;
Frase ::= >(non Essere [Nega] | >(a momenti | (un altro | ancora un) po' e) Essere)
[Completamente] Insulto.(NOindet|indet)
| Fare [Davvero] [da [stra^["-da"]]] Cagare
| Avere [Davvero | Completamente] Rotto Minchia
| Avere [Davvero]
( Merda.art (nel | dentro il |- all'interno del) Teschio
| il Teschio (pieno | [in^]farcito | riempito | guarnito) di Merda.NOart
)
;
Quello ::= quel (^lo | Insulto) [la']
| (que | ')^sto [Insulto] qua
| quell'altro [Insulto] [la']
;
Virgola ::= "(virgola)" Insulto ["(punto)"]
;
Essere ::= [mi] (2: (rifl: ti | NOrifl: _) sei | 3: (rifl: si | NOrifl: _) e')
;
Avere ::= [mi] (2: hai | 3: ha)
;
Fare ::= [mi] (2: fai | 3: fa)
;
Rotto ::= rotto | sbregato | divelto | sfilacciato | spaccato | distrutto | rovinato
| scassato | sfasciato | fracassato | spappolato | scucito
;
Completamente ::= completamente |- del tutto | definitivamente
| (leggermente | lievemente) | [giusto] un attim^[in^]o
;
Davvero ::= davvero | veramente | (leggermente | lievemente)
| [giusto] un attim^[in^]o
;
Merda ::= (art: la | NOart: _) >(merda |- cacca) | (art: il | NOart: _) guano
;
Teschio ::= + teschio | cranio
;
Nega ::= + neanche |+ mica | per niente | assolutamente
;
Cagare ::= >(ca^(c |+ g)^are | sboccare |-- vomitare) [Minchia]
|- venire (la diarrea | il cagotto)
;
Minchia ::= la minchia | il prepuzio | il glande | il cazzo | la renga | il frenulo
| lo scroto | i coglioni | le palle | le gonadi | l'inguine | la cappella
| il filetto
;
Insulto ::= NOrifl: (indet: un | NOindet: _)
( Super ^"-"^ (Pre^Post | [Pre^] Unico).NOindet.
| Pre^(Post | Unico).NOindet.
| Unico
)
| rifl: ([Super^"-"^] rin^Med^ito).NOindet.
;
Med ::= spastich | coglion | goldon | ebetit | down | froc | mongol | bamb
;
Pre ::= (indet: ^o | NOindet: _) spasti | [rin^]coglio[^n] | handi | mongo[^l] | goldon
| (tri | tetra | penta | deca
| (indet: ^'^ | NOindet: _) >(esa | epta | octa | endeca)
) [^ginta]
;
Post ::= down | cappato | gay | frocio | plegico | somico
;
Unico ::= (indet: ^o | NOindet: _) spastico | rincoglionito | (indet: ^'^ | NOindet: _) handicappato
| mongolo[^ide] | down | frocio | gay | coglione
;
Super ::= ((indet: ^'^ | NOindet: _) >(ultra | iper) | mega[^lo] | super | turbo)
[^Super.NOindet.]
;
|