/usr/share/imagevis3d/shaders/GLRaycaster-2D-FS.glsl is in imagevis3d 3.1.0-4.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 | /*
For more information, please see: http://software.sci.utah.edu
The MIT License
Copyright (c) 2008 Scientific Computing and Imaging Institute,
University of Utah.
Permission is hereby granted, free of charge, to any person obtaining a
copy of this software and associated documentation files (the "Software"),
to deal in the Software without restriction, including without limitation
the rights to use, copy, modify, merge, publish, distribute, sublicense,
and/or sell copies of the Software, and to permit persons to whom the
Software is furnished to do so, subject to the following conditions:
The above copyright notice and this permission notice shall be included
in all copies or substantial portions of the Software.
THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
DEALINGS IN THE SOFTWARE.
*/
/**
\file GLRaycaster-2D-FS.glsl
\author Jens Krueger
SCI Institute
University of Utah
\version 1.0
\date October 2008
*/
uniform sampler2D texTrans; ///< the 2D Transfer function
uniform sampler2D texRayExitPos; ///< the backface (or ray exit point) texture in eyecoords
uniform float fTransScale; ///< value scale for 2D Transfer function lookup
uniform float fGradientScale; ///< gradient scale for 2D Transfer function lookup
uniform float fStepScale; ///< opacity correction quotient
uniform vec3 vVoxelStepsize; ///< Stepsize (in texcoord) to get to the next voxel
uniform vec2 vScreensize; ///< the size of the screen in pixels
uniform float fRayStepsize; ///< stepsize along the ray
varying vec3 vEyePos;
vec4 sampleVolume(vec3 coords);
vec4 UnderCompositing(vec4 src, vec4 dst);
vec3 ComputeGradient(vec3 vCenter, vec3 StepSize);
void main(void)
{
// compute the coordinates to look up the previous pass
vec2 vFragCoords = vec2(gl_FragCoord.x / vScreensize.x , gl_FragCoord.y / vScreensize.y);
// compute the ray parameters
vec3 vRayEntry = texture2D(texRayExitPos, vFragCoords).xyz;
vec3 vRayExit = vEyePos;
vec3 vRayEntryTex = (gl_TextureMatrix[0] * vec4(vRayEntry,1.0)).xyz;
vec3 vRayExitTex = (gl_TextureMatrix[0] * vec4(vRayExit,1.0)).xyz;
float fRayLength = length(vRayExit - vRayEntry);
// compute the maximum number of steps before the domain is left
int iStepCount = int(fRayLength/fRayStepsize)+1;
vec3 vRayIncTex = (vRayExitTex-vRayEntryTex)/(fRayLength/fRayStepsize);
// do the actual raycasting
vec4 vColor = vec4(0.0,0.0,0.0,0.0);
vec3 vCurrentPosTex = vRayEntryTex;
for (int i = 0;i<iStepCount;i++) {
float fVolumVal = sampleVolume( vCurrentPosTex).x;
// compute the gradient/normal
vec3 vGradient = ComputeGradient(vCurrentPosTex, vVoxelStepsize);
float fGradientMag = length(vGradient);
// apply 2D transfer function
vec4 vTransVal = texture2D(texTrans, vec2(fVolumVal*fTransScale, 1.0-fGradientMag*fGradientScale));
// apply opacity correction
vTransVal.a = 1.0 - pow(1.0 - vTransVal.a, fStepScale);
vColor = UnderCompositing(vTransVal,vColor);
vCurrentPosTex += vRayIncTex;
if (vColor.a >= 0.99) break;
}
gl_FragColor = vColor;
}
|