/usr/share/ada/adainclude/gnatcoll/gnatcoll-sql_impl.adb is in libgnatcoll1.6-dev 1.6gpl2014-6.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535 536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576 577 578 579 580 581 582 583 584 585 586 587 588 589 590 591 592 593 594 595 596 597 598 599 600 601 602 603 604 605 606 607 608 609 610 611 612 613 614 615 616 617 618 619 620 621 622 623 624 625 626 627 628 629 630 631 632 633 634 635 636 637 638 639 640 641 642 643 644 645 646 647 648 649 650 651 652 653 654 655 656 657 658 659 660 661 662 663 664 665 666 667 668 669 670 671 672 673 674 675 676 677 678 679 680 681 682 683 684 685 686 687 688 689 690 691 692 693 694 695 696 697 698 699 700 701 702 703 704 705 706 707 708 709 710 711 712 713 714 715 716 717 718 719 720 721 722 723 724 725 726 727 728 729 730 731 732 733 734 735 736 737 738 739 740 741 742 743 744 745 746 747 748 749 750 751 752 753 754 755 756 757 758 759 760 761 762 763 764 765 766 767 768 769 770 771 772 773 774 775 776 777 778 779 780 781 782 783 784 785 786 787 788 789 790 791 792 793 794 795 796 797 798 799 800 801 802 803 804 805 806 807 808 809 810 811 812 813 814 815 816 817 818 819 820 821 822 823 824 825 826 827 828 829 830 831 832 833 834 835 836 837 838 839 840 841 842 843 844 845 846 847 848 849 850 851 852 853 854 855 856 857 858 859 860 861 862 863 864 865 866 867 868 869 870 871 872 873 874 875 876 877 878 879 880 881 882 883 884 885 886 887 888 889 890 891 892 893 894 895 896 897 898 899 900 901 902 903 904 905 906 907 908 909 910 911 912 913 914 915 916 917 918 919 920 921 922 923 924 925 926 927 928 929 930 931 932 933 934 935 936 937 938 939 940 941 942 943 944 945 946 947 948 949 950 951 952 953 954 955 956 957 958 959 960 961 962 963 964 965 966 967 968 969 970 971 972 973 974 975 976 977 978 979 980 981 982 983 984 985 986 987 988 989 990 991 992 993 994 995 996 997 998 999 1000 1001 1002 1003 1004 1005 1006 1007 1008 1009 1010 1011 1012 1013 1014 1015 1016 1017 1018 1019 1020 1021 1022 1023 1024 1025 1026 1027 1028 1029 1030 1031 1032 1033 1034 1035 1036 1037 1038 1039 1040 1041 1042 1043 1044 1045 1046 1047 1048 1049 1050 1051 1052 1053 1054 1055 1056 1057 1058 1059 1060 1061 1062 1063 1064 1065 1066 1067 1068 1069 1070 1071 1072 1073 1074 1075 1076 1077 1078 1079 1080 1081 1082 1083 1084 1085 1086 1087 1088 1089 1090 1091 1092 1093 1094 1095 1096 1097 1098 1099 1100 1101 1102 1103 1104 1105 1106 1107 1108 1109 1110 1111 1112 1113 1114 1115 1116 1117 1118 1119 1120 1121 1122 1123 1124 1125 1126 1127 1128 1129 1130 1131 1132 1133 1134 1135 1136 1137 1138 1139 1140 1141 1142 1143 1144 1145 1146 1147 1148 1149 1150 1151 1152 1153 1154 1155 1156 1157 1158 1159 1160 1161 1162 1163 1164 1165 1166 1167 1168 1169 1170 1171 1172 1173 1174 1175 1176 1177 1178 1179 1180 1181 1182 1183 1184 1185 1186 1187 1188 1189 1190 1191 1192 1193 1194 1195 1196 1197 1198 1199 1200 1201 1202 1203 1204 1205 1206 1207 1208 1209 1210 1211 1212 1213 1214 1215 1216 1217 1218 1219 1220 1221 1222 1223 1224 1225 1226 1227 1228 1229 1230 1231 1232 1233 1234 1235 1236 1237 1238 1239 1240 1241 1242 1243 1244 1245 1246 1247 1248 1249 1250 1251 1252 1253 1254 1255 1256 1257 1258 1259 1260 1261 1262 1263 1264 1265 1266 1267 1268 1269 1270 1271 1272 1273 1274 1275 1276 1277 1278 1279 1280 1281 1282 1283 1284 1285 1286 1287 1288 1289 1290 1291 1292 1293 1294 1295 1296 1297 1298 1299 1300 1301 1302 1303 1304 1305 1306 1307 1308 1309 1310 1311 1312 1313 1314 1315 1316 1317 1318 1319 1320 1321 1322 1323 1324 1325 1326 1327 1328 1329 1330 1331 1332 1333 1334 1335 1336 1337 1338 1339 1340 1341 1342 1343 1344 1345 1346 1347 1348 1349 1350 1351 1352 1353 1354 1355 1356 1357 1358 1359 1360 1361 1362 1363 1364 1365 1366 1367 1368 1369 1370 1371 1372 1373 1374 1375 1376 1377 1378 1379 1380 1381 1382 1383 1384 1385 1386 1387 1388 1389 1390 1391 1392 1393 1394 1395 1396 1397 1398 1399 1400 1401 1402 1403 1404 1405 1406 1407 1408 1409 1410 1411 1412 1413 1414 1415 1416 1417 1418 1419 1420 1421 1422 1423 1424 1425 1426 1427 1428 1429 1430 1431 1432 1433 1434 1435 1436 1437 1438 1439 1440 1441 1442 1443 1444 1445 1446 1447 1448 1449 1450 1451 1452 1453 1454 1455 1456 1457 1458 1459 1460 1461 1462 1463 1464 1465 1466 1467 1468 1469 1470 1471 1472 1473 1474 1475 1476 1477 1478 1479 1480 1481 1482 1483 1484 1485 1486 1487 1488 1489 1490 1491 1492 1493 1494 1495 1496 1497 1498 1499 1500 1501 1502 1503 1504 1505 1506 1507 1508 1509 1510 1511 1512 1513 1514 1515 1516 1517 1518 1519 1520 1521 1522 1523 1524 1525 1526 1527 1528 1529 1530 1531 1532 1533 1534 1535 1536 1537 1538 1539 1540 1541 1542 1543 1544 1545 1546 1547 1548 1549 1550 1551 1552 1553 1554 1555 1556 1557 1558 1559 1560 1561 1562 1563 1564 1565 1566 1567 1568 1569 1570 1571 1572 1573 1574 1575 1576 1577 1578 1579 1580 1581 1582 1583 1584 1585 1586 1587 1588 1589 1590 1591 1592 1593 1594 1595 1596 1597 1598 1599 1600 1601 1602 1603 1604 1605 1606 1607 1608 1609 1610 1611 1612 1613 1614 1615 1616 1617 1618 1619 1620 1621 1622 1623 1624 1625 1626 1627 1628 1629 1630 1631 1632 1633 1634 1635 1636 1637 1638 1639 1640 1641 1642 1643 1644 1645 1646 1647 1648 1649 1650 1651 1652 1653 1654 1655 1656 1657 1658 1659 1660 1661 1662 1663 | ------------------------------------------------------------------------------
-- G N A T C O L L --
-- --
-- Copyright (C) 2005-2014, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or modify it --
-- under terms of the GNU General Public License as published by the Free --
-- Software Foundation; either version 3, or (at your option) any later --
-- version. This library is distributed in the hope that it will be useful, --
-- but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHAN- --
-- TABILITY or FITNESS FOR A PARTICULAR PURPOSE. --
-- --
-- --
-- --
-- --
-- --
-- You should have received a copy of the GNU General Public License and --
-- a copy of the GCC Runtime Library Exception along with this program; --
-- see the files COPYING3 and COPYING.RUNTIME respectively. If not, see --
-- <http://www.gnu.org/licenses/>. --
-- --
------------------------------------------------------------------------------
with Ada.Calendar; use Ada.Calendar;
with Ada.Calendar.Time_Zones; use Ada.Calendar.Time_Zones;
with Ada.Strings.Fixed; use Ada.Strings.Fixed;
with Ada.Strings.Hash;
with Ada.Strings.Unbounded; use Ada.Strings.Unbounded;
with Ada.Unchecked_Deallocation;
with GNAT.Calendar.Time_IO; use GNAT.Calendar, GNAT.Calendar.Time_IO;
with GNAT.Strings; use GNAT.Strings;
with GNATCOLL.Utils; use GNATCOLL.Utils;
package body GNATCOLL.SQL_Impl is
use Field_List, Table_Sets, Assignment_Lists;
Comparison_Equal : aliased constant String := "=";
Comparison_Different : aliased constant String := "<>";
Comparison_Less : aliased constant String := "<";
Comparison_Less_Equal : aliased constant String := "<=";
Comparison_Greater : aliased constant String := ">";
Comparison_Greater_Equal : aliased constant String := ">=";
--------------------------
-- Named field data --
--------------------------
-- Instantiation of field_data for specific types of fields, created for
-- instance via Expression, From_String, or operators on time. Such fields
-- are still typed
type Field_Type is (Field_Std, Field_Operator, Field_Parameter);
-- The type of the field:
-- Field_Std: Str_Value is directly the text of the field
-- Field_Operator: Str_Value is the operator, that acts on several
-- fields ("-" for instance")
-- Field_Parameter: the field's exact value is unknown, and will be
-- substituted at runtime (for instance "?1" in sqlite3). Str_Value
-- is then the index of the field.
type Named_Field_Internal (Typ : Field_Type)
is new SQL_Field_Internal with record
Table : Table_Names := No_Names;
case Typ is
when Field_Std =>
Str_Value : GNAT.Strings.String_Access;
-- The expression representing the field in SQL. See Field_Type
-- for more information
when Field_Operator =>
Op_Value : GNAT.Strings.String_Access;
List : SQL_Field_List;
when Field_Parameter =>
Index : Positive;
Param_Type : Parameter_Type;
end case;
end record;
type Named_Field_Internal_Access is access all Named_Field_Internal'Class;
overriding procedure Free (Self : in out Named_Field_Internal);
overriding function To_String
(Self : Named_Field_Internal;
Format : Formatter'Class;
Long : Boolean) return String;
overriding procedure Append_Tables
(Self : Named_Field_Internal; To : in out Table_Sets.Set);
overriding procedure Append_If_Not_Aggregate
(Self : access Named_Field_Internal;
To : in out SQL_Field_List'Class;
Is_Aggregate : in out Boolean);
procedure Assign
(R : out SQL_Assignment;
Field : SQL_Field'Class;
Value : Named_Field_Internal_Access);
-- Assign Value to Field (or set field to NULL if Value is null).
-- On exit, Value belongs to R and should not be freed by the caller.
---------------------
-- Function fields --
---------------------
type Function_Field is new SQL_Field_Internal with record
Prefix, Suffix : GNAT.Strings.String_Access;
To_Field : SQL_Field_Pointer;
end record;
type Function_Field_Access is access all Function_Field'Class;
overriding procedure Free (Self : in out Function_Field);
overriding function To_String
(Self : Function_Field;
Format : Formatter'Class;
Long : Boolean) return String;
overriding procedure Append_Tables
(Self : Function_Field; To : in out Table_Sets.Set);
overriding procedure Append_If_Not_Aggregate
(Self : access Function_Field;
To : in out SQL_Field_List'Class;
Is_Aggregate : in out Boolean);
-- A field that applies a function (via Prefix .. Suffix) to another field
--------------
-- Criteria --
--------------
type Comparison_Criteria is new SQL_Criteria_Data with record
Op, Suffix : Cst_String_Access;
Arg1, Arg2 : SQL_Field_Pointer;
end record;
overriding function To_String
(Self : Comparison_Criteria;
Format : Formatter'Class;
Long : Boolean := True) return String;
overriding procedure Append_Tables
(Self : Comparison_Criteria; To : in out Table_Sets.Set);
overriding procedure Append_If_Not_Aggregate
(Self : Comparison_Criteria;
To : in out SQL_Field_List'Class;
Is_Aggregate : in out Boolean);
----------------
-- Data_Field --
----------------
package body Data_Fields is
overriding function To_String
(Self : Field;
Format : Formatter'Class;
Long : Boolean := True) return String is
begin
if Self.Data.Data /= null then
return To_String (Self.Data.Data.all, Format, Long);
else
return "";
end if;
end To_String;
overriding procedure Append_Tables
(Self : Field; To : in out Table_Sets.Set) is
begin
if Self.Data.Data /= null then
Append_Tables (Self.Data.Data.all, To);
end if;
end Append_Tables;
overriding procedure Append_If_Not_Aggregate
(Self : Field;
To : in out SQL_Field_List'Class;
Is_Aggregate : in out Boolean)
is
begin
if Self.Data.Data /= null then
Append_If_Not_Aggregate (Self.Data.Data, To, Is_Aggregate);
end if;
end Append_If_Not_Aggregate;
end Data_Fields;
package Any_Fields is new Data_Fields (SQL_Field);
-------------------
-- Instance_Name --
-------------------
function Instance_Name (Names : Table_Names) return String is
begin
if Names.Instance = null then
if Names.Instance_Index = -1 then
if Names.Name = null then
return "";
else
return Names.Name.all;
end if;
else
return Names.Name (Names.Name'First)
& Image (Names.Instance_Index, Min_Width => 1);
end if;
else
return Names.Instance.all;
end if;
end Instance_Name;
----------
-- Hash --
----------
function Hash (Self : Table_Names) return Ada.Containers.Hash_Type is
begin
return Ada.Strings.Hash (Instance_Name (Self));
end Hash;
---------------
-- To_String --
---------------
overriding function To_String
(Self : SQL_Field_List;
Format : Formatter'Class;
Long : Boolean := True) return String
is
C : Field_List.Cursor := First (Self.List);
Result : Unbounded_String;
begin
if Has_Element (C) then
Append (Result, To_String (Element (C), Format, Long));
Next (C);
end if;
while Has_Element (C) loop
Append (Result, ", ");
Append (Result, To_String (Element (C), Format, Long));
Next (C);
end loop;
return To_String (Result);
end To_String;
---------------
-- To_String --
---------------
overriding function To_String
(Self : SQL_Field;
Format : Formatter'Class;
Long : Boolean := True) return String
is
pragma Unreferenced (Format);
begin
if not Long then
return Self.Name.all;
else
declare
N : constant String := Instance_Name
((Name => Self.Table,
Instance => Self.Instance,
Instance_Index => Self.Instance_Index));
begin
if N /= "" then
return N & "." & Self.Name.all;
else
-- Self.Table could be null in the case of the Null_Field_*
-- constants
return Self.Name.all;
end if;
end;
end if;
end To_String;
----------
-- Free --
----------
procedure Free (Self : in out Named_Field_Internal) is
begin
case Self.Typ is
when Field_Std => Free (Self.Str_Value);
when Field_Operator => Free (Self.Op_Value);
when Field_Parameter => null;
end case;
end Free;
---------------
-- To_String --
---------------
function To_String
(Self : Named_Field_Internal;
Format : Formatter'Class;
Long : Boolean) return String
is
Result : Unbounded_String;
C : Field_List.Cursor;
begin
case Self.Typ is
when Field_Std =>
if Self.Table = No_Names then
return Self.Str_Value.all;
elsif Long then
if Self.Table.Instance = null then
return Self.Table.Name.all & '.' & Self.Str_Value.all;
else
return Self.Table.Instance.all & '.' & Self.Str_Value.all;
end if;
else
return Self.Str_Value.all;
end if;
when Field_Operator =>
C := First (Self.List.List);
Result := To_Unbounded_String (To_String (Element (C), Format));
Next (C);
while Has_Element (C) loop
Result := Result & " " & Self.Op_Value.all & " "
& To_String (Element (C), Format);
Next (C);
end loop;
return To_String (Result);
when Field_Parameter =>
return Parameter_String (Format, Self.Index, Self.Param_Type);
end case;
end To_String;
-------------------
-- Append_Tables --
-------------------
procedure Append_Tables
(Self : Named_Field_Internal; To : in out Table_Sets.Set) is
begin
if Self.Table /= No_Names then
Include (To, Self.Table);
end if;
end Append_Tables;
-------------------
-- Append_Tables --
-------------------
overriding procedure Append_Tables
(Self : Function_Field; To : in out Table_Sets.Set) is
begin
Append_Tables (Self.To_Field.Data.Field.all, To);
end Append_Tables;
-----------------------------
-- Append_If_Not_Aggregate --
-----------------------------
overriding procedure Append_If_Not_Aggregate
(Self : access Function_Field;
To : in out SQL_Field_List'Class;
Is_Aggregate : in out Boolean)
is
begin
Append_If_Not_Aggregate (Self.To_Field.Data.Field.all, To, Is_Aggregate);
end Append_If_Not_Aggregate;
-----------------------------
-- Append_If_Not_Aggregate --
-----------------------------
procedure Append_If_Not_Aggregate
(Self : access Named_Field_Internal;
To : in out SQL_Field_List'Class;
Is_Aggregate : in out Boolean)
is
C : Field_List.Cursor;
begin
if Self.Typ = Field_Operator then
C := First (Self.List.List);
while Has_Element (C) loop
Append_If_Not_Aggregate (Element (C), To, Is_Aggregate);
Next (C);
end loop;
end if;
-- We create a SQL_Field_Text, but it might be any other type.
-- This isn't really relevant, however, since the exact type is not used
-- later on.
if Self.Table /= No_Names then
Self.Refcount := Self.Refcount + 1;
Append
(To.List, Any_Fields.Field'
(Table => Self.Table.Name,
Instance => Self.Table.Instance,
Instance_Index => Self.Table.Instance_Index,
Name => null,
Data => (Ada.Finalization.Controlled with
SQL_Field_Internal_Access (Self))));
end if;
end Append_If_Not_Aggregate;
------------
-- Adjust --
------------
procedure Adjust (Self : in out Field_Data) is
begin
if Self.Data /= null then
Self.Data.Refcount := Self.Data.Refcount + 1;
end if;
end Adjust;
--------------
-- Finalize --
--------------
procedure Finalize (Self : in out Field_Data) is
procedure Unchecked_Free is new Ada.Unchecked_Deallocation
(SQL_Field_Internal'Class, SQL_Field_Internal_Access);
Data : SQL_Field_Internal_Access := Self.Data;
begin
Self.Data := null; -- Make Finalize idempotent
if Data /= null then
Data.Refcount := Data.Refcount - 1;
if Data.Refcount = 0 then
Free (Data.all);
Unchecked_Free (Data);
end if;
end if;
end Finalize;
---------
-- "&" --
---------
function "&" (Left, Right : SQL_Field'Class) return SQL_Field_List is
Result : SQL_Field_List;
begin
Append (Result.List, Left);
Append (Result.List, Right);
return Result;
end "&";
---------
-- "&" --
---------
function "&"
(Left : SQL_Field_List; Right : SQL_Field'Class) return SQL_Field_List
is
Result : SQL_Field_List;
begin
Result.List := Left.List; -- Does a copy, so we do not modify Left
Append (Result.List, Right);
return Result;
end "&";
---------
-- "&" --
---------
function "&"
(Left : SQL_Field'Class; Right : SQL_Field_List) return SQL_Field_List
is
Result : SQL_Field_List;
begin
Result.List := Right.List; -- Does a copy so that we do not modify Right
Prepend (Result.List, Left);
return Result;
end "&";
---------
-- "&" --
---------
function "&"
(Left, Right : SQL_Field_List) return SQL_Field_List
is
Result : SQL_Field_List;
C : Field_List.Cursor := First (Right.List);
begin
Result.List := Left.List; -- Does a copy, don't modify Left
while Has_Element (C) loop
Append (Result.List, Element (C));
Next (C);
end loop;
return Result;
end "&";
---------
-- "+" --
---------
function "+" (Left : SQL_Field'Class) return SQL_Field_List is
Result : SQL_Field_List;
begin
Append (Result.List, Left);
return Result;
end "+";
-------------------
-- Append_Tables --
-------------------
procedure Append_Tables (Self : SQL_Field; To : in out Table_Sets.Set) is
begin
if Self.Table /= null then
Include (To, (Name => Self.Table, Instance => Self.Instance,
Instance_Index => Self.Instance_Index));
end if;
end Append_Tables;
-----------------------------
-- Append_If_Not_Aggregate --
-----------------------------
procedure Append_If_Not_Aggregate
(Self : SQL_Field;
To : in out SQL_Field_List'Class;
Is_Aggregate : in out Boolean)
is
pragma Unreferenced (Is_Aggregate);
begin
-- Ignore constant fields (NULL,...)
if Self.Table /= null then
Append (To.List, Self);
end if;
end Append_If_Not_Aggregate;
---------------
-- To_String --
---------------
function To_String
(Self : SQL_Criteria;
Format : Formatter'Class;
Long : Boolean := True) return String
is
begin
if Self.Criteria.Data /= null then
return To_String (Self.Criteria.Data.all, Format, Long);
else
return "";
end if;
end To_String;
-------------------
-- Append_Tables --
-------------------
procedure Append_Tables (Self : SQL_Criteria; To : in out Table_Sets.Set) is
begin
if Self.Criteria.Data /= null then
Append_Tables (Self.Criteria.Data.all, To);
end if;
end Append_Tables;
-----------------------------
-- Append_If_Not_Aggregate --
-----------------------------
procedure Append_If_Not_Aggregate
(Self : SQL_Criteria;
To : in out SQL_Field_List'Class;
Is_Aggregate : in out Boolean) is
begin
if Self.Criteria.Data /= null then
Append_If_Not_Aggregate (Self.Criteria.Data.all, To, Is_Aggregate);
end if;
end Append_If_Not_Aggregate;
--------------
-- Set_Data --
--------------
procedure Set_Data
(Self : in out SQL_Criteria; Data : not null access SQL_Criteria_Data) is
begin
-- Make sure Adjust/Finalize are properly called for memory management.
-- We cannot simply change the pointer directly
Self.Criteria :=
Controlled_SQL_Criteria'
(Ada.Finalization.Controlled with
Data => SQL_Criteria_Data_Access (Data));
end Set_Data;
--------------
-- Get_Data --
--------------
function Get_Data (Self : SQL_Criteria) return SQL_Criteria_Data_Access is
begin
return Self.Criteria.Data;
end Get_Data;
------------
-- Adjust --
------------
procedure Adjust (Self : in out Controlled_SQL_Criteria) is
begin
if Self.Data /= null then
Self.Data.Refcount := Self.Data.Refcount + 1;
end if;
end Adjust;
--------------
-- Finalize --
--------------
procedure Finalize (Self : in out Controlled_SQL_Criteria) is
procedure Unchecked_Free is new Ada.Unchecked_Deallocation
(SQL_Criteria_Data'Class, SQL_Criteria_Data_Access);
Data : SQL_Criteria_Data_Access := Self.Data;
begin
Self.Data := null; -- Make Finalize idempotent
if Data /= null then
Data.Refcount := Data.Refcount - 1;
if Data.Refcount = 0 then
Free (Data.all);
Unchecked_Free (Data);
end if;
end if;
end Finalize;
------------
-- Adjust --
------------
procedure Adjust (Self : in out SQL_Field_Pointer) is
begin
if Self.Data /= null then
Self.Data.Refcount := Self.Data.Refcount + 1;
end if;
end Adjust;
--------------
-- Finalize --
--------------
procedure Finalize (Self : in out SQL_Field_Pointer) is
procedure Unchecked_Free is new Ada.Unchecked_Deallocation
(Field_Pointer_Data, Field_Pointer_Data_Access);
procedure Unchecked_Free is new Ada.Unchecked_Deallocation
(SQL_Field'Class, Field_Access);
Data : Field_Pointer_Data_Access := Self.Data;
begin
Self.Data := null; -- Make Finalize idempotent
if Data /= null then
Data.Refcount := Data.Refcount - 1;
if Data.Refcount = 0 then
Unchecked_Free (Data.Field);
Unchecked_Free (Data);
end if;
end if;
end Finalize;
---------
-- "+" --
---------
function "+" (Field : SQL_Field'Class) return SQL_Field_Pointer is
begin
return SQL_Field_Pointer'
(Ada.Finalization.Controlled with
Data => new Field_Pointer_Data'
(Refcount => 1,
Field => new SQL_Field'Class'(Field)));
end "+";
---------------
-- To_String --
---------------
overriding function To_String
(Self : Comparison_Criteria;
Format : Formatter'Class;
Long : Boolean := True) return String
is
Arg1 : constant String := To_String (Self.Arg1, Format, Long => Long);
Arg2 : constant String := To_String (Self.Arg2, Format, Long => Long);
begin
if Self.Op.all = "="
and then Arg2 = "TRUE"
then
return Arg1;
elsif Self.Op.all = "="
and then Arg2 = "FALSE"
then
return "not " & Arg1;
elsif Self.Suffix /= null then
return Arg1 & Self.Op.all & Arg2 & Self.Suffix.all;
else
return Arg1 & Self.Op.all & Arg2;
end if;
end To_String;
-------------------
-- Append_Tables --
-------------------
overriding procedure Append_Tables
(Self : Comparison_Criteria; To : in out Table_Sets.Set) is
begin
Append_Tables (Self.Arg1, To);
Append_Tables (Self.Arg2, To);
end Append_Tables;
-----------------------------
-- Append_If_Not_Aggregate --
-----------------------------
overriding procedure Append_If_Not_Aggregate
(Self : Comparison_Criteria;
To : in out SQL_Field_List'Class;
Is_Aggregate : in out Boolean) is
begin
Append_If_Not_Aggregate (Self.Arg1, To, Is_Aggregate);
Append_If_Not_Aggregate (Self.Arg2, To, Is_Aggregate);
end Append_If_Not_Aggregate;
-------------
-- Compare --
-------------
function Compare
(Left, Right : SQL_Field'Class;
Op : Cst_String_Access;
Suffix : Cst_String_Access := null) return SQL_Criteria
is
Data : constant SQL_Criteria_Data_Access :=
new Comparison_Criteria'
(SQL_Criteria_Data with
Op => Op, Suffix => Suffix, Arg1 => +Left, Arg2 => +Right);
Result : SQL_Criteria;
begin
Set_Data (Result, Data);
return Result;
end Compare;
---------------
-- To_String --
---------------
function To_String
(Self : SQL_Field_Pointer;
Format : Formatter'Class;
Long : Boolean) return String is
begin
return To_String (Self.Data.Field.all, Format, Long);
end To_String;
-------------------
-- Append_Tables --
-------------------
procedure Append_Tables
(Self : SQL_Field_Pointer; To : in out Table_Sets.Set) is
begin
if Self.Data /= null and then Self.Data.Field /= null then
Append_Tables (Self.Data.Field.all, To);
end if;
end Append_Tables;
-----------------------------
-- Append_If_Not_Aggregate --
-----------------------------
procedure Append_If_Not_Aggregate
(Self : SQL_Field_Pointer;
To : in out SQL_Field_List'Class;
Is_Aggregate : in out Boolean) is
begin
if Self.Data.Field /= null then
Append_If_Not_Aggregate (Self.Data.Field.all, To, Is_Aggregate);
end if;
end Append_If_Not_Aggregate;
-----------
-- First --
-----------
function First (List : SQL_Field_List) return Field_List.Cursor is
begin
return First (List.List);
end First;
------------
-- Append --
------------
procedure Append
(List : in out SQL_Field_List'Class; Field : SQL_Field_Pointer) is
begin
if Field.Data /= null and then Field.Data.Field /= null then
Append (List.List, Field.Data.Field.all);
end if;
end Append;
-------------------
-- Append_Tables --
-------------------
procedure Append_Tables
(Self : SQL_Assignment; To : in out Table_Sets.Set)
is
C : Assignment_Lists.Cursor := First (Self.List);
begin
while Has_Element (C) loop
Append_Tables (Element (C).Field, To);
Append_Tables (Element (C).To_Field, To);
Next (C);
end loop;
end Append_Tables;
---------------
-- To_String --
---------------
function To_String
(Self : SQL_Assignment;
Format : Formatter'Class;
With_Field : Boolean) return String
is
Result : Unbounded_String;
C : Assignment_Lists.Cursor := First (Self.List);
Data : Assignment_Item;
begin
while Has_Element (C) loop
Data := Element (C);
if Result /= Null_Unbounded_String then
Append (Result, ", ");
end if;
if Data.To_Field /= No_Field_Pointer then
if With_Field then
Append
(Result, To_String (Data.Field, Format, Long => False)
& "=" & To_String (Data.To_Field, Format, Long => True));
else
Append
(Result, To_String (Data.To_Field, Format, Long => True));
end if;
elsif With_Field then
Append
(Result, To_String (Data.Field, Format, Long => False)
& "=" & Null_String);
else
Append (Result, Null_String);
end if;
Next (C);
end loop;
return To_String (Result);
end To_String;
-------------
-- To_List --
-------------
procedure To_List (Self : SQL_Assignment; List : out SQL_Field_List) is
N : SQL_Field_Internal_Access;
C : Assignment_Lists.Cursor := First (Self.List);
Data : Assignment_Item;
begin
while Has_Element (C) loop
Data := Element (C);
if Data.To_Field /= No_Field_Pointer then
Append (List, Data.To_Field);
else
-- Setting a field to null
N := new Named_Field_Internal (Field_Std);
Named_Field_Internal (N.all).Str_Value := new String'(Null_String);
List := List
& Any_Fields.Field'
(Table => null,
Instance => null,
Instance_Index => -1,
Name => null,
Data => (Ada.Finalization.Controlled with N));
end if;
Next (C);
end loop;
end To_List;
----------------
-- Get_Fields --
----------------
procedure Get_Fields (Self : SQL_Assignment; List : out SQL_Field_List) is
C : Assignment_Lists.Cursor := First (Self.List);
begin
while Has_Element (C) loop
Append (List, Element (C).Field);
Next (C);
end loop;
end Get_Fields;
---------
-- "&" --
---------
function "&" (Left, Right : SQL_Assignment) return SQL_Assignment is
Result : SQL_Assignment;
C : Assignment_Lists.Cursor := First (Right.List);
begin
Result.List := Left.List;
while Has_Element (C) loop
Append (Result.List, Element (C));
Next (C);
end loop;
return Result;
end "&";
------------
-- Assign --
------------
procedure Assign
(R : out SQL_Assignment;
Field : SQL_Field'Class;
Value : Named_Field_Internal_Access)
is
begin
if Value = null then
Append (R.List, Assignment_Item'(+Field, No_Field_Pointer));
else
declare
A : constant Assignment_Item :=
(Field => +Field,
To_Field => +Any_Fields.Field'
(Table => null,
Instance => null,
Instance_Index => -1,
Name => null,
Data => (Ada.Finalization.Controlled
with SQL_Field_Internal_Access (Value))));
begin
Append (R.List, A);
end;
end if;
end Assign;
----------
-- Free --
----------
overriding procedure Free (Self : in out Function_Field) is
begin
Free (Self.Prefix);
Free (Self.Suffix);
Free (SQL_Field_Internal (Self));
end Free;
---------------
-- To_String --
---------------
overriding function To_String
(Self : Function_Field;
Format : Formatter'Class;
Long : Boolean) return String
is
pragma Unreferenced (Long);
begin
return Self.Prefix.all
& To_String (Self.To_Field.Data.Field.all, Format, Long => True)
& Self.Suffix.all;
end To_String;
-----------------
-- Field_Types --
-----------------
package body Field_Types is
type Ada_Type_Access is access Ada_Type;
package Typed_Data_Fields is new Data_Fields (Field);
type Typed_Named_Field_Internal is new Named_Field_Internal with record
Data_Value : Ada_Type_Access;
end record;
overriding procedure Free (Self : in out Typed_Named_Field_Internal);
overriding function To_String
(Self : Typed_Named_Field_Internal;
Format : Formatter'Class;
Long : Boolean) return String;
procedure Unchecked_Free is new Ada.Unchecked_Deallocation
(Ada_Type, Ada_Type_Access);
function Internal_From_Data
(Data : SQL_Field_Internal_Access) return Field'Class;
pragma Inline (Internal_From_Data);
----------
-- Free --
----------
overriding procedure Free (Self : in out Typed_Named_Field_Internal) is
begin
Unchecked_Free (Self.Data_Value);
Free (Named_Field_Internal (Self));
end Free;
---------------
-- To_String --
---------------
overriding function To_String
(Self : Typed_Named_Field_Internal;
Format : Formatter'Class;
Long : Boolean) return String is
begin
if Self.Data_Value /= null then
return To_SQL (Format, Self.Data_Value.all, Quote => True);
end if;
return To_String (Named_Field_Internal (Self), Format, Long);
end To_String;
----------------
-- From_Table --
----------------
function From_Table
(Self : Field;
Table : SQL_Single_Table'Class) return Field'Class
is
F : Typed_Data_Fields.Field
(Table => null, Instance => Table.Instance,
Instance_Index => Table.Instance_Index, Name => null);
D : constant Named_Field_Internal_Access :=
new Named_Field_Internal (Field_Std);
begin
D.Table := (Name => null, Instance => Table.Instance,
Instance_Index => Table.Instance_Index);
D.Str_Value := new String'(Self.Name.all);
F.Data.Data := SQL_Field_Internal_Access (D);
return Field (F);
end From_Table;
------------------------
-- Internal_From_Data --
------------------------
function Internal_From_Data
(Data : SQL_Field_Internal_Access) return Field'Class is
begin
return Typed_Data_Fields.Field'
(Table => null, Instance => null, Name => null,
Instance_Index => -1,
Data => (Ada.Finalization.Controlled with Data => Data));
end Internal_From_Data;
----------------
-- Expression --
----------------
function Expression (Value : Ada_Type) return Field'Class is
Data : constant Named_Field_Internal_Access :=
new Typed_Named_Field_Internal (Field_Std);
begin
Typed_Named_Field_Internal (Data.all).Data_Value :=
new Ada_Type'(Value);
return Internal_From_Data (SQL_Field_Internal_Access (Data));
end Expression;
-----------------
-- From_String --
-----------------
function From_String (SQL : String) return Field'Class is
Data : constant Named_Field_Internal_Access :=
new Named_Field_Internal (Field_Std);
begin
Data.Str_Value := new String'(SQL);
return Internal_From_Data (SQL_Field_Internal_Access (Data));
end From_String;
-----------
-- Param --
-----------
function Param (Index : Positive) return Field'Class is
Data : constant Named_Field_Internal_Access :=
new Named_Field_Internal (Field_Parameter);
begin
Data.Index := Index;
Data.Param_Type := Param_Type;
return Internal_From_Data (SQL_Field_Internal_Access (Data));
end Param;
---------
-- "&" --
---------
function "&"
(Field : SQL_Field'Class; Value : Ada_Type) return SQL_Field_List is
begin
return Field & Expression (Value);
end "&";
function "&"
(Value : Ada_Type; Field : SQL_Field'Class) return SQL_Field_List is
begin
return Expression (Value) & Field;
end "&";
function "&"
(List : SQL_Field_List; Value : Ada_Type) return SQL_Field_List is
begin
return List & Expression (Value);
end "&";
function "&"
(Value : Ada_Type; List : SQL_Field_List) return SQL_Field_List is
begin
return Expression (Value) & List;
end "&";
--------------
-- Operator --
--------------
function Operator (Field1, Field2 : Field'Class) return Field'Class is
F : Typed_Data_Fields.Field
(Table => null, Instance => null,
Instance_Index => -1, Name => null);
D : constant Named_Field_Internal_Access :=
new Named_Field_Internal (Field_Operator);
begin
D.Op_Value := new String'(Name);
D.List := Field1 & Field2;
F.Data.Data := SQL_Field_Internal_Access (D);
return F;
end Operator;
---------------------
-- Scalar_Operator --
---------------------
function Scalar_Operator
(Self : Field'Class; Operand : Scalar) return Field'Class
is
F : Typed_Data_Fields.Field
(Table => null, Instance => null, Name => null,
Instance_Index => -1);
D : constant Named_Field_Internal_Access :=
new Named_Field_Internal (Field_Operator);
F2 : Typed_Data_Fields.Field
(Table => null, Instance => null, Name => null,
Instance_Index => -1);
D2 : constant Named_Field_Internal_Access :=
new Named_Field_Internal (Field_Std);
begin
D2.Str_Value := new String'(Prefix & Scalar'Image (Operand) & Suffix);
F2.Data.Data := SQL_Field_Internal_Access (D2);
D.Op_Value := new String'(Name);
D.List := Self & F2;
F.Data.Data := SQL_Field_Internal_Access (D);
return F;
end Scalar_Operator;
------------------
-- SQL_Function --
------------------
function SQL_Function return Field'Class is
F : Typed_Data_Fields.Field
(Table => null, Instance => null, Name => null,
Instance_Index => -1);
D : constant Named_Field_Internal_Access :=
new Named_Field_Internal (Field_Std);
begin
D.Str_Value := new String'(Name);
F.Data.Data := SQL_Field_Internal_Access (D);
return F;
end SQL_Function;
--------------------
-- Apply_Function --
--------------------
function Apply_Function
(Self : Argument_Type'Class) return Field'Class
is
F : Typed_Data_Fields.Field
(Table => null, Instance => null, Name => null,
Instance_Index => -1);
D : constant Function_Field_Access := new Function_Field;
begin
if Suffix /= ")" and then Suffix /= "" then
D.Prefix := new String'(Name);
D.To_Field := +Self;
D.Suffix := new String'(" " & Suffix);
else
D.Prefix := new String'(Name);
D.To_Field := +Self;
D.Suffix := new String'(Suffix);
end if;
F.Data.Data := SQL_Field_Internal_Access (D);
return F;
end Apply_Function;
---------------
-- Operators --
---------------
function "=" (Left : Field; Right : Field'Class) return SQL_Criteria is
begin
return Compare (Left, Right, Comparison_Equal'Access);
end "=";
function "/=" (Left : Field; Right : Field'Class) return SQL_Criteria is
begin
return Compare (Left, Right, Comparison_Different'Access);
end "/=";
function "<" (Left : Field; Right : Field'Class) return SQL_Criteria is
begin
return Compare (Left, Right, Comparison_Less'Access);
end "<";
function "<=" (Left : Field; Right : Field'Class) return SQL_Criteria is
begin
return Compare (Left, Right, Comparison_Less_Equal'Access);
end "<=";
function ">" (Left : Field; Right : Field'Class) return SQL_Criteria is
begin
return Compare (Left, Right, Comparison_Greater'Access);
end ">";
function ">=" (Left : Field; Right : Field'Class) return SQL_Criteria is
begin
return Compare (Left, Right, Comparison_Greater_Equal'Access);
end ">=";
function "=" (Left : Field; Right : Ada_Type) return SQL_Criteria
is
begin
return Compare (Left, Expression (Right), Comparison_Equal'Access);
end "=";
function "/=" (Left : Field; Right : Ada_Type) return SQL_Criteria
is
begin
return Compare
(Left, Expression (Right), Comparison_Different'Access);
end "/=";
function "<" (Left : Field; Right : Ada_Type) return SQL_Criteria is
begin
return Compare (Left, Expression (Right), Comparison_Less'Access);
end "<";
function "<=" (Left : Field; Right : Ada_Type) return SQL_Criteria
is
begin
return Compare
(Left, Expression (Right), Comparison_Less_Equal'Access);
end "<=";
function ">" (Left : Field; Right : Ada_Type) return SQL_Criteria is
begin
return Compare
(Left, Expression (Right), Comparison_Greater'Access);
end ">";
function ">=" (Left : Field; Right : Ada_Type) return SQL_Criteria is
begin
return Compare
(Left, Expression (Right), Comparison_Greater_Equal'Access);
end ">=";
function Greater_Than
(Left : SQL_Field'Class; Right : Field) return SQL_Criteria
is
begin
return Compare (Left, Right, Comparison_Greater'Access);
end Greater_Than;
function Greater_Or_Equal
(Left : SQL_Field'Class; Right : Field) return SQL_Criteria
is
begin
return Compare (Left, Right, Comparison_Greater_Equal'Access);
end Greater_Or_Equal;
function Equal
(Left : SQL_Field'Class; Right : Field) return SQL_Criteria
is
begin
return Compare (Left, Right, Comparison_Equal'Access);
end Equal;
function Less_Than
(Left : SQL_Field'Class; Right : Field) return SQL_Criteria
is
begin
return Compare (Left, Right, Comparison_Less'Access);
end Less_Than;
function Less_Or_Equal
(Left : SQL_Field'Class; Right : Field) return SQL_Criteria
is
begin
return Compare (Left, Right, Comparison_Less_Equal'Access);
end Less_Or_Equal;
function Greater_Than
(Left : SQL_Field'Class; Right : Ada_Type) return SQL_Criteria is
begin
return Compare
(Left, Expression (Right), Comparison_Greater'Access);
end Greater_Than;
function Greater_Or_Equal
(Left : SQL_Field'Class; Right : Ada_Type) return SQL_Criteria is
begin
return Compare
(Left, Expression (Right), Comparison_Greater_Equal'Access);
end Greater_Or_Equal;
function Equal
(Left : SQL_Field'Class; Right : Ada_Type) return SQL_Criteria is
begin
return Compare (Left, Expression (Right), Comparison_Equal'Access);
end Equal;
function Less_Than
(Left : SQL_Field'Class; Right : Ada_Type) return SQL_Criteria is
begin
return Compare
(Left, Expression (Right), Comparison_Less'Access);
end Less_Than;
function Less_Or_Equal
(Left : SQL_Field'Class; Right : Ada_Type) return SQL_Criteria is
begin
return Compare
(Left, Expression (Right), Comparison_Less_Equal'Access);
end Less_Or_Equal;
function "=" (Self : Field; Value : Ada_Type) return SQL_Assignment is
Result : SQL_Assignment;
F : constant Named_Field_Internal_Access :=
new Typed_Named_Field_Internal (Field_Std);
begin
Typed_Named_Field_Internal (F.all).Data_Value := new Ada_Type'(Value);
Assign (Result, Self, F);
return Result;
end "=";
---------
-- "=" --
---------
function "=" (Self : Field; To : Field'Class) return SQL_Assignment is
Result : SQL_Assignment;
begin
-- Special case when assigning to one of the Null_Field constants
if To.Table = null
and then To.Instance = null
and then To.Name = Null_String'Access
then
Assign (Result, Self, null);
else
Append (Result.List, Assignment_Item'(+Self, +To));
end if;
return Result;
end "=";
end Field_Types;
-------------------
-- Boolean_Image --
-------------------
function Boolean_Image (Self : Formatter; Value : Boolean) return String is
pragma Unreferenced (Self);
begin
return Boolean'Image (Value);
end Boolean_Image;
--------------------
-- Boolean_To_SQL --
--------------------
function Boolean_To_SQL
(Self : Formatter'Class;
Value : Boolean;
Quote : Boolean) return String
is
pragma Unreferenced (Quote);
begin
return Boolean_Image (Self, Value);
end Boolean_To_SQL;
------------------
-- Float_To_SQL --
------------------
function Float_To_SQL
(Self : Formatter'Class;
Value : Float;
Quote : Boolean) return String
is
pragma Unreferenced (Self, Quote);
Img : constant String := Float'Image (Value);
begin
if Img (Img'First) = ' ' then
return Img (Img'First + 1 .. Img'Last);
else
return Img;
end if;
end Float_To_SQL;
--------------------
-- Integer_To_SQL --
--------------------
function Integer_To_SQL
(Self : Formatter'Class;
Value : Integer;
Quote : Boolean) return String
is
pragma Unreferenced (Self, Quote);
Img : constant String := Integer'Image (Value);
begin
if Img (Img'First) = ' ' then
return Img (Img'First + 1 .. Img'Last);
else
return Img;
end if;
end Integer_To_SQL;
-----------------------
-- Supports_Timezone --
-----------------------
function Supports_Timezone (Self : Formatter) return Boolean is
pragma Unreferenced (Self);
begin
return True;
end Supports_Timezone;
-----------------
-- Time_To_SQL --
-----------------
function Time_To_SQL
(Self : Formatter'Class;
Value : Ada.Calendar.Time;
Quote : Boolean) return String
is
Adjusted : Time;
begin
-- Value is always considered as GMT, which is what we store in the
-- database. Unfortunately, GNAT.Calendar.Time_IO converts that back to
-- local time.
if Value /= GNAT.Calendar.No_Time then
Adjusted := Value - Duration (UTC_Time_Offset (Value)) * 60.0;
if Supports_Timezone (Self) then
if Quote then
return Image (Adjusted, "'%Y-%m-%d %H:%M:%S +00:00'");
else
return Image (Adjusted, "%Y-%m-%d %H:%M:%S +00:00");
end if;
else
if Quote then
return Image (Adjusted, "'%Y-%m-%d %H:%M:%S'");
else
return Image (Adjusted, "%Y-%m-%d %H:%M:%S");
end if;
end if;
else
return "NULL";
end if;
end Time_To_SQL;
-----------------
-- Date_To_SQL --
-----------------
function Date_To_SQL
(Self : Formatter'Class;
Value : Ada.Calendar.Time;
Quote : Boolean) return String
is
pragma Unreferenced (Self);
Adjusted : Time;
begin
-- Value is always considered as GMT, which is what we store in the
-- database. Unfortunately, GNAT.Calendar.Time_IO converts that back to
-- local time.
if Value /= GNAT.Calendar.No_Time then
Adjusted := Value - Duration (UTC_Time_Offset (Value)) * 60.0;
if Quote then
return Image (Adjusted, "'%Y-%m-%d'");
else
return Image (Adjusted, "%Y-%m-%d");
end if;
else
return "NULL";
end if;
end Date_To_SQL;
-------------------
-- Decimal_To_SQL --
-------------------
function Money_To_SQL
(Self : Formatter'Class;
Value : T_Money;
Quote : Boolean) return String
is
pragma Unreferenced (Quote);
begin
return Self.Money_Image (Value);
end Money_To_SQL;
-----------------
-- Money_Image --
-----------------
function Money_Image (Self : Formatter; Value : T_Money) return String is
pragma Unreferenced (Self);
Img : constant String := T_Money'Image (Value);
begin
if Img (Img'First) = ' ' then
return Img (Img'First + 1 .. Img'Last);
else
return Img;
end if;
end Money_Image;
-----------------
-- Json_To_SQL --
-----------------
function Json_To_SQL
(Self : Formatter'Class; Value : String; Quote : Boolean) return String
is
pragma Unreferenced (Self, Quote);
begin
if Trim (Value, Ada.Strings.Both) = "" then
return "null";
-- Json null, not to be confused with SQL NULL.
else
return Value;
end if;
end Json_To_SQL;
-----------------
-- XML_To_SQL --
-----------------
function XML_To_SQL
(Self : Formatter'Class; Value : String; Quote : Boolean) return String
is
pragma Unreferenced (Self, Quote);
begin
if Trim (Value, Ada.Strings.Both) = "" then
return "<null/>";
-- XML null, not to be confused with SQL NULL.
else
return Value;
end if;
end XML_To_SQL;
-------------------
-- String_To_SQL --
-------------------
function String_To_SQL
(Self : Formatter'Class; Value : String; Quote : Boolean) return String
is
begin
return String_Image (Self, Value, Quote);
end String_To_SQL;
------------------
-- String_Image --
------------------
function String_Image
(Self : Formatter;
Value : String;
Quote : Boolean) return String
is
-- This function used to quote the backslashes as well. However, this
-- is incorrect, since the SQL backends will already take each
-- character on its own. For instance, to insert a newline with psql
-- we need to
-- SELECT 'a\n' || chr(13) || 'e';
-- This outputs a string with 5 characters.
-- Same with sqlite.
pragma Unreferenced (Self);
Num_Of_Apostrophes : constant Natural :=
Ada.Strings.Fixed.Count (Value, "'");
begin
if not Quote then
return Value;
end if;
if Num_Of_Apostrophes = 0 then
return "'" & Value & "'";
end if;
declare
New_Str : String
(Value'First .. Value'Last + Num_Of_Apostrophes + 2);
Index : Natural := New_Str'First + 1;
begin
New_Str (New_Str'First) := ''';
New_Str (New_Str'Last) := ''';
for I in Value'Range loop
if Value (I) = ''' then
New_Str (Index .. Index + 1) := "''";
Index := Index + 1;
else
New_Str (Index) := Value (I);
end if;
Index := Index + 1;
end loop;
return New_Str;
end;
end String_Image;
----------------------
-- Parameter_String --
----------------------
function Parameter_String
(Self : Formatter;
Index : Positive;
Typ : Parameter_Type) return String
is
pragma Unreferenced (Self, Index, Typ);
begin
return "?";
end Parameter_String;
end GNATCOLL.SQL_Impl;
|