/usr/share/ada/adainclude/gnatcoll/gnatcoll-refcount.adb is in libgnatcoll1.6-dev 1.6gpl2014-6.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 | ------------------------------------------------------------------------------
-- G N A T C O L L --
-- --
-- Copyright (C) 2010-2014, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or modify it --
-- under terms of the GNU General Public License as published by the Free --
-- Software Foundation; either version 3, or (at your option) any later --
-- version. This library is distributed in the hope that it will be useful, --
-- but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHAN- --
-- TABILITY or FITNESS FOR A PARTICULAR PURPOSE. --
-- --
-- --
-- --
-- --
-- --
-- You should have received a copy of the GNU General Public License and --
-- a copy of the GCC Runtime Library Exception along with this program; --
-- see the files COPYING3 and COPYING.RUNTIME respectively. If not, see --
-- <http://www.gnu.org/licenses/>. --
-- --
------------------------------------------------------------------------------
with Ada.Unchecked_Deallocation;
with Interfaces; use Interfaces;
with Ada.Tags; use Ada.Tags;
with GNATCOLL.Traces; use GNATCOLL.Traces;
package body GNATCOLL.Refcount is
Me : constant Trace_Handle := Create ("REFCOUNT", Off);
procedure Unchecked_Free is new Ada.Unchecked_Deallocation
(Refcounted'Class, Refcounted_Access);
package body Sync_Counters is separate;
--------------------
-- Smart_Pointers --
--------------------
package body Smart_Pointers is
---------
-- Set --
---------
procedure Set (Self : in out Ref; Data : access Encapsulated'Class) is
begin
if Self.Data = Refcounted_Access (Data) then
-- Avoid finalizing Self.Data if we are going to reuse it
return;
end if;
if Self.Data /= null then
Finalize (Self); -- decrement reference count
end if;
if Data /= null then
Self.Data := Refcounted_Access (Data);
Adjust (Self); -- increment reference count
end if;
end Set;
---------
-- Set --
---------
procedure Set (Self : in out Ref; Data : Encapsulated'Class) is
Tmp : constant Encapsulated_Access := new Encapsulated'Class'(Data);
begin
Set (Self, Tmp);
end Set;
---------
-- Get --
---------
function Get (P : Ref) return Encapsulated_Access is
begin
return Encapsulated_Access (P.Data);
end Get;
---------
-- "=" --
---------
overriding function "=" (P1, P2 : Ref) return Boolean is
begin
return P1.Data = P2.Data;
end "=";
--------------
-- Finalize --
--------------
overriding procedure Finalize (P : in out Ref) is
Data : Refcounted_Access := P.Data;
begin
-- Make Finalize idempotent, since it could be called several
-- times for the same instance (RM 7.6.1(24)).
P.Data := null;
-- Test if refcount is > 0, in case we are already freeing this
-- element.
if Data /= null then
if Sync_Counters.Sync_Add_And_Fetch (Data.Refcount'Access, -1) =
0
then
Trace (Me, "Freeing memory for "
& External_Tag (Ref'Class (P)'Tag));
Free (Data.all);
Unchecked_Free (Data);
end if;
end if;
end Finalize;
------------
-- Adjust --
------------
overriding procedure Adjust (P : in out Ref) is
Dummy : Integer_32;
pragma Unreferenced (Dummy);
begin
if P.Data /= null then
Dummy := Sync_Counters.Sync_Add_And_Fetch
(P.Data.Refcount'Access, 1);
end if;
end Adjust;
------------------
-- Get_Refcount --
------------------
function Get_Refcount (Self : Ref) return Natural is
begin
if Self.Data = null then
return 0;
else
return Natural (Self.Data.Refcount);
end if;
end Get_Refcount;
end Smart_Pointers;
end GNATCOLL.Refcount;
|