/usr/share/tcltk/tcllib1.16/math/constants.tcl is in tcllib 1.16-dfsg-2.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 | # constants.tcl --
# Module defining common mathematical and numerical constants
#
# Copyright (c) 2004 by Arjen Markus. All rights reserved.
#
# See the file "license.terms" for information on usage and redistribution
# of this file, and for a DISCLAIMER OF ALL WARRANTIES.
#
# RCS: @(#) $Id: constants.tcl,v 1.9 2011/01/18 07:49:53 arjenmarkus Exp $
#
#----------------------------------------------------------------------
package require Tcl 8.2
package provide math::constants 1.0.1
# namespace constants
# Create a convenient namespace for the constants
#
namespace eval ::math::constants {
#
# List of constants and their description
#
variable constants {
pi 3.14159265358979323846 "ratio of circle circumference and diameter"
e 2.71828182845904523536 "base for natural logarithm"
ln10 2.30258509299404568402 "natural logarithm of 10"
phi 1.61803398874989484820 "golden ratio"
gamma 0.57721566490153286061 "Euler's constant"
sqrt2 1.41421356237309504880 "Square root of 2"
thirdrt2 1.25992104989487316477 "One-third power of 2"
sqrt3 1.73205080756887729533 "Square root of 3"
radtodeg 57.2957795131 "Conversion from radians to degrees"
degtorad 0.017453292519943 "Conversion from degrees to radians"
onethird 1.0/3.0 "One third (0.3333....)"
twothirds 2.0/3.0 "Two thirds (0.3333....)"
onesixth 1.0/6.0 "One sixth (0.1666....)"
huge [find_huge] "(Approximately) largest number"
tiny [find_tiny] "(Approximately) smallest number not equal zero"
eps [find_eps] "Smallest number such that 1+eps != 1"
}
namespace export constants print-constants
}
# constants --
# Expose the constants in the caller's routine or namespace
#
# Arguments:
# args List of constants to be exposed
# Result:
# None
#
proc ::math::constants::constants {args} {
foreach const $args {
uplevel 1 [list variable $const [set ::math::constants::$const]]
}
}
# print-constants --
# Print the selected or all constants to the screen
#
# Arguments:
# args List of constants to be exposed
# Result:
# None
#
proc ::math::constants::print-constants {args} {
variable constants
if { [llength $args] != 0 } {
foreach const $args {
set idx [lsearch $constants $const]
if { $idx >= 0 } {
set descr [lindex $constants [expr {$idx+2}]]
puts "$const = [set ::math::constants::$const] = $descr"
} else {
puts "*** $const unknown ***"
}
}
} else {
foreach {const value descr} $constants {
puts "$const = [set ::math::constants::$const] = $descr"
}
}
}
# find_huge --
# Find the largest possible number
#
# Arguments:
# None
# Result:
# Estimate of the largest possible number
#
proc ::math::constants::find_huge {} {
set result 1.0
set Inf Inf
while {1} {
if {[catch {expr {2.0 * $result}} result]} {
break
}
if { $result == $Inf } {
break
}
set prev_result $result
}
set result $prev_result
set adder [expr { $result / 2. }]
while { $adder != 0.0 } {
if {![catch {expr {$adder + $prev_result}} result]} {
if { $result == $prev_result } break
if { $result != $Inf } {
set prev_result $result
}
}
set adder [expr { $adder / 2. }]
}
return $prev_result
}
# find_tiny --
# Find the smallest possible number
#
# Arguments:
# None
# Result:
# Estimate of the smallest possible number
#
proc ::math::constants::find_tiny {} {
set result 1.0
while { ! [catch {set result [expr {$result/2.0}]}] && $result > 0.0 } {
set prev_result $result
}
return $prev_result
}
# find_eps --
# Find the smallest number eps such that 1+eps != 1
#
# Arguments:
# None
# Result:
# Estimate of the machine epsilon
#
proc ::math::constants::find_eps { } {
set eps 1.0
while { [expr {1.0+$eps}] != 1.0 } {
set prev_eps $eps
set eps [expr {0.5*$eps}]
}
return $prev_eps
}
# Create the variables from the list:
# - By using expr we ensure that the best double precision
# approximation is assigned to the variable, rather than
# just the string
# - It also allows us to rely on IEEE arithmetic if available,
# so that for instance 3.0*(1.0/3.0) is exactly 1.0
#
namespace eval ::math::constants {
foreach {const value descr} $constants {
# FRINK: nocheck
set [namespace current]::$const [expr 0.0+$value]
}
unset value
unset const
unset descr
rename find_eps {}
rename find_tiny {}
rename find_huge {}
}
# some tests --
#
if { [info exists ::argv0]
&& [string equal $::argv0 [info script]] } {
::math::constants::constants pi e ln10 onethird eps
set prec $::tcl_precision
if {![package vsatisfies [package provide Tcl] 8.5]} {
set ::tcl_precision 17
} else {
set ::tcl_precision 0
}
puts "$pi - [expr {1.0/$pi}]"
puts $e
puts $ln10
puts "onethird: [expr {3.0*$onethird}]"
::math::constants::print-constants onethird pi e
puts "All defined constants:"
::math::constants::print-constants
if { 1.0+$eps == 1.0 } {
puts "Something went wrong with eps!"
} else {
puts "Difference: [set ee [expr {1.0+$eps}]] - 1.0 = [expr {$ee-1.0}]"
}
set ::tcl_precision $prec
}
|