/usr/share/fusioninventory/lib/FusionInventory/Agent/Target.pm is in fusioninventory-agent 1:2.3.10.1-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 | package FusionInventory::Agent::Target;
use strict;
use warnings;
use English qw(-no_match_vars);
use FusionInventory::Agent::Logger;
use FusionInventory::Agent::Storage;
sub new {
my ($class, %params) = @_;
die 'no basevardir parameter' unless $params{basevardir};
my $self = {
logger => $params{logger} ||
FusionInventory::Agent::Logger->new(),
maxDelay => $params{maxDelay} || 3600,
initialDelay => $params{delaytime},
};
bless $self, $class;
return $self;
}
sub _init {
my ($self, %params) = @_;
my $logger = $self->{logger};
# target identity
$self->{id} = $params{id};
$self->{storage} = FusionInventory::Agent::Storage->new(
logger => $self->{logger},
directory => $params{vardir}
);
# handle persistent state
$self->_loadState();
$self->{nextRunDate} = $self->_computeNextRunDate()
if !$self->{nextRunDate};
$self->_saveState();
$logger->debug(
"[target $self->{id}] Next server contact planned for " .
localtime($self->{nextRunDate})
);
}
sub getStorage {
my ($self) = @_;
return $self->{storage};
}
sub setNextRunDate {
my ($self, $nextRunDate) = @_;
lock($self->{nextRunDate}) if $self->{shared};
$self->{nextRunDate} = $nextRunDate;
$self->_saveState();
}
sub resetNextRunDate {
my ($self) = @_;
lock($self->{nextRunDate}) if $self->{shared};
$self->{nextRunDate} = $self->_computeNextRunDate();
$self->_saveState();
}
sub getNextRunDate {
my ($self) = @_;
return $self->{nextRunDate};
}
sub getFormatedNextRunDate {
my ($self) = @_;
return $self->{nextRunDate} > 1 ?
scalar localtime($self->{nextRunDate}) : "now";
}
sub getMaxDelay {
my ($self) = @_;
return $self->{maxDelay};
}
sub setMaxDelay {
my ($self, $maxDelay) = @_;
$self->{maxDelay} = $maxDelay;
$self->_saveState();
}
# compute a run date, as current date and a random delay
# between maxDelay / 2 and maxDelay
sub _computeNextRunDate {
my ($self) = @_;
my $ret;
if ($self->{initialDelay}) {
$ret = time + ($self->{initialDelay} / 2) + int rand($self->{initialDelay} / 2);
$self->{initialDelay} = undef;
} else {
$ret =
time +
$self->{maxDelay} / 2 +
int rand($self->{maxDelay} / 2);
}
return $ret;
}
sub _loadState {
my ($self) = @_;
my $data = $self->{storage}->restore(name => 'target');
$self->{maxDelay} = $data->{maxDelay} if $data->{maxDelay};
$self->{nextRunDate} = $data->{nextRunDate} if $data->{nextRunDate};
}
sub _saveState {
my ($self) = @_;
$self->{storage}->save(
name => 'target',
data => {
maxDelay => $self->{maxDelay},
nextRunDate => $self->{nextRunDate},
}
);
}
1;
__END__
=head1 NAME
FusionInventory::Agent::Target - Abstract target
=head1 DESCRIPTION
This is an abstract class for execution targets.
=head1 METHODS
=head2 new(%params)
The constructor. The following parameters are allowed, as keys of the %params
hash:
=over
=item I<logger>
the logger object to use
=item I<maxDelay>
the maximum delay before contacting the target, in seconds
(default: 3600)
=item I<basevardir>
the base directory of the storage area (mandatory)
=back
=head2 getNextRunDate()
Get nextRunDate attribute.
=head2 getFormatedNextRunDate()
Get nextRunDate attribute as a formated string.
=head2 setNextRunDate($nextRunDate)
Set next execution date.
=head2 resetNextRunDate()
Set next execution date to a random value.
=head2 getMaxDelay($maxDelay)
Get maxDelay attribute.
=head2 setMaxDelay($maxDelay)
Set maxDelay attribute.
=head2 getStorage()
Return the storage object for this target.
|