/usr/lib/libreoffice/share/basic/Access2Base/DoCmd.xba is in libreoffice-base 1:4.3.3-2+deb8u11.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535 536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576 577 578 579 580 581 582 583 584 585 586 587 588 589 590 591 592 593 594 595 596 597 598 599 600 601 602 603 604 605 606 607 608 609 610 611 612 613 614 615 616 617 618 619 620 621 622 623 624 625 626 627 628 629 630 631 632 633 634 635 636 637 638 639 640 641 642 643 644 645 646 647 648 649 650 651 652 653 654 655 656 657 658 659 660 661 662 663 664 665 666 667 668 669 670 671 672 673 674 675 676 677 678 679 680 681 682 683 684 685 686 687 688 689 690 691 692 693 694 695 696 697 698 699 700 701 702 703 704 705 706 707 708 709 710 711 712 713 714 715 716 717 718 719 720 721 722 723 724 725 726 727 728 729 730 731 732 733 734 735 736 737 738 739 740 741 742 743 744 745 746 747 748 749 750 751 752 753 754 755 756 757 758 759 760 761 762 763 764 765 766 767 768 769 770 771 772 773 774 775 776 777 778 779 780 781 782 783 784 785 786 787 788 789 790 791 792 793 794 795 796 797 798 799 800 801 802 803 804 805 806 807 808 809 810 811 812 813 814 815 816 817 818 819 820 821 822 823 824 825 826 827 828 829 830 831 832 833 834 835 836 837 838 839 840 841 842 843 844 845 846 847 848 849 850 851 852 853 854 855 856 857 858 859 860 861 862 863 864 865 866 867 868 869 870 871 872 873 874 875 876 877 878 879 880 881 882 883 884 885 886 887 888 889 890 891 892 893 894 895 896 897 898 899 900 901 902 903 904 905 906 907 908 909 910 911 912 913 914 915 916 917 918 919 920 921 922 923 924 925 926 927 928 929 930 931 932 933 934 935 936 937 938 939 940 941 942 943 944 945 946 947 948 949 950 951 952 953 954 955 956 957 958 959 960 961 962 963 964 965 966 967 968 969 970 971 972 973 974 975 976 977 978 979 980 981 982 983 984 985 986 987 988 989 990 991 992 993 994 995 996 997 998 999 1000 1001 1002 1003 1004 1005 1006 1007 1008 1009 1010 1011 1012 1013 1014 1015 1016 1017 1018 1019 1020 1021 1022 1023 1024 1025 1026 1027 1028 1029 1030 1031 1032 1033 1034 1035 1036 1037 1038 1039 1040 1041 1042 1043 1044 1045 1046 1047 1048 1049 1050 1051 1052 1053 1054 1055 1056 1057 1058 1059 1060 1061 1062 1063 1064 1065 1066 1067 1068 1069 1070 1071 1072 1073 1074 1075 1076 1077 1078 1079 1080 1081 1082 1083 1084 1085 1086 1087 1088 1089 1090 1091 1092 1093 1094 1095 1096 1097 1098 1099 1100 1101 1102 1103 1104 1105 1106 1107 1108 1109 1110 1111 1112 1113 1114 1115 1116 1117 1118 1119 1120 1121 1122 1123 1124 1125 1126 1127 1128 1129 1130 1131 1132 1133 1134 1135 1136 1137 1138 1139 1140 1141 1142 1143 1144 1145 1146 1147 1148 1149 1150 1151 1152 1153 1154 1155 1156 1157 1158 1159 1160 1161 1162 1163 1164 1165 1166 1167 1168 1169 1170 1171 1172 1173 1174 1175 1176 1177 1178 1179 1180 1181 1182 1183 1184 1185 1186 1187 1188 1189 1190 1191 1192 1193 1194 1195 1196 1197 1198 1199 1200 1201 1202 1203 1204 1205 1206 1207 1208 1209 1210 1211 1212 1213 1214 1215 1216 1217 1218 1219 1220 1221 1222 1223 1224 1225 1226 1227 1228 1229 1230 1231 1232 1233 1234 1235 1236 1237 1238 1239 1240 1241 1242 1243 1244 1245 1246 1247 1248 1249 1250 1251 1252 1253 1254 1255 1256 1257 1258 1259 1260 1261 1262 1263 1264 1265 1266 1267 1268 1269 1270 1271 1272 1273 1274 1275 1276 1277 1278 1279 1280 1281 1282 1283 1284 1285 1286 1287 1288 1289 1290 1291 1292 1293 1294 1295 1296 1297 1298 1299 1300 1301 1302 1303 1304 1305 1306 1307 1308 1309 1310 1311 1312 1313 1314 1315 1316 1317 1318 1319 1320 1321 1322 1323 1324 1325 1326 1327 1328 1329 1330 1331 1332 1333 1334 1335 1336 1337 1338 1339 1340 1341 1342 1343 1344 1345 1346 1347 1348 1349 1350 1351 1352 1353 1354 1355 1356 1357 1358 1359 1360 1361 1362 1363 1364 1365 1366 1367 1368 1369 1370 1371 1372 1373 1374 1375 1376 1377 1378 1379 1380 1381 1382 1383 1384 1385 1386 1387 1388 1389 1390 1391 1392 1393 1394 1395 1396 1397 1398 1399 1400 1401 1402 1403 1404 1405 1406 1407 1408 1409 1410 1411 1412 1413 1414 1415 1416 1417 1418 1419 1420 1421 1422 1423 1424 1425 1426 1427 1428 1429 1430 1431 1432 1433 1434 1435 1436 1437 1438 1439 1440 1441 1442 1443 1444 1445 1446 1447 1448 1449 1450 1451 1452 1453 1454 1455 1456 1457 1458 1459 1460 1461 1462 1463 1464 1465 1466 1467 1468 1469 1470 1471 1472 1473 1474 1475 1476 1477 1478 1479 1480 1481 1482 1483 1484 1485 1486 1487 1488 1489 1490 1491 1492 1493 1494 1495 1496 1497 1498 1499 1500 1501 1502 1503 1504 1505 1506 1507 1508 1509 1510 1511 1512 1513 1514 1515 1516 1517 1518 1519 1520 1521 1522 1523 1524 1525 1526 1527 1528 1529 1530 1531 1532 1533 1534 1535 1536 1537 1538 1539 1540 1541 1542 1543 1544 1545 1546 1547 1548 1549 1550 1551 1552 1553 1554 1555 1556 1557 1558 1559 1560 1561 1562 1563 1564 1565 1566 1567 1568 1569 1570 1571 1572 1573 1574 1575 1576 1577 1578 1579 1580 1581 1582 1583 1584 1585 1586 1587 1588 1589 1590 1591 1592 1593 1594 1595 1596 1597 1598 1599 1600 1601 1602 1603 1604 1605 1606 1607 1608 1609 1610 1611 1612 1613 1614 1615 1616 1617 1618 1619 1620 1621 1622 1623 1624 1625 1626 1627 1628 1629 1630 1631 1632 1633 1634 1635 1636 1637 1638 1639 1640 1641 1642 1643 1644 1645 1646 1647 1648 1649 1650 1651 1652 1653 1654 1655 1656 1657 1658 1659 1660 1661 1662 1663 1664 1665 1666 1667 1668 1669 1670 1671 1672 1673 1674 1675 1676 1677 1678 1679 1680 1681 1682 1683 1684 1685 1686 1687 1688 1689 1690 1691 1692 1693 1694 1695 1696 1697 1698 1699 1700 1701 1702 1703 1704 1705 1706 1707 1708 1709 1710 1711 1712 1713 1714 1715 1716 1717 1718 1719 1720 1721 1722 1723 1724 1725 1726 1727 1728 1729 1730 1731 1732 1733 1734 1735 1736 1737 1738 1739 1740 1741 1742 1743 1744 1745 1746 1747 1748 1749 1750 1751 1752 1753 1754 1755 1756 1757 1758 1759 1760 1761 1762 1763 1764 1765 1766 1767 1768 1769 1770 1771 1772 1773 1774 1775 1776 1777 1778 1779 1780 1781 1782 1783 1784 1785 1786 1787 1788 1789 1790 1791 1792 1793 1794 1795 1796 1797 1798 1799 1800 1801 1802 1803 1804 1805 1806 1807 1808 1809 1810 1811 1812 1813 1814 1815 1816 1817 1818 1819 1820 1821 1822 1823 1824 1825 1826 1827 1828 1829 1830 1831 1832 1833 1834 1835 1836 1837 1838 1839 1840 1841 1842 1843 1844 1845 1846 1847 1848 1849 1850 1851 1852 1853 1854 1855 1856 1857 1858 1859 1860 1861 1862 1863 1864 1865 1866 1867 1868 1869 1870 1871 1872 1873 1874 1875 1876 1877 1878 1879 1880 1881 1882 1883 1884 1885 1886 1887 1888 1889 1890 1891 1892 1893 1894 1895 1896 1897 1898 1899 1900 1901 1902 1903 1904 1905 1906 1907 1908 1909 1910 1911 1912 1913 1914 1915 1916 1917 1918 1919 1920 1921 1922 1923 1924 1925 1926 1927 1928 1929 1930 1931 1932 1933 1934 1935 1936 1937 1938 1939 1940 1941 1942 1943 1944 1945 1946 1947 1948 1949 1950 1951 1952 1953 1954 1955 1956 1957 1958 1959 1960 1961 1962 1963 1964 1965 1966 1967 1968 1969 1970 1971 1972 1973 1974 1975 1976 1977 1978 1979 1980 1981 1982 1983 1984 1985 1986 1987 1988 1989 1990 1991 1992 1993 1994 1995 1996 1997 1998 1999 2000 2001 2002 2003 2004 2005 2006 2007 2008 2009 2010 2011 2012 2013 2014 2015 2016 2017 2018 2019 2020 2021 2022 2023 2024 2025 2026 2027 2028 2029 2030 2031 2032 2033 2034 2035 2036 2037 2038 2039 2040 2041 2042 2043 2044 2045 2046 2047 2048 2049 2050 2051 2052 2053 2054 2055 2056 2057 2058 2059 2060 2061 2062 2063 2064 2065 2066 2067 2068 2069 2070 2071 2072 2073 2074 2075 2076 2077 2078 2079 2080 2081 2082 2083 2084 2085 2086 2087 2088 2089 2090 2091 2092 2093 2094 2095 2096 2097 2098 2099 2100 2101 2102 2103 2104 2105 2106 2107 2108 2109 2110 2111 2112 2113 2114 2115 2116 2117 2118 2119 2120 2121 2122 2123 2124 2125 2126 2127 2128 2129 2130 2131 2132 2133 2134 2135 2136 2137 2138 2139 2140 2141 2142 2143 2144 2145 2146 2147 2148 2149 2150 2151 2152 2153 2154 2155 2156 2157 2158 2159 2160 2161 2162 2163 2164 2165 2166 2167 2168 2169 2170 2171 2172 2173 2174 2175 2176 2177 2178 2179 2180 2181 2182 2183 2184 2185 2186 2187 2188 2189 2190 2191 2192 2193 2194 2195 2196 2197 2198 2199 2200 2201 2202 2203 2204 2205 2206 2207 2208 2209 2210 2211 2212 2213 2214 2215 2216 2217 2218 2219 2220 2221 2222 2223 2224 2225 2226 2227 2228 2229 2230 2231 2232 2233 2234 2235 2236 2237 2238 2239 2240 2241 2242 2243 2244 2245 2246 2247 2248 2249 2250 2251 2252 2253 2254 2255 2256 2257 2258 2259 2260 2261 2262 2263 2264 2265 2266 2267 2268 2269 2270 2271 2272 2273 2274 | <?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE script:module PUBLIC "-//OpenOffice.org//DTD OfficeDocument 1.0//EN" "module.dtd">
<script:module xmlns:script="http://openoffice.org/2000/script" script:name="DoCmd" script:language="StarBasic">REM =======================================================================================================================
REM === The Access2Base library is a part of the LibreOffice project. ===
REM === Full documentation is available on http://www.access2base.com ===
REM =======================================================================================================================
Option Explicit
Type _FindParams
FindRecord As Integer ' Set to 1 at first invocation of FindRecord
FindWhat As Variant
Match As Integer
MatchCase As Boolean
Search As Integer
SearchAsFormatted As Boolean ' Must be False
FindFirst As Boolean
OnlyCurrentField As Integer
Form As String ' Shortcut
GridControl As String ' Shortcut
Target As String ' Shortcut
LastRow As Long ' Last row explored - 0 = before first
LastColumn As Integer ' Last column explored - 0 ... N-1 index in next arrays; 0 if OnlyCurrentField = acCurrent
ColumnNames() As String ' Array of column names in grid with boundfield and of same type as FindWhat
ResultSetIndex() As Integer ' Array of column numbers in ResultSet
End Type
'Global _gFind As _FindParams
Type _Window
Frame As Object ' com.sun.star.comp.framework.Frame
_Name As String ' Object Name
WindowType As Integer ' One of the object types
End Type
REM VBA allows call to actions with missing arguments e.g. OpenForm("aaa",,"[field]=2")
REM in StarBasic IsMissing requires Variant parameters
REM -----------------------------------------------------------------------------------------------------------------------
Public Function mClose(Optional ByVal pvObjectType As Variant _
, Optional ByVal pvObjectName As Variant _
, Optional ByVal pvSave As Variant _
) As Boolean
If _ErrorHandler() Then On Local Error Goto Error_Function
Const cstThisSub = "Close"
Utils._SetCalledSub(cstThisSub)
mClose = False
If IsMissing(pvObjectType) Or IsMissing(pvObjectName) Then Call _TraceArguments()
If IsMissing(pvSave) Then pvSave = acSavePrompt
If Not (Utils._CheckArgument(pvObjectType, 1, Utils._AddNumeric(), _
Array(acTable, acQuery, acForm, acReport)) _
And Utils._CheckArgument(pvObjectName, 2, vbString) _
And Utils._CheckArgument(pvSave, 3, Utils._AddNumeric(), Array(acSavePrompt)) _
) Then Goto Exit_Function
Dim sObjects() As String, sObjectName As String, oController As Object, oObject As Object
Dim i As Integer, bFound As Boolean, lComponent As Long
Dim oDatabase As Object
Set oDatabase = Application._CurrentDb()
If oDatabase._DbConnect <> DBCONNECTBASE Then Goto Error_NotApplicable
' Check existence of object and find its exact (case-sensitive) name
Select Case pvObjectType
Case acForm
sObjects = oDatabase.Document.getFormDocuments.ElementNames()
lComponent = com.sun.star.sdb.application.DatabaseObject.FORM
Case acTable
sObjects = oDatabase.Connection.getTables.ElementNames()
lComponent = com.sun.star.sdb.application.DatabaseObject.TABLE
Case acQuery
sObjects = oDatabase.Connection.getQueries.ElementNames()
lComponent = com.sun.star.sdb.application.DatabaseObject.QUERY
Case acReport
sObjects = oDatabase.Document.getReportDocuments.ElementNames()
lComponent = com.sun.star.sdb.application.DatabaseObject.REPORT
End Select
bFound = False
For i = 0 To UBound(sObjects)
If UCase(pvObjectName) = UCase(sObjects(i)) Then
sObjectName = sObjects(i)
bFound = True
Exit For
End If
Next i
If Not bFound Then Goto Trace_NotFound
Select Case pvObjectType
Case acForm
Set oController = oDatabase.Document.getFormDocuments.getByName(sObjectName)
mClose = oController.close()
Case acTable, acQuery ' Not optimal but it works !!
Set oController = oDatabase.Document.CurrentController
Set oObject = oController.loadComponent(lComponent, sObjectName, False)
oObject.frame.close(False)
mClose = True
Case acReport
Set oController = oDatabase.Document.getReportDocuments.getByName(sObjectName)
mClose = oController.close()
End Select
Exit_Function:
Set oObject = Nothing
Set oController = Nothing
Utils._ResetCalledSub(cstThisSub)
Exit Function
Error_Function:
TraceError(TRACEABORT, Err, "Close", Erl)
GoTo Exit_Function
Trace_Error:
TraceError(TRACEFATAL, ERRCLOSEOBJECT, Utils._CalledSub(), 0, , Array(_GetLabel(Array("Table", "Query", "Form", "Report")(pvObjectType)), pvObjectName))
Goto Exit_Function
Trace_NotFound:
TraceError(TRACEFATAL, ERROBJECTNOTFOUND, Utils._CalledSub(), 0, , Array(_GetLabel(Array("Table", "Query", "Form", "Report")(pvObjectType)), pvObjectName))
Goto Exit_Function
Error_NotApplicable:
TraceError(TRACEFATAL, ERRMETHOD, Utils._CalledSub(), 0, 1, cstThisSub)
Goto Exit_Function
End Function ' (m)Close V1.1.0
REM -----------------------------------------------------------------------------------------------------------------------
Public Function CopyObject(ByVal Optional pvDestinationDatabase As Variant _
, ByVal Optional pvNewName As Variant _
, ByVal Optional pvSourceType As Variant _
, ByVal Optional pvSourceName As Variant _
) As Boolean
' Copies tables and queries into identical (new) objects
If _ErrorHandler() Then On Local Error Goto Error_Function
Const cstThisSub = "CopyObject"
Utils._SetCalledSub(cstThisSub)
CopyObject = False
If IsMissing(pvDestinationDatabase) Then pvDestinationDatabase = ""
If Not Utils._CheckArgument(pvDestinationDatabase, 1, vbString, "") Then Goto Exit_Function
If IsMissing(pvNewName) Then Call _TraceArguments()
If Not Utils._CheckArgument(pvNewName, 2, vbString) Then Goto Exit_Function
If IsMissing(pvSourceType) Then Call _TraceArguments()
If Not Utils._CheckArgument(pvSourceType, 1, Utils._AddNumeric(), Array(acQuery, acTable) _
) Then Goto Exit_Function
If IsMissing(pvSourceName) Then Call _TraceArguments()
If Not Utils._CheckArgument(pvSourceName, 2, vbString) Then Goto Exit_Function
Dim oSource As Object, oTarget As Object, oDatabase As Object
Dim oSourceTable As Object, oSourceColumns As Object, oSourceCol As Object, oTargetCol As Object
Dim oSourceKeys As Object, oSourceKey As Object, oTargetKey As Object
Dim i As Integer, j As Integer, sSql As String, vPrimaryKeys() As Variant
Set oDatabase = Application._CurrentDb()
With oDatabase
If ._DbConnect <> DBCONNECTBASE Then Goto Error_NotApplicable
Select Case pvSourceType
Case acQuery
Set oSource = .QueryDefs(pvSourceName, True)
If IsNull(oSource) Then Goto Error_NotFound
Set oTarget = .QueryDefs(pvNewName, True)
If Not IsNull(oTarget) Then .Connection.getQueries.dropByName(oTarget.Name) ' a query with same name exists already ... drop it
If oSource.Query.EscapeProcessing Then
Set oTarget = .CreateQueryDef(pvNewName, oSource.SQL)
Else
Set oTarget = .CreateQueryDef(pvNewName, oSource.SQL, dbSQLPassThrough)
End If
' Save .odb document
.Document.store()
Case acTable
Set oSource = .TableDefs(pvSourceName, True)
If IsNull(oSource) Then Goto Error_NotFound
Set oTarget = .TableDefs(pvNewName, True)
If Not IsNull(oTarget) Then .Connection.getTables.dropByName(oTarget.Name) ' a table with same name exists already ... drop it
' Copy source table columns
Set oSourceTable = oSource.Table
Set oTarget = .Connection.getTables.createDataDescriptor
oTarget.Description = oSourceTable.Description
oTarget.Name = pvNewName
oTarget.Type = oSourceTable.Type
Set oSourceColumns = oSourceTable.Columns
Set oTargetCol = oTarget.Columns.createDataDescriptor
For i = 0 To oSourceColumns.getCount() - 1
' Append each individual column to the table descriptor
Set oSourceCol = oSourceColumns.getByIndex(i)
oTargetCol.Name = oSourceCol.Name
oTargetCol.ControlDefault = oSourceCol.ControlDefault
oTargetCol.Description = oSourceCol.Description
oTargetCol.FormatKey = oSourceCol.FormatKey
oTargetCol.HelpText = oSourceCol.HelpText
oTargetCol.Hidden = oSourceCol.Hidden
oTargetCol.IsCurrency = oSourceCol.IsCurrency
oTargetCol.IsNullable = oSourceCol.IsNullable
oTargetCol.Precision = oSourceCol.Precision
oTargetCol.Scale = oSourceCol.Scale
oTargetCol.Type = oSourceCol.Type
oTargetCol.TypeName = oSourceCol.TypeName
oTarget.Columns.appendByDescriptor(oTargetCol)
Next i
' Copy keys
Set oSourceKeys = oSourceTable.Keys
Set oTargetKey = oTarget.Keys.createDataDescriptor()
For i = 0 To oSourceKeys.getCount() - 1
' Append each key to table descriptor
Set oSourceKey = oSourceKeys.getByIndex(i)
oTargetKey.DeleteRule = oSourceKey.DeleteRule
oTargetKey.Name = oSourceKey.Name
oTargetKey.ReferencedTable = oSourceKey.ReferencedTable
oTargetKey.Type = oSourceKey.Type
' If oSourceKey.Type = com.sun.star.sdbcx.KeyType.PRIMARY Then vPrimaryKeys = oSourceKey.Columns.getElementNames()
oTargetKey.UpdateRule = oSourceKey.UpdateRule
Set oTargetCol = oTargetKey.Columns.createDataDescriptor()
For j = 0 To oSourceKey.Columns.getCount() - 1
Set oSourceCol = oSourceKey.Columns.getByIndex(j)
oTargetCol.Name = oSourceCol.Name
oTargetCol.Description = oSourceCol.Description
oTargetCol.IsCurrency = oSourceCol.IsCurrency
oTargetCol.IsNullable = oSourceCol.IsNullable
oTargetCol.Precision = oSourceCol.Precision
oTargetCol.Scale = oSourceCol.Scale
oTargetCol.Type = oSourceCol.Type
oTargetCol.TypeName = oSourceCol.TypeName
oTargetKey.Columns.appendByDescriptor(oTargetCol)
Next j
oTarget.Keys.appendByDescriptor(oTargetKey)
Next i
' Duplicate table whole design
.Connection.getTables.appendByDescriptor(oTarget)
' Copy data
sSql = "INSERT INTO [" & pvNewName & "] SELECT [" & oSource.Name & "].* FROM [" & oSource.Name & "]"
DoCmd.RunSQL(sSql, dbSQLPassthrough)
Case Else
End Select
End With
CopyObject = True
Exit_Function:
Utils._ResetCalledSub(cstThisSub)
Set oSourceCol = Nothing
Set oSourceKey = Nothing
Set oSourceKeys = Nothing
Set oSource = Nothing
Set oSourceTable = Nothing
Set oSourceColumns = Nothing
Set oTargetCol = Nothing
Set oTargetKey = Nothing
Set oTarget = Nothing
Exit Function
Error_NotFound:
TraceError(TRACEFATAL, ERROBJECTNOTFOUND, Utils._CalledSub(), 0, , Array(Iif(pvSourceType = acQuery, _GetLabel("QUERY"), _GetLabel("TABLE")), pvSourceName))
Goto Exit_Function
Error_NotApplicable:
TraceError(TRACEFATAL, ERRMETHOD, Utils._CalledSub(), 0, 1, cstThisSub)
Goto Exit_Function
Error_Function:
TraceError(TRACEABORT, Err, cstThisSub, Erl)
GoTo Exit_Function
End Function ' CopyObject V1.1.0
REM -----------------------------------------------------------------------------------------------------------------------
Public Function FindNext() As Boolean
' Must be called after a FindRecord
' Execute instructions set in FindRecord object
If _ErrorHandler() Then On Local Error Goto Error_Function
FindNext = False
Utils._SetCalledSub("FindNext")
Dim ofForm As Object, ocGrid As Object
Dim i As Integer, lInitialRow As Long, lFindRow As Long
Dim bFound As Boolean, b2ndRound As Boolean, bStop As Boolean
Dim vFindValue As Variant, oFindrecord As Object
Set oFindRecord = _A2B_.FindRecord
With oFindRecord
If .FindRecord = 0 Then Goto Error_FindRecord
.FindRecord = 0
Set ofForm = getObject(.Form)
If ofForm._Type = OBJCONTROL Then Set ofForm = ofForm.Form ' Bug Tombola
Set ocGrid = getObject(.GridControl)
' Move cursor to the initial row. Operation based on last FindRecord, not on user interactions done inbetween
If ofForm.DatabaseForm.RowCount <= 0 then Goto Exit_Function ' Dataset is empty
lInitialRow = .LastRow ' Used if Search = acSearchAll
bFound = False
lFindRow = .LastRow
b2ndRound = False
Do
' Last column ? Go to next row
If .LastColumn >= UBound(.ColumnNames) Then
bStop = False
If ofForm.DatabaseForm.isAfterLast() And .Search = acUp Then
ofForm.DatabaseForm.last()
ElseIf ofForm.DatabaseForm.isLast() And .Search = acSearchAll Then
ofForm.DatabaseForm.first()
b2ndRound = True
ElseIf ofForm.DatabaseForm.isBeforeFirst() And (.Search = acDown Or .Search = acSearchAll) Then
ofForm.DatabaseForm.first()
ElseIf ofForm.DatabaseForm.isFirst() And .search = acUp Then
ofForm.DatabaseForm.beforeFirst()
bStop = True
ElseIf ofForm.DatabaseForm.isLast() And .search = acDown Then
ofForm.DatabaseForm.afterLast()
bStop = True
ElseIf .Search = acUp Then
ofForm.DatabaseForm.previous()
Else
ofForm.DatabaseForm.next()
End If
lFindRow = ofForm.DatabaseForm.getRow()
If bStop Or (.Search = acSearchAll And lFindRow >= lInitialRow And b2ndRound) Then
ofForm.DatabaseForm.absolute(lInitialRow)
Exit Do
End If
.LastColumn = 0
Else
.LastColumn = .LastColumn + 1
End If
' Examine column contents
If .LastColumn <= UBound(.ColumnNames) Then
For i = .LastColumn To UBound(.ColumnNames)
vFindValue = Utils._getResultSetColumnValue(ofForm.DatabaseForm.createResultSet(), .ResultSetIndex(i))
Select Case VarType(.FindWhat)
Case vbDate, vbInteger, vbLong, vbSingle, vbDouble, vbCurrency, vbBigint, vbDecimal
bFound = ( .FindWhat = vFindValue )
Case vbString
Select Case .Match
Case acStart
If .MatchCase Then
bFound = ( Left(.FindWhat, Len(.FindWhat)) = vFindValue )
Else
bFound = ( UCase(Left(.FindWhat, Len(.FindWhat))) = UCase(vFindValue) )
End If
Case acAnyWhere
If .MatchCase Then
bFound = ( InStr(1, vFindValue, .FindWhat, 0) > 0 )
Else
bFound = ( InStr(vFindValue, .FindWhat) > 0 )
End If
Case acEntire
If .MatchCase Then
bFound = ( .FindWhat = vFindValue )
Else
bFound = ( UCase(.FindWhat) = UCase(vFindValue) )
End If
End Select
End Select
If bFound Then
.LastColumn = i
Exit For
End If
Next i
End If
Loop While Not bFound
.LastRow = lFindRow
If bFound Then
ocGrid.Controls(.ColumnNames(.LastColumn)).setFocus()
.FindRecord = 1
FindNext = True
End If
End With
Exit_Function:
Utils._ResetCalledSub("FindNext")
Exit Function
Error_Function:
TraceError(TRACEABORT, Err, "FindNext", Erl)
GoTo Exit_Function
Error_FindRecord:
TraceError(TRACEERRORS, ERRFINDRECORD, Utils._CalledSub(), 0)
Goto Exit_Function
End Function ' FindNext V1.1.0
REM -----------------------------------------------------------------------------------------------------------------------
Public Function FindRecord(Optional ByVal pvFindWhat As Variant _
, Optional ByVal pvMatch As Variant _
, Optional ByVal pvMatchCase As Variant _
, Optional ByVal pvSearch As Variant _
, Optional ByVal pvSearchAsFormatted As Variant _
, Optional ByVal pvTargetedField As Variant _
, Optional ByVal pvFindFirst As Variant _
) As Boolean
'Find a value (string or other) in the underlying data of a gridcontrol
'Search in all columns or only in one single control
' see pvTargetedField = acAll or acCurrent
' pvTargetedField may also be a shortcut to a GridControl or one of its subcontrols
'Initialize _Findrecord structure in Database root and call FindNext() to set cursor on found value
If _ErrorHandler() Then On Local Error Goto Error_Function
FindRecord = False
Utils._SetCalledSub("FindRecord")
If IsMissing(pvFindWhat) Or pvFindWhat = "" Then Call _TraceArguments()
If IsMissing(pvMatch) Then pvMatch = acEntire
If IsMissing(pvMatchCase) Then pvMatchCase = False
If IsMissing(pvSearch) Then pvSearch = acSearchAll
If IsMissing(pvSearchAsFormatted) Then pvSearchAsFormatted = False ' Anyway only False supported
If IsMissing(pvTargetedField) Then pvTargetedField = acCurrent
If IsMissing(pvFindFirst) Then pvFindFirst = True
If Not (Utils._CheckArgument(pvFindWhat, 1, Utils._AddNumeric(Array(vbString, vbDate))) _
And Utils._CheckArgument(pvMatch, 2, Utils._AddNumeric(), Array(acAnywhere, acEntire, acStart)) _
And Utils._CheckArgument(pvMatchCase, 3, vbBoolean) _
And Utils._CheckArgument(pvSearch, 4, Utils._AddNumeric(), Array(acDown, acSearchAll, acUp)) _
And Utils._CheckArgument(pvSearchAsFormatted, 5, vbBoolean, Array(False)) _
And Utils._CheckArgument(pvTargetedField, 6, Utils._AddNumeric(vbString)) _
And Utils._CheckArgument(pvFindFirst, 7, vbBoolean) _
) Then Exit Function
If VarType(pvTargetedField) <> vbString Then
If Not Utils._CheckArgument(pvTargetedField, 6, Utils._AddNumeric(), Array(acAll, acCurrent)) Then Exit Function
End If
Dim ocTarget As Object, i As Integer, j As Integer, vNames() As Variant, iCount As Integer, vIndexes() As Variant
Dim vColumn As Variant, vDataField As Variant, ofParentForm As Variant, oColumns As Object, vParentGrid As Object
Dim bFound As Boolean, ocGridControl As Object, iFocus As Integer
Dim oFindRecord As _FindParams
With oFindRecord
.FindRecord = 0
.FindWhat = pvFindWhat
.Match = pvMatch
.MatchCase = pvMatchCase
.Search = pvSearch
.SearchAsFormatted = pvSearchAsFormatted
.FindFirst = pvFindFirst
' Determine target
' Either: pvTargetedField = Grid => search all fields
' pvTargetedField = Control in Grid => search only in that column
' pvTargetedField = acAll or acCurrent => determine focus
Select Case True
Case VarType(pvTargetedField) = vbString
Set ocTarget = getObject(pvTargetedField)
If ocTarget.SubType = CTLGRIDCONTROL Then
.OnlyCurrentField = acAll
.GridControl = ocTarget._Shortcut
.Target = .GridControl
ofParentForm = getObject(_getUpperShortcut(ocTarget._Shortcut, ocTarget._Name))
If IsNull(ofParentForm.DatabaseForm) Then Goto Error_DatabaseForm
Set oColumns = ofParentForm.DatabaseForm.createResultSet().Columns
iCount = -1
For i = 0 To ocTarget.ControlModel.Count - 1
Set vColumn = ocTarget.ControlModel.getByIndex(i)
Set vDataField = vColumn.BoundField ' examine field type
If Not IsNull(vDataField) Then
If _CheckColumnType(pvFindWhat, vDataField) Then
iCount = iCount + 1
ReDim Preserve vNames(0 To iCount)
vNames(iCount) = vColumn.Name
ReDim Preserve vIndexes(0 To iCount)
For j = 0 To oColumns.Count - 1
If vDataField.Name = oColumns.ElementNames(j) Then
vIndexes(iCount) = j + 1
Exit For
End If
Next j
End If
End If
Next i
ElseIf ocTarget._Type = OBJCONTROL Then ' Control within a grid tbc
If IsNull(ocTarget.ControlModel.BoundField) Then Goto Error_Target ' Control MUST be bound to a database record or query
' BoundField is in ControlModel, thanks PASTIM !
.OnlyCurrentField = acCurrent
vParentGrid = getObject(_getUpperShortcut(ocTarget._Shortcut, ocTarget._Name))
If vParentGrid.SubType <> CTLGRIDCONTROL Then Goto Error_Target
.GridControl = vParentGrid._Shortcut
ofParentForm = getObject(_getUpperShortcut(vParentGrid._Shortcut, vParentGrid._Name))
If ofParentForm._Type = OBJCONTROL Then Set ofParentForm = ofParentForm.Form ' Bug Tombola
If IsNull(ofParentForm.DatabaseForm) Then Goto Error_DatabaseForm
.Target = ocTarget._Shortcut
Set vDataField = ocTarget.ControlModel.BoundField
If Not _CheckColumnType(pvFindWhat, vDataField) Then Goto Error_Target
ReDim vNames(0), vIndexes(0)
vNames(0) = ocTarget._Name
Set oColumns = ofParentForm.DatabaseForm.createResultSet().Columns
For j = 0 To oColumns.Count - 1
If vDataField.Name = oColumns.ElementNames(j) Then
vIndexes(0) = j + 1
Exit For
End If
Next j
End If
Case Else ' Determine focus
iCount = Application.Forms()._Count
If iCount = 0 Then Goto Error_ActiveForm
bFound = False
For i = 0 To iCount - 1 ' Determine form having the focus
Set ofParentForm = Application.Forms(i)
If ofParentForm.Component.CurrentController.Frame.IsActive() Then
bFound = True
Exit For
End If
Next i
If Not bFound Then Goto Error_ActiveForm
If IsNull(ofParentForm.DatabaseForm) Then Goto Error_DatabaseForm
iCount = ofParentForm.Controls().Count
bFound = False
For i = 0 To iCount - 1
Set ocGridControl = ofParentForm.Controls(i)
If ocGridControl.SubType = CTLGRIDCONTROL Then
bFound = True
Exit For
End If
Next i
If Not bFound Then Goto Error_NoGrid
.GridControl= ocGridControl._Shortcut
iFocus = -1
iFocus = ocGridControl.ControlView.getCurrentColumnPosition() ' Deprecated but no alternative found !!
If pvTargetedField = acAll Or iFocus < 0 Or iFocus >= ocGridControl.ControlModel.Count Then ' Has a control within the grid the focus ? NO
.OnlyCurrentField = acAll
Set oColumns = ofParentForm.DatabaseForm.createResultSet().Columns
iCount = -1
For i = 0 To ocGridControl.ControlModel.Count - 1
Set vColumn = ocGridControl.ControlModel.getByIndex(i)
Set vDataField = vColumn.BoundField ' examine field type
If Not IsNull(vDataField) Then
If _CheckColumnType(pvFindWhat, vDataField) Then
iCount = iCount + 1
ReDim Preserve vNames(0 To iCount)
vNames(iCount) = vColumn.Name
ReDim Preserve vIndexes(0 To iCount)
For j = 0 To oColumns.Count - 1
If vDataField.Name = oColumns.ElementNames(j) Then
vIndexes(iCount) = j + 1
Exit For
End If
Next j
End If
End If
Next i
Else ' Has a control within the grid the focus ? YES
.OnlyCurrentField = acCurrent
Set vColumn = ocGridControl.ControlModel.getByIndex(iFocus)
Set ocTarget = ocGridControl.Controls(vColumn.Name)
.Target = ocTarget._Shortcut
Set vDataField = ocTarget.ControlModel.BoundField
If IsNull(vDataField) Then Goto Error_Target ' Control MUST be bound to a database record or query
If Not _CheckColumnType(pvFindWhat, vDataField) Then Goto Error_Target
ReDim vNames(0), vIndexes(0)
vNames(0) = ocTarget._Name
Set oColumns = ofParentForm.DatabaseForm.createResultSet().Columns
For j = 0 To oColumns.Count - 1
If vDataField.Name = oColumns.ElementNames(j) Then
vIndexes(0) = j + 1
Exit For
End If
Next j
End If
End Select
.Form = ofParentForm._Shortcut
.LastColumn = UBound(vNames)
.ColumnNames = vNames
.ResultSetIndex = vIndexes
If pvFindFirst Then
Select Case pvSearch
Case acDown, acSearchAll
ofParentForm.DatabaseForm.beforeFirst()
.LastRow = 0
Case acUp
ofParentForm.DatabaseForm.afterLast()
.LastRow = ofParentForm.DatabaseForm.RowCount + 1
End Select
Else
Select Case True
Case ofParentForm.DatabaseForm.isBeforeFirst And (pvSearch = acSearchAll Or pvSearch = acDown)
.LastRow = 0
Case ofParentForm.DatabaseForm.isAfterLast And pvSearch = acUp
ofParentForm.DatabaseForm.last() ' RowCount produces a wrong value as long as last record has not been reached
.LastRow = ofParentForm.DatabaseForm.RowCount + 1
Case Else
.LastRow = ofParentForm.DatabaseForm.getRow()
End Select
End If
.FindRecord = 1
End With
Set _A2B_.FindRecord = oFindRecord
FindRecord = DoCmd.Findnext()
Exit_Function:
Utils._ResetCalledSub("FindRecord")
Exit Function
Error_Function:
TraceError(TRACEABORT, Err, "FindRecord", Erl)
GoTo Exit_Function
Error_ActiveForm:
TraceError(TRACEERRORS, ERRNOACTIVEFORM, Utils._CalledSub(), 0)
Goto Exit_Function
Error_DatabaseForm:
TraceError(TRACEFATAL, ERRDATABASEFORM, Utils._CalledSub(), 0, 1, vParentForm._Name)
Goto Exit_Function
Error_Target:
TraceError(TRACEFATAL, ERRWRONGARGUMENT, Utils._CalledSub(), 0, 1, Array(6, pvTargetedField))
Goto Exit_Function
Error_NoGrid:
TraceError(TRACEFATAL, ERRNOGRIDINFORM, Utils._CalledSub(), 0, 1, vParentForm._Name)
Goto Exit_Function
End Function ' FindRecord V1.1.0
REM -----------------------------------------------------------------------------------------------------------------------
Public Function GetHiddenAttribute(ByVal Optional pvObjectType As Variant _
, ByVal Optional pvObjectName As Variant _
) As Boolean
If _ErrorHandler() Then On Local Error Goto Error_Function
Const cstThisSub = "GetHiddenAttribute"
Utils._SetCalledSub(cstThisSub)
If IsMissing(pvObjectType) Then Call _TraceArguments()
If Not Utils._CheckArgument(pvObjectType, 1, Utils._AddNumeric(), _
Array(acDiagram, acForm, acQuery, acTable, acReport, acBasicIDE, acDatabaseWindow, acDocument) _
) Then Goto Exit_Function
If IsMissing(pvObjectName) Then
Select Case pvObjectType
Case acForm, acQuery, acTable, acReport, acDocument : Call _TraceArguments()
Case Else
End Select
pvObjectName = ""
Else
If Not Utils._CheckArgument(pvObjectName, 2, vbString) Then Goto Exit_Function
End If
Dim oWindow As Object
Set oWindow = _SelectWindow(pvObjectType, pvObjectName)
If IsNull(oWindow.Frame) Then Goto Error_NotFound
GetHiddenAttribute = Not oWindow.Frame.ContainerWindow.isVisible()
Exit_Function:
Utils._ResetCalledSub(cstThisSub)
Exit Function
Error_NotFound:
TraceError(TRACEFATAL, ERROBJECTNOTFOUND, Utils._CalledSub(), 0, , Array(_GetLabel("OBJECT"), pvObjectName))
Goto Exit_Function
Error_Function:
TraceError(TRACEABORT, Err, cstThisSub, Erl)
GoTo Exit_Function
End Function ' GetHiddenAttribute V1.1.0
REM -----------------------------------------------------------------------------------------------------------------------
Public Function GoToControl(Optional ByVal pvControlName As variant) As Boolean
' Set the focus on the named control on the active form.
' Return False if the control does not exist or is disabled,
Utils._SetCalledSub("GoToControl")
If _ErrorHandler() Then On Local Error Goto Error_Function
If IsMissing(pvControlName) Then Call _TraceArguments()
If Not Utils._CheckArgument(pvControlName, 1, vbString) Then Goto Exit_Function
GoToControl = False
Dim oWindow As Object, ofForm As Object, ocControl As Object
Dim i As Integer, iCount As Integer
Set oWindow = _SelectWindow()
If oWindow.WindowType = acForm Then
Set ofForm = Application.Forms(oWindow._Name)
iCount = ofForm.Controls().Count
For i = 0 To iCount - 1
ocControl = ofForm.Controls(i)
If UCase(ocControl._Name) = UCase(pvControlName) Then
If Methods.hasProperty(ocControl, "Enabled") Then
If ocControl.Enabled Then
ocControl.setFocus()
GoToControl = True
Exit For
End If
End If
End If
Next i
End If
Exit_Function:
Utils._ResetCalledSub("GoToControl")
Exit Function
Error_Function:
TraceError(TRACEABORT, Err, "GoToControl", Erl)
GoTo Exit_Function
End Function ' GoToControl V0.9.0
REM -----------------------------------------------------------------------------------------------------------------------
Public Function GoToRecord(Optional ByVal pvObjectType As Variant _
, Optional ByVal pvObjectName As Variant _
, Optional ByVal pvRecord As Variant _
, Optional ByVal pvOffset As Variant _
) As Boolean
'Move to record indicated by pvRecord in the object designated by pvObjectType (MUST BE acDataForm)
If _ErrorHandler() Then On Local Error Goto Error_Function
GoToRecord = False
Utils._SetCalledSub("GoToRecord")
If IsMissing(pvObjectName) Then pvObjectName = ""
If IsMissing(pvObjectType) Then
If pvObjectName <> "" Then pvObjectType = acDataForm Else pvObjectType = acActiveDataObject
End If
If IsMissing(pvRecord) Then pvRecord = acNext
If IsMissing(pvOffset) Then pvOffset = 1
If Not (Utils._CheckArgument(pvObjectType, 1, Utils._AddNumeric() _
, Array(acActiveDataObject, acDataForm)) _
And Utils._CheckArgument(pvObjectName, 2, vbString) _
And Utils._CheckArgument(pvRecord, 3, Utils._AddNumeric() _
, Array(acFirst, acGoTo, acLast, acNewRec, acNext, acPrevious)) _
And Utils._CheckArgument(pvOffset, 4, Utils._AddNumeric()) _
) Then Goto Exit_Function
If pvObjectType = acActiveDataObject And pvObjectName <> "" Then Goto Error_Target
If pvOffset < 0 And pvRecord <> acGoTo Then Goto Error_Offset
Dim ofForm As Object, oGeneric As Object
Dim i As Integer, iCount As Integer, bFound As Boolean, lOffset As Long
Dim sObjectName, iLengthName As Integer
Select Case pvObjectType
Case acActiveDataObject ' Determine active form
iCount = Application._CountOpenForms()
If iCount = 0 Then Goto Error_ActiveForm
bFound = False
For i = 0 To iCount - 1 ' Determine form having the focus
Set ofForm = Application.Forms(i)
If ofForm.Component.CurrentController.Frame.IsActive() Then
bFound = True
Exit For
End If
Next i
If Not bFound Then Goto Error_ActiveForm
Case acDataForm
' pvObjectName can be "myForm", "Forms!myForm", "Forms!myForm!mySubform" or "Forms!myForm!mySubform.Form"
sObjectName = UCase(pvObjectName)
iLengthName = Len(sObjectName)
Select Case True
Case iLengthName > 6 And Left(sObjectName, 6) = "FORMS!" And Right(sObjectName, 5) = ".FORM"
Set ofForm = getObject(pvObjectName)
If ofForm._Type <> OBJSUBFORM Then Goto Error_Target
Case iLengthName > 6 And Left(sObjectName, 6) = "FORMS!"
Set oGeneric = getObject(pvObjectName)
If oGeneric._Type = OBJFORM Or oGeneric._Type = OBJSUBFORM Then
Set ofForm = oGeneric
ElseIf oGeneric.SubType = CTLSUBFORM Then
Set ofForm = oGeneric.Form
Else Goto Error_Target
End If
Case sObjectName = ""
Call _TraceArguments()
Case Else
Set ofForm = Application.Forms(pvObjectName)
End Select
Case Else ' Not supported
End Select
' Check if current row updated => Save it
Dim oResultSet As Object
Set oResultSet = ofForm.DatabaseForm
If oResultSet.IsNew Then
oResultSet.insertRow()
ElseIf oResultSet.IsModified Then
oResultSet.updateRow()
End If
lOffset = pvOffset
Select Case pvRecord
Case acFirst : GoToRecord = oResultSet.first()
Case acGoTo : GoToRecord = oResultSet.absolute(lOffset)
Case acLast : GoToRecord = oResultSet.last()
Case acNewRec
oResultSet.last() ' To simulate the behaviour in the UI
oResultSet.moveToInsertRow()
GoToRecord = True
Case acNext
If lOffset = 1 Then
GoToRecord = oResultSet.next()
Else
GoToRecord = oResultSet.relative(lOffset)
End If
Case acPrevious
If lOffset = 1 Then
GoToRecord = oResultSet.previous()
Else
GoToRecord = oResultSet.relative(- lOffset)
End If
End Select
Exit_Function:
Utils._ResetCalledSub("GoToRecord")
Exit Function
Error_Function:
TraceError(TRACEABORT, Err, "GoToRecord", Erl)
GoTo Exit_Function
Error_ActiveForm:
TraceError(TRACEERRORS, ERRNOACTIVEFORM, Utils._CalledSub(), 0)
Goto Exit_Function
Error_Target:
TraceError(TRACEFATAL, ERRWRONGARGUMENT, Utils._CalledSub(), 0, 1, Array(2, pvObjectName))
Goto Exit_Function
Error_Offset:
TraceError(TRACEFATAL, ERRWRONGARGUMENT, Utils._CalledSub(), 0, 1, Array(4, pvOffset))
Goto Exit_Function
End Function ' GoToRecord
REM -----------------------------------------------------------------------------------------------------------------------
Public Function Maximize() As Boolean
' Maximize the window having the focus
Utils._SetCalledSub("Maximize")
Dim oWindow As Object
Maximize = False
Set oWindow = _SelectWindow()
If Not IsNull(oWindow.Frame) Then
If Utils._hasUNOProperty(oWindow.Frame.ContainerWindow, "IsMaximized") Then oWindow.Frame.ContainerWindow.IsMaximized = True ' Ignored when <= OO3.2
Maximize = True
End If
Utils._ResetCalledSub("Maximize")
Exit Function
End Function ' Maximize V0.8.5
REM -----------------------------------------------------------------------------------------------------------------------
Public Function Minimize() As Boolean
' Maximize the form having the focus
Utils._SetCalledSub("Minimize")
Dim oWindow As Object
Minimize = False
Set oWindow = _SelectWindow()
If Not IsNull(oWindow.Frame) Then
If Utils._hasUNOProperty(oWindow.Frame.ContainerWindow, "IsMinimized") Then oWindow.Frame.ContainerWindow.IsMinimized = True
Minimize = True
End If
Utils._ResetCalledSub("Minimize")
Exit Function
End Function ' Minimize V0.8.5
REM -----------------------------------------------------------------------------------------------------------------------
Public Function MoveSize(ByVal Optional pvLeft As Variant _
, ByVal Optional pvTop As Variant _
, ByVal Optional pvWidth As Variant _
, ByVal Optional pvHeight As Variant _
) As Variant
' Execute MoveSize action
Utils._SetCalledSub("MoveSize")
If _ErrorHandler() Then On Local Error Goto Error_Function
MoveSize = False
If IsMissing(pvLeft) Then pvLeft = -1
If IsMissing(pvTop) Then pvTop = -1
If IsMissing(pvWidth) Then pvWidth = -1
If IsMissing(pvHeight) Then pvHeight = -1
If Not Utils._CheckArgument(pvLeft, 1, Utils._AddNumeric()) Then Goto Exit_Function
If Not Utils._CheckArgument(pvTop, 2, Utils._AddNumeric()) Then Goto Exit_Function
If Not Utils._CheckArgument(pvWidth, 3, Utils._AddNumeric()) Then Goto Exit_Function
If Not Utils._CheckArgument(pvHeight, 4, Utils._AddNumeric()) Then Goto Exit_Function
Dim iArg As Integer, iWrong As Integer ' Check arguments values
iArg = 0
If pvHeight < -1 Then
iArg = 4 : iWrong = pvHeight
ElseIf pvWidth < -1 Then
iArg = 3 : iWrong = pvWidth
ElseIf pvTop < -1 Then
iArg = 2 : iWrong = pvTop
ElseIf pvLeft < -1 Then
iArg = 1 : iWrong = pvLeft
End If
If iArg > 0 Then
TraceError(TRACEFATAL, ERRWRONGARGUMENT, Utils._CalledSub(), 0, 1, Array(iArg, iWrong))
Goto Exit_Function
End If
Dim iPosSize As Integer
iPosSize = 0
If pvLeft >= 0 Then iPosSize = iPosSize + com.sun.star.awt.PosSize.X
If pvTop >= 0 Then iPosSize = iPosSize + com.sun.star.awt.PosSize.Y
If pvWidth > 0 Then iPosSize = iPosSize + com.sun.star.awt.PosSize.WIDTH
If pvHeight > 0 Then iPosSize = iPosSize + com.sun.star.awt.PosSize.HEIGHT
Dim oWindow As Object
Set oWindow = _SelectWindow()
With oWindow
If Not IsNull(.Frame) Then
If Utils._hasUNOProperty(.Frame.ContainerWindow, "IsMaximized") Then ' Ignored when <= OO3.2
.Frame.ContainerWindow.IsMaximized = False
.Frame.ContainerWindow.IsMinimized = False
End If
.Frame.ContainerWindow.setPosSize(pvLeft, pvTop, pvWidth, pvHeight, iPosSize)
MoveSize = True
End If
End With
Exit_Function:
Utils._ResetCalledSub("MoveSize")
Exit Function
Error_Function:
TraceError(TRACEABORT, Err, "MoveSize", Erl)
GoTo Exit_Function
End Function ' MoveSize V1.1.0
REM -----------------------------------------------------------------------------------------------------------------------
Public Function OpenForm(Optional ByVal pvFormName As Variant _
, Optional ByVal pvView As Variant _
, Optional ByVal pvFilterName As Variant _
, Optional ByVal pvWhereCondition As Variant _
, Optional ByVal pvDataMode As Variant _
, Optional ByVal pvWindowMode As Variant _
, Optional ByVal pvOpenArgs As Variant _
) As Variant
If _ErrorHandler() Then On Local Error Goto Error_Function
Utils._SetCalledSub("OpenForm")
If IsMissing(pvFormName) Then Call _TraceArguments()
If IsMissing(pvView) Then pvView = acNormal
If IsMissing(pvFilterName) Then pvFilterName = ""
If IsMissing(pvWhereCondition) Then pvWhereCondition = ""
If IsMissing(pvDataMode) Then pvDataMode = acFormPropertySettings
If IsMissing(pvWindowMode) Then pvWindowMode = acWindowNormal
If IsMissing(pvOpenArgs) Then pvOpenArgs = ""
Set OpenForm = Nothing
If Not (Utils._CheckArgument(pvFormName, 1, vbString) _
And Utils._CheckArgument(pvView, 2, Utils._AddNumeric(), Array(acNormal, acPreview, acDesign)) _
And Utils._CheckArgument(pvFilterName, 3, vbString) _
And Utils._CheckArgument(pvWhereCondition, 4, vbString) _
And Utils._CheckArgument(pvDataMode, 5, Utils._AddNumeric(), Array(acFormAdd, acFormEdit, acFormPropertySettings, acFormReadOnly)) _
And Utils._CheckArgument(pvWindowMode, 6, Utils._AddNumeric(), Array(acDialog, acHidden, acIcon, acWindowNormal)) _
) Then Goto Exit_Function
Dim ofForm As Object, sWarning As String
Dim oDatabase As Object, oOpenForm As Object, bOpenMode As Boolean, oController As Object
Set oDatabase = Application._CurrentDb()
If oDatabase._DbConnect <> DBCONNECTBASE Then Goto Error_NotApplicable
Set ofForm = Application.AllForms(pvFormName)
If ofForm.IsLoaded Then
sWarning = _GetLabel("ERR" & ERRFORMYETOPEN)
sWarning = Join(Split(sWarning, "%0"), ofForm._Name)
TraceLog(TRACEANY, "OpenForm: " & sWarning)
Set OpenForm = ofForm
Goto Exit_Function
End If
' Open the form
Select Case pvView
Case acNormal, acPreview: bOpenMode = False
Case acDesign : bOpenMode = True
End Select
Set oController = oDatabase.Document.CurrentController
Set oOpenForm = oController.loadComponent(com.sun.star.sdb.application.DatabaseObject.FORM, ofForm._Name, bOpenMode)
' Apply the filters (FilterName) AND (WhereCondition)
Dim sFilter As String, oForm As Object, oFormsCollection As Object
If pvFilterName = "" And pvWhereCondition = "" Then
sFilter = ""
ElseIf pvFilterName = "" Or pvWhereCondition = "" Then
sFilter = pvFilterName & pvWhereCondition
Else
sFilter = "(" & pvFilterName & ") And (" & pvWhereCondition & ")"
End If
Set oFormsCollection = oOpenForm.DrawPage.Forms
If oFormsCollection.hasByName("MainForm") Then
Set oForm = oFormsCollection.getByName("MainForm")
ElseIf oFormsCollection.hasByName("Form") Then
Set oForm = oFormsCollection.getByName("Form")
ElseIf oFormsCollection.hasByName(ofForm._Name) Then
Set oForm = oFormsCollection.getByName(ofForm._Name)
Else
Goto Trace_Error
End If
If sFilter <> "" Then
oForm.Filter = oDatabase._ReplaceSquareBrackets(sFilter)
oForm.ApplyFilter = True
oForm.reload()
ElseIf oForm.Filter <> "" Then ' If a filter has been set previously it must be removed
oForm.Filter = ""
oForm.ApplyFilter = False
oForm.reload()
End If
'Housekeeping
Set ofForm = Application.AllForms(pvFormName) ' Redone to reinitialize all properties of ofForm now FormName is open
With ofForm
Select Case pvDataMode
Case acFormAdd
.AllowAdditions = True
.AllowDeletions = False
.AllowEdits = False
Case acFormEdit
.AllowAdditions = True
.AllowDeletions = True
.AllowEdits = True
Case acFormReadOnly
.AllowAdditions = False
.AllowDeletions = False
.AllowEdits = False
Case acFormPropertySettings
End Select
.Visible = ( pvWindowMode <> acHidden )
._OpenArgs = pvOpenArgs
'To avoid AOO 3,4 bug See http://user.services.openoffice.org/en/forum/viewtopic.php?f=13&t=53751
.Component.CurrentController.ViewSettings.ShowOnlineLayout = True
End With
Set OpenForm = ofForm
Exit_Function:
Utils._ResetCalledSub("OpenForm")
Set ofForm = Nothing
Set oOpenForm = Nothing
Exit Function
Error_Function:
TraceError(TRACEABORT, Err, "OpenForm", Erl)
Set OpenForm = Nothing
GoTo Exit_Function
Error_NotApplicable:
TraceError(TRACEFATAL, ERRACTION, Utils._CalledSub(), 0, 1)
Goto Exit_Function
Trace_Error:
TraceError(TRACEFATAL, ERROPENFORM, Utils._CalledSub(), 0, , pvFormName)
Set OpenForm = Nothing
Goto Exit_Function
End Function ' OpenForm V0.9.0
REM -----------------------------------------------------------------------------------------------------------------------
Public Function OpenQuery(Optional ByVal pvQueryName As Variant _
, Optional ByVal pvView As Variant _
, Optional ByVal pvDataMode As Variant _
) As Boolean
If _ErrorHandler() Then On Local Error Goto Error_Function
Utils._SetCalledSub("OpenQuery")
If IsMissing(pvQueryName) Then Call _TraceArguments()
If IsMissing(pvView) Then pvView = acViewNormal
If IsMissing(pvDataMode) Then pvDataMode = acEdit
OpenQuery = DoCmd._OpenObject("Query", pvQueryName, pvView, pvDataMode)
Exit_Function:
Utils._ResetCalledSub("OpenQuery")
Exit Function
Error_Function:
TraceError(TRACEABORT, Err, "OpenQuery", Erl)
GoTo Exit_Function
End Function ' OpenQuery
REM -----------------------------------------------------------------------------------------------------------------------
Public Function OpenReport(Optional ByVal pvReportName As Variant _
, Optional ByVal pvView As Variant _
, Optional ByVal pvDataMode As Variant _
) As Boolean
If _ErrorHandler() Then On Local Error Goto Error_Function
Utils._SetCalledSub("OpenReport")
If IsMissing(pvReportName) Then Call _TraceArguments()
If IsMissing(pvView) Then pvView = acViewNormal
If IsMissing(pvDataMode) Then pvDataMode = acEdit
OpenReport = DoCmd._OpenObject("Report", pvReportName, pvView, pvDataMode)
Exit_Function:
Utils._ResetCalledSub("OpenReport")
Exit Function
Error_Function:
TraceError(TRACEABORT, Err, "OpenReport", Erl)
GoTo Exit_Function
End Function ' OpenReport
REM -----------------------------------------------------------------------------------------------------------------------
Public Function OpenSQL(Optional ByVal pvSQL As Variant _
, Optional ByVal pvOption As Variant _
) As Boolean
' Return True if the execution of the SQL statement was successful
' SQL must contain a SELECT query
' pvOption can force pass through mode
If _ErrorHandler() Then On Local Error Goto Error_Function
Utils._SetCalledSub("OpenSQL")
OpenSQL = False
If IsMissing(pvSQL) Then Call _TraceArguments()
If Not Utils._CheckArgument(pvSQL, 1, vbString) Then Goto Exit_Function
Const cstNull = -1
If IsMissing(pvOption) Then
pvOption = cstNull
Else
If Not Utils._CheckArgument(pvOption, 2, Utils._AddNumeric(), dbSQLPassThrough) Then Goto Exit_Function
End If
OpenSQL = Application._CurrentDb.OpenSQL(pvSQL, pvOption)
Exit_Function:
Utils._ResetCalledSub("OpenSQL")
Exit Function
Error_Function:
TraceError(TRACEABORT, Err, "OpenSQL", Erl)
GoTo Exit_Function
End Function ' OpenSQL V1.1.0
REM -----------------------------------------------------------------------------------------------------------------------
Public Function OpenTable(Optional ByVal pvTableName As Variant _
, Optional ByVal pvView As Variant _
, Optional ByVal pvDataMode As Variant _
) As Boolean
If _ErrorHandler() Then On Local Error Goto Error_Function
Utils._SetCalledSub("OpenTable")
If IsMissing(pvTableName) Then Call _TraceArguments()
If IsMissing(pvView) Then pvView = acViewNormal
If IsMissing(pvDataMode) Then pvDataMode = acEdit
OpenTable = DoCmd._OpenObject("Table", pvTableName, pvView, pvDataMode)
Exit_Function:
Utils._ResetCalledSub("OpenTable")
Exit Function
Error_Function:
TraceError(TRACEABORT, Err, "OpenTable", Erl)
GoTo Exit_Function
End Function ' OpenTable
REM -----------------------------------------------------------------------------------------------------------------------
Public Function OutputTo(ByVal pvObjectType As Variant _
, ByVal Optional pvObjectName As Variant _
, ByVal Optional pvOutputFormat As Variant _
, ByVal Optional pvOutputFile As Variant _
, ByVal Optional pvAutoStart As Variant _
, ByVal Optional pvTemplateFile As Variant _
, ByVal Optional pvEncoding As Variant _
) As Boolean
'Supported: acFormatPDF, acFormatODT, acFormatDOC, acFormatHTML for forms
If _ErrorHandler() Then On Local Error Goto Error_Function
Utils._SetCalledSub("OutputTo")
OutputTo = False
If Not Utils._CheckArgument(pvObjectType, 1, Utils._AddNumeric(), acSendForm) Then Goto Exit_Function
If IsMissing(pvObjectName) Then pvObjectName = ""
If Not Utils._CheckArgument(pvObjectName, 2, vbString) Then Goto Exit_Function
If IsMissing(pvOutputFormat) Then pvOutputFormat = ""
If Not Utils._CheckArgument(pvOutputFormat, 3, vbString) Then Goto Exit_Function
If pvOutputFormat <> "" Then
If Not Utils._CheckArgument(UCase(pvOutputFormat), 3, vbString, Array( _
UCase(acFormatPDF), UCase(acFormatODT), UCase(acFormatDOC), UCase(acFormatHTML) _
, "PDF", "ODT", "DOC", "HTML", "" _
)) Then Goto Exit_Function ' A 2nd time to allow case unsensitivity
End If
If IsMissing(pvOutputFile) Then pvOutputFile = ""
If Not Utils._CheckArgument(pvOutputFile, 4, vbString) Then Goto Exit_Function
If IsMissing(pvAutoStart) Then pvAutoStart = False
If Not Utils._CheckArgument(pvAutoStart, 5, vbBoolean) Then Goto Exit_Function
If IsMissing(pvTemplateFile) Then pvTemplateFile = ""
If Not Utils._CheckArgument(pvTemplateFile, 6, vbString, "") Then Goto Exit_Function
If IsMissing(pvEncoding) Then pvEncoding = ""
If Not Utils._CheckArgument(pvEncoding, 7, vbString, "") Then Goto Exit_Function
Dim vWindow As Variant, sOutputFile As String, ofForm As Object, i As Integer, bFound As Boolean
'Find applicable form
If pvObjectName = "" Then
vWindow = _SelectWindow()
If vWindow.WindowType <> acSendForm Then Goto Error_Action
Set ofForm = Application.Forms(vWindow._Name)
Else
bFound = False
For i = 0 To Application.Forms()._Count - 1
Set ofForm = Application.Forms(i)
If UCase(ofForm._Name) = UCase(pvObjectName) Then
bFound = True
Exit For
End If
Next i
If Not bFound Then Goto Error_NotFound
End If
'Determine format and parameters
Dim sOutputFormat As String, sFilter As String, oFilterData As Object, oExport As Object, sSuffix As String
If pvOutputFormat = "" Then
sOutputFormat = _PromptFormat() ' Prompt user for format
If sOutputFormat = "" Then Goto Exit_Function
Else
sOutputFormat = UCase(pvOutputFormat)
End If
Select Case sOutputFormat
Case UCase(acFormatPDF), "PDF"
sFilter = acFormatPDF
oFilterData = Array( _
_MakePropertyValue ("ExportFormFields", False), _
)
sSuffix = "pdf"
Case UCase(acFormatDOC), "DOC"
sFilter = acFormatDOC
oFilterData = Array()
sSuffix = "doc"
Case UCase(acFormatODT), "ODT"
sFilter = acFormatODT
oFilterData = Array()
sSuffix = "odt"
Case UCase(acFormatHTML), "HTML"
sFilter = acFormatHTML
oFilterData = Array()
sSuffix = "html"
End Select
oExport = Array( _
_MakePropertyValue("Overwrite", True), _
_MakePropertyValue("FilterName", sFilter), _
_MakePropertyValue("FilterData", oFilterData), _
)
'Determine output file
If pvOutputFile = "" Then ' Prompt file picker to user
sOutputFile = _PromptFilePicker(sSuffix)
If sOutputFile = "" Then Goto Exit_Function
Else
sOutputFile = pvOutputFile
End If
sOutputFile = ConvertToURL(sOutputFile)
'Create file
On Local Error Goto Error_File
ofForm.Component.storeToURL(sOutputFile, oExport)
On Local Error Goto Error_Function
'Launch application, if requested
If pvAutoStart Then Call _ShellExecute(sOutputFile)
OutputTo = True
Exit_Function:
Utils._ResetCalledSub("OutputTo")
Exit Function
Error_NotFound:
TraceError(TRACEFATAL, ERROBJECTNOTFOUND, Utils._CalledSub(), 0, , Array(_GetLabel("OBJECT"), pvObjectName))
Goto Exit_Function
Error_Action:
TraceError(TRACEFATAL, ERRACTION, Utils._CalledSub(), 0)
Goto Exit_Function
Error_Function:
TraceError(TRACEABORT, Err, "OutputTo", Erl)
GoTo Exit_Function
Error_File:
TraceError(TRACEFATAL, ERRFILENOTCREATED, Utils._CalledSub(), 0, , sOutputFile)
GoTo Exit_Function
End Function ' OutputTo V0.9.1
REM -----------------------------------------------------------------------------------------------------------------------
Public Function Quit(Optional ByVal pvSave As Variant) As Variant
' Quit the application
' Modified from Andrew Pitonyak's Base Macro Programming §5.8.1
If _ErrorHandler() Then On Local Error Goto Error_Function
Const cstThisSub = "Quit"
Utils._SetCalledSub(cstThisSub)
If IsMissing(pvSave) Then pvSave = acQuitSaveAll
If Not Utils._CheckArgument(pvSave, 1, Utils._AddNumeric(), _
Array(acQuitPrompt, acQuitSaveAll, acQuitSaveNone) _
) Then Goto Exit_Function
Dim oDatabase As Object, oDoc As Object
Set oDatabase = Application._CurrentDb()
If oDatabase._DbConnect <> DBCONNECTBASE Then Goto Error_NotApplicable
If Not IsNull(oDatabase) Then
Set oDoc = oDatabase.Document
Select Case pvSave
Case acQuitPrompt
If MsgBox(_GetLabel("QUIT"), vbYesNo + vbQuestion, _GetLabel("QUITSHORT")) = vbNo Then Exit Function
Case acQuitSaveNone
oDoc.setModified(False)
Case Else
End Select
If HasUnoInterfaces(oDoc, "com.sun.star.util.XCloseable") Then
If (oDoc.isModified) Then
If (oDoc.hasLocation AND (Not oDoc.isReadOnly)) Then
oDoc.store()
End If
End If
oDoc.close(true)
Else
oDoc.dispose()
End If
End If
Exit_Function:
Utils._ResetCalledSub(cstThisSub)
Set oDatabase = Nothing
Set oDoc = Nothing
Exit Function
Error_Function:
TraceError(TRACEABORT, Err, Utils._CalledSub(), Erl)
Set OpenForm = Nothing
GoTo Exit_Function
Error_NotApplicable:
TraceError(TRACEFATAL, ERRACTION, Utils._CalledSub(), 0, 1, cstThisSub)
Goto Exit_Function
End Function ' Quit V1.1.0
REM -----------------------------------------------------------------------------------------------------------------------
Public Sub RunApp(Optional ByVal pvCommandLine As Variant)
' Convert to URL and execute the Command Line
If _ErrorHandler() Then On Local Error Goto Error_Sub
Utils._SetCalledSub("RunApp")
If IsMissing(pvCommandLine) Then Call _TraceArguments()
If Not Utils._CheckArgument(pvCommandLine, 1, vbString) Then Goto Exit_Sub
_ShellExecute(ConvertToURL(pvCommandLine))
Exit_Sub:
Utils._ResetCalledSub("RunApp")
Exit Sub
Error_Sub:
TraceError(TRACEABORT, Err, "RunApp", Erl)
GoTo Exit_Sub
End Sub ' RunApp V0.8.5
REM -----------------------------------------------------------------------------------------------------------------------
REM -----------------------------------------------------------------------------------------------------------------------
Public Function RunCommand(Optional pvCommand As Variant) As Boolean
' Execute command via DispatchHelper
If _ErrorHandler() Then On Local Error Goto Exit_Function ' Avoid any abort
Utils._SetCalledSub("RunCommand")
Dim iVBACommand As Integer, sOOCommand As String, sDispatch As String
If IsMissing(pvCommand) Then Call _TraceArguments()
If Not ( Utils._CheckArgument(pvCommand, 1, Utils._AddNumeric(vbString)) ) Then Goto Exit_Function
If VarType(pvCommand) = vbString Then
sOOCommand = pvCommand
iVBACommand = -1
Else
sOOCommand = ""
iVBACommand = pvCommand
End If
Select Case True
Case iVBACommand = acCmdAboutMicrosoftAccess Or UCase(sOOCommand) = "ABOUT" : sDispatch = "About"
Case iVBACommand = acCmdAboutOpenOffice Or UCase(sOOCommand) = "ABOUT" : sDispatch = "About"
Case iVBACommand = acCmdAboutLibreOffice Or UCase(sOOCommand) = "ABOUT" : sDispatch = "About"
Case UCase(sOOCommand) = "ACTIVEHELP" : sDispatch = "ActiveHelp"
Case UCase(sOOCommand) = "ADDDIRECT" : sDispatch = "AddDirect"
Case UCase(sOOCommand) = "ADDFIELD" : sDispatch = "AddField"
Case UCase(sOOCommand) = "AUTOCONTROLFOCUS" : sDispatch = "AutoControlFocus"
Case UCase(sOOCommand) = "AUTOFILTER" : sDispatch = "AutoFilter"
Case UCase(sOOCommand) = "AUTOPILOTADDRESSDATASOURCE" : sDispatch = "AutoPilotAddressDataSource"
Case UCase(sOOCommand) = "BASICBREAK" : sDispatch = "BasicBreak"
Case iVBACommand = acCmdVisualBasicEditor Or UCase(sOOCommand) = "BASICIDEAPPEAR" : sDispatch = "BasicIDEAppear"
Case UCase(sOOCommand) = "BASICSTOP" : sDispatch = "BasicStop"
Case iVBACommand = acCmdBringToFront Or UCase(sOOCommand) = "BRINGTOFRONT" : sDispatch = "BringToFront"
Case UCase(sOOCommand) = "CHECKBOX" : sDispatch = "CheckBox"
Case UCase(sOOCommand) = "CHOOSEMACRO" : sDispatch = "ChooseMacro"
Case iVBACommand = acCmdClose Or UCase(sOOCommand) = "CLOSEDOC" : sDispatch = "CloseDoc"
Case UCase(sOOCommand) = "CLOSEWIN" : sDispatch = "CloseWin"
Case iVBACommand = acCmdToolbarsCustomize Or UCase(sOOCommand) = "CONFIGUREDIALOG" : sDispatch = "ConfigureDialog"
Case UCase(sOOCommand) = "CONTROLPROPERTIES" : sDispatch = "ControlProperties"
Case iVBACommand = acCmdChangeToCommandButton Or UCase(sOOCommand) = "CONVERTTOBUTTON" : sDispatch = "ConvertToButton"
Case iVBACommand = acCmdChangeToCheckBox Or UCase(sOOCommand) = "CONVERTTOCHECKBOX" : sDispatch = "ConvertToCheckBox"
Case iVBACommand = acCmdChangeToComboBox Or UCase(sOOCommand) = "CONVERTTOCOMBO" : sDispatch = "ConvertToCombo"
Case UCase(sOOCommand) = "CONVERTTOCURRENCY" : sDispatch = "ConvertToCurrency"
Case UCase(sOOCommand) = "CONVERTTODATE" : sDispatch = "ConvertToDate"
Case iVBACommand = acCmdChangeToTextBox Or UCase(sOOCommand) = "CONVERTTOEDIT" : sDispatch = "ConvertToEdit"
Case UCase(sOOCommand) = "CONVERTTOFILECONTROL" : sDispatch = "ConvertToFileControl"
Case iVBACommand = acCmdChangeToLabel Or UCase(sOOCommand) = "CONVERTTOFIXED" : sDispatch = "ConvertToFixed"
Case UCase(sOOCommand) = "CONVERTTOFORMATTED" : sDispatch = "ConvertToFormatted"
Case UCase(sOOCommand) = "CONVERTTOGROUP" : sDispatch = "ConvertToGroup"
Case UCase(sOOCommand) = "CONVERTTOIMAGEBTN" : sDispatch = "ConvertToImageBtn"
Case iVBACommand = acCmdChangeToImage Or UCase(sOOCommand) = "CONVERTTOIMAGECONTROL" : sDispatch = "ConvertToImageControl"
Case iVBACommand = acCmdChangeToListBox Or UCase(sOOCommand) = "CONVERTTOLIST" : sDispatch = "ConvertToList"
Case UCase(sOOCommand) = "CONVERTTONAVIGATIONBAR" : sDispatch = "ConvertToNavigationBar"
Case UCase(sOOCommand) = "CONVERTTONUMERIC" : sDispatch = "ConvertToNumeric"
Case UCase(sOOCommand) = "CONVERTTOPATTERN" : sDispatch = "ConvertToPattern"
Case iVBACommand = acCmdChangeToOptionButton Or UCase(sOOCommand) = "CONVERTTORADIO" : sDispatch = "ConvertToRadio"
Case UCase(sOOCommand) = "CONVERTTOSCROLLBAR" : sDispatch = "ConvertToScrollBar"
Case UCase(sOOCommand) = "CONVERTTOSPINBUTTON" : sDispatch = "ConvertToSpinButton"
Case UCase(sOOCommand) = "CONVERTTOTIME" : sDispatch = "ConvertToTime"
Case iVBACommand = acCmdCopy Or UCase(sOOCommand) = "COPY" : sDispatch = "Copy"
Case UCase(sOOCommand) = "CURRENCYFIELD" : sDispatch = "CurrencyField"
Case iVBACommand = acCmdCut Or UCase(sOOCommand) = "CUT" : sDispatch = "Cut"
Case UCase(sOOCommand) = "DATEFIELD" : sDispatch = "DateField"
Case iVBACommand = acCmdCreateRelationship Or UCase(sOOCommand) = "DBADDRELATION " : sDispatch = "DBAddRelation "
Case UCase(sOOCommand) = "DBCONVERTTOVIEW " : sDispatch = "DBConvertToView "
Case iVBACommand = acCmdDelete Or UCase(sOOCommand) = "DBDELETE " : sDispatch = "DBDelete "
Case UCase(sOOCommand) = "DBDIRECTSQL " : sDispatch = "DBDirectSQL "
Case UCase(sOOCommand) = "DBDSADVANCEDSETTINGS " : sDispatch = "DBDSAdvancedSettings "
Case UCase(sOOCommand) = "DBDSCONNECTIONTYPE " : sDispatch = "DBDSConnectionType "
Case iVBACommand = acCmdDatabaseProperties Or UCase(sOOCommand) = "DBDSPROPERTIES " : sDispatch = "DBDSProperties "
Case UCase(sOOCommand) = "DBEDIT " : sDispatch = "DBEdit "
Case iVBACommand = acCmdSQLView Or UCase(sOOCommand) = "DBEDITSQLVIEW " : sDispatch = "DBEditSqlView "
Case iVBACommand = acCmdRemove Or UCase(sOOCommand) = "DBFORMDELETE " : sDispatch = "DBFormDelete "
Case iVBACommand = acCmdDesignView Or UCase(sOOCommand) = "DBFORMEDIT " : sDispatch = "DBFormEdit "
Case iVBACommand = acCmdFormView Or UCase(sOOCommand) = "DBFORMOPEN " : sDispatch = "DBFormOpen "
Case UCase(sOOCommand) = "DBFORMRENAME " : sDispatch = "DBFormRename "
Case iVBACommand = acCmdNewObjectForm Or UCase(sOOCommand) = "DBNEWFORM " : sDispatch = "DBNewForm "
Case UCase(sOOCommand) = "DBNEWFORMAUTOPILOT " : sDispatch = "DBNewFormAutoPilot "
Case UCase(sOOCommand) = "DBNEWQUERY " : sDispatch = "DBNewQuery "
Case UCase(sOOCommand) = "DBNEWQUERYAUTOPILOT " : sDispatch = "DBNewQueryAutoPilot "
Case UCase(sOOCommand) = "DBNEWQUERYSQL " : sDispatch = "DBNewQuerySql "
Case UCase(sOOCommand) = "DBNEWREPORT " : sDispatch = "DBNewReport "
Case UCase(sOOCommand) = "DBNEWREPORTAUTOPILOT " : sDispatch = "DBNewReportAutoPilot "
Case iVBACommand = acCmdNewObjectTable Or UCase(sOOCommand) = "DBNEWTABLE " : sDispatch = "DBNewTable "
Case UCase(sOOCommand) = "DBNEWTABLEAUTOPILOT " : sDispatch = "DBNewTableAutoPilot "
Case iVBACommand = acCmdNewObjectView Or UCase(sOOCommand) = "DBNEWVIEW " : sDispatch = "DBNewView "
Case UCase(sOOCommand) = "DBNEWVIEWSQL " : sDispatch = "DBNewViewSQL "
Case iVBACommand = acCmdOpenDatabase Or UCase(sOOCommand) = "DBOPEN " : sDispatch = "DBOpen "
Case iVBACommand = acCmdRemove Or UCase(sOOCommand) = "DBQUERYDELETE " : sDispatch = "DBQueryDelete "
Case iVBACommand = acCmdDesignView Or UCase(sOOCommand) = "DBQUERYEDIT " : sDispatch = "DBQueryEdit "
Case iVBACommand = acCmdNewObjectQuery Or UCase(sOOCommand) = "DBQUERYOPEN " : sDispatch = "DBQueryOpen "
Case UCase(sOOCommand) = "DBQUERYRENAME " : sDispatch = "DBQueryRename "
Case UCase(sOOCommand) = "DBREFRESHTABLES " : sDispatch = "DBRefreshTables "
Case iVBACommand = acCmdShowAllRelationships Or UCase(sOOCommand) = "DBRELATIONDESIGN " : sDispatch = "DBRelationDesign "
Case UCase(sOOCommand) = "DBRENAME " : sDispatch = "DBRename "
Case iVBACommand = acCmdRemove Or UCase(sOOCommand) = "DBREPORTDELETE " : sDispatch = "DBReportDelete "
Case iVBACommand = acCmdDesignView Or UCase(sOOCommand) = "DBREPORTEDIT " : sDispatch = "DBReportEdit "
Case iVBACommand = acCmdNewObjectReport Or UCase(sOOCommand) = "DBREPORTOPEN " : sDispatch = "DBReportOpen "
Case UCase(sOOCommand) = "DBREPORTRENAME " : sDispatch = "DBReportRename "
Case iVBACommand = acCmdSelectAll Or UCase(sOOCommand) = "DBSELECTALL " : sDispatch = "DBSelectAll "
Case UCase(sOOCommand) = "DBSHOWDOCINFOPREVIEW " : sDispatch = "DBShowDocInfoPreview "
Case UCase(sOOCommand) = "DBSHOWDOCPREVIEW " : sDispatch = "DBShowDocPreview "
Case iVBACommand = acCmdRemoveTable Or UCase(sOOCommand) = "DBTABLEDELETE " : sDispatch = "DBTableDelete "
Case iVBACommand = acCmdDesignView Or UCase(sOOCommand) = "DBTABLEEDIT " : sDispatch = "DBTableEdit "
Case UCase(sOOCommand) = "DBTABLEFILTER " : sDispatch = "DBTableFilter "
Case iVBACommand = acCmdOpenTable Or UCase(sOOCommand) = "DBTABLEOPEN " : sDispatch = "DBTableOpen "
Case iVBACommand = acCmdRename Or UCase(sOOCommand) = "DBTABLERENAME " : sDispatch = "DBTableRename "
Case UCase(sOOCommand) = "DBUSERADMIN " : sDispatch = "DBUserAdmin "
Case UCase(sOOCommand) = "DBVIEWFORMS " : sDispatch = "DBViewForms "
Case UCase(sOOCommand) = "DBVIEWQUERIES " : sDispatch = "DBViewQueries "
Case UCase(sOOCommand) = "DBVIEWREPORTS " : sDispatch = "DBViewReports "
Case UCase(sOOCommand) = "DBVIEWTABLES " : sDispatch = "DBViewTables "
Case iVBACommand = acCmdDelete Or UCase(sOOCommand) = "DELETE" : sDispatch = "Delete"
Case iVBACommand = acCmdDeleteRecord Or UCase(sOOCommand) = "DELETERECORD" : sDispatch = "DeleteRecord"
Case UCase(sOOCommand) = "DESIGNERDIALOG" : sDispatch = "DesignerDialog"
Case UCase(sOOCommand) = "EDIT" : sDispatch = "Edit"
Case UCase(sOOCommand) = "FIRSTRECORD" : sDispatch = "FirstRecord"
Case UCase(sOOCommand) = "FONTDIALOG" : sDispatch = "FontDialog"
Case UCase(sOOCommand) = "FONTHEIGHT" : sDispatch = "FontHeight"
Case UCase(sOOCommand) = "FORMATTEDFIELD" : sDispatch = "FormattedField"
Case UCase(sOOCommand) = "FORMFILTER" : sDispatch = "FormFilter"
Case iVBACommand = acCmdApplyFilterSort Or UCase(sOOCommand) = "FORMFILTERED" : sDispatch = "FormFiltered"
Case UCase(sOOCommand) = "FORMFILTEREXECUTE" : sDispatch = "FormFilterExecute"
Case UCase(sOOCommand) = "FORMFILTEREXIT" : sDispatch = "FormFilterExit"
Case UCase(sOOCommand) = "FORMFILTERNAVIGATOR" : sDispatch = "FormFilterNavigator"
Case UCase(sOOCommand) = "FORMPROPERTIES" : sDispatch = "FormProperties"
Case UCase(sOOCommand) = "FULLSCREEN" : sDispatch = "FullScreen"
Case UCase(sOOCommand) = "GALLERY" : sDispatch = "Gallery"
Case UCase(sOOCommand) = "GRID" : sDispatch = "Grid"
Case iVBACommand = acCmdSnapToGrid Or UCase(sOOCommand) = "GRIDUSE" : sDispatch = "GridUse"
Case iVBACommand = acCmdViewGrid Or UCase(sOOCommand) = "GRIDVISIBLE" : sDispatch = "GridVisible"
Case UCase(sOOCommand) = "GROUPBOX" : sDispatch = "GroupBox"
Case UCase(sOOCommand) = "HELPINDEX" : sDispatch = "HelpIndex"
Case UCase(sOOCommand) = "HELPSUPPORT" : sDispatch = "HelpSupport"
Case iVBACommand = acCmdInsertHyperlink Or UCase(sOOCommand) = "HYPERLINKDIALOG" : sDispatch = "HyperlinkDialog"
Case UCase(sOOCommand) = "IMAGEBUTTON" : sDispatch = "Imagebutton"
Case UCase(sOOCommand) = "IMAGECONTROL" : sDispatch = "ImageControl"
Case UCase(sOOCommand) = "LABEL" : sDispatch = "Label"
Case iVBACommand = acCmdMaximumRecords Or UCase(sOOCommand) = "LASTRECORD" : sDispatch = "LastRecord"
Case UCase(sOOCommand) = "LISTBOX" : sDispatch = "ListBox"
Case UCase(sOOCommand) = "MACRODIALOG" : sDispatch = "MacroDialog"
Case UCase(sOOCommand) = "MACROORGANIZER" : sDispatch = "MacroOrganizer"
Case UCase(sOOCommand) = "MORECONTROLS" : sDispatch = "MoreControls"
Case UCase(sOOCommand) = "NAVIGATIONBAR" : sDispatch = "NavigationBar"
Case iVBACommand = acCmdObjectBrowser Or UCase(sOOCommand) = "NAVIGATOR" : sDispatch = "Navigator"
Case UCase(sOOCommand) = "NEWDOC" : sDispatch = "NewDoc"
Case UCase(sOOCommand) = "NEWRECORD" : sDispatch = "NewRecord"
Case UCase(sOOCommand) = "NEXTRECORD" : sDispatch = "NextRecord"
Case UCase(sOOCommand) = "NUMERICFIELD" : sDispatch = "NumericField"
Case UCase(sOOCommand) = "OPEN" : sDispatch = "Open"
Case UCase(sOOCommand) = "OPTIONSTREEDIALOG" : sDispatch = "OptionsTreeDialog"
Case UCase(sOOCommand) = "ORGANIZER" : sDispatch = "Organizer"
Case UCase(sOOCommand) = "PARAGRAPHDIALOG" : sDispatch = "ParagraphDialog"
Case iVBACommand = acCmdPaste Or UCase(sOOCommand) = "PASTE" : sDispatch = "Paste"
Case iVBACommand = acCmdPasteSpecial Or UCase(sOOCommand) = "PASTESPECIAL " : sDispatch = "PasteSpecial "
Case UCase(sOOCommand) = "PATTERNFIELD" : sDispatch = "PatternField"
Case UCase(sOOCommand) = "PREVRECORD" : sDispatch = "PrevRecord"
Case iVBACommand = acCmdPrint Or UCase(sOOCommand) = "PRINT" : sDispatch = "Print"
Case UCase(sOOCommand) = "PRINTDEFAULT" : sDispatch = "PrintDefault"
Case UCase(sOOCommand) = "PRINTERSETUP" : sDispatch = "PrinterSetup"
Case iVBACommand = acCmdPrintPreview Or UCase(sOOCommand) = "PRINTPREVIEW" : sDispatch = "PrintPreview"
Case UCase(sOOCommand) = "PUSHBUTTON" : sDispatch = "Pushbutton"
Case UCase(sOOCommand) = "QUIT" : sDispatch = "Quit"
Case UCase(sOOCommand) = "RADIOBUTTON" : sDispatch = "RadioButton"
Case iVBACommand = acCmdSaveRecord Or UCase(sOOCommand) = "RECSAVE" : sDispatch = "RecSave"
Case iVBACommand = acCmdFind Or UCase(sOOCommand) = "RECSEARCH" : sDispatch = "RecSearch"
Case iVBACommand = acCmdUndo Or UCase(sOOCommand) = "RECUNDO" : sDispatch = "RecUndo"
Case iVBACommand = acCmdRefresh Or UCase(sOOCommand) = "REFRESH" : sDispatch = "Refresh"
Case UCase(sOOCommand) = "RELOAD" : sDispatch = "Reload"
Case iVBACommand = acCmdRemoveFilterSort Or UCase(sOOCommand) = "REMOVEFILTERSORT" : sDispatch = "RemoveFilterSort"
Case iVBACommand = acCmdRunMacro Or UCase(sOOCommand) = "RUNMACRO" : sDispatch = "RunMacro"
Case iVBACommand = acCmdSave Or UCase(sOOCommand) = "SAVE" : sDispatch = "Save"
Case UCase(sOOCommand) = "SAVEALL" : sDispatch = "SaveAll"
Case iVBACommand = acCmdSaveAs Or UCase(sOOCommand) = "SAVEAS" : sDispatch = "SaveAs"
Case UCase(sOOCommand) = "SAVEBASICAS" : sDispatch = "SaveBasicAs"
Case UCase(sOOCommand) = "SCRIPTORGANIZER" : sDispatch = "ScriptOrganizer"
Case UCase(sOOCommand) = "SCROLLBAR" : sDispatch = "ScrollBar"
Case iVBACommand = acCmdFind Or UCase(sOOCommand) = "SEARCHDIALOG" : sDispatch = "SearchDialog"
Case iVBACommand = acCmdSelectAll Or UCase(sOOCommand) = "SELECTALL" : sDispatch = "SelectAll"
Case iVBACommand = acCmdSelectAllRecords Or UCase(sOOCommand) = "SELECTALL" : sDispatch = "SelectAll"
Case iVBACommand = acCmdSendToBack Or UCase(sOOCommand) = "SENDTOBACK" : sDispatch = "SendToBack"
Case UCase(sOOCommand) = "SHOWFMEXPLORER" : sDispatch = "ShowFmExplorer"
Case UCase(sOOCommand) = "SIDEBAR" : sDispatch = "Sidebar"
Case iVBACommand = acCmdSortDescending Or UCase(sOOCommand) = "SORTDOWN" : sDispatch = "SortDown"
Case iVBACommand = acCmdSortAscending Or UCase(sOOCommand) = "SORTUP" : sDispatch = "Sortup"
Case UCase(sOOCommand) = "SPINBUTTON" : sDispatch = "SpinButton"
Case UCase(sOOCommand) = "STATUSBARVISIBLE" : sDispatch = "StatusBarVisible"
Case UCase(sOOCommand) = "SWITCHCONTROLDESIGNMODE" : sDispatch = "SwitchControlDesignMode"
Case iVBACommand = acCmdTabOrder Or UCase(sOOCommand) = "TABDIALOG" : sDispatch = "TabDialog"
Case UCase(sOOCommand) = "USEWIZARDS" : sDispatch = "UseWizards"
Case UCase(sOOCommand) = "VERSIONDIALOG" : sDispatch = "VersionDialog"
Case UCase(sOOCommand) = "VIEWDATASOURCEBROWSER" : sDispatch = "ViewDataSourceBrowser"
Case iVBACommand = acCmdDatasheetView Or UCase(sOOCommand) = "VIEWFORMASGRID" : sDispatch = "ViewFormAsGrid"
Case iVBACommand = acCmdZoomSelection Or UCase(sOOCommand) = "ZOOM" : sDispatch = "Zoom"
Case Else
If iVBACommand >= 0 Then Goto Exit_Function
sDispatch = pvCommand
End Select
Dim oDocument As Object, oDispatcher As Object, oArgs() As new com.sun.star.beans.PropertyValue, sTargetFrameName As String
Dim oResult As Variant
oDocument = _SelectWindow().Frame
oDispatcher = createUnoService("com.sun.star.frame.DispatchHelper")
sTargetFrameName = ""
oResult = oDispatcher.executeDispatch(oDocument, ".uno:" & sDispatch, sTargetFrameName, 0, oArgs())
Exit_Function:
RunCommand = True
Utils._ResetCalledSub("RunCommand")
Exit Function
Error_Function:
TraceError(TRACEABORT, Err, "RunCommand", Erl)
GoTo Exit_Function
End Function ' RunCommand V0.7.0
REM -----------------------------------------------------------------------------------------------------------------------
Public Function RunSQL(Optional ByVal pvSQL As Variant _
, Optional ByVal pvOption As Variant _
) As Boolean
' Return True if the execution of the SQL statement was successful
' SQL must contain an ACTION query
If _ErrorHandler() Then On Local Error Goto Error_Function
Utils._SetCalledSub("RunSQL")
RunSQL = False
If IsMissing(pvSQL) Then Call _TraceArguments()
If Not Utils._CheckArgument(pvSQL, 1, vbString) Then Goto Exit_Function
Const cstNull = -1
If IsMissing(pvOption) Then
pvOption = cstNull
Else
If Not Utils._CheckArgument(pvOption, 2, Utils._AddNumeric(), dbSQLPassThrough) Then Goto Exit_Function
End If
RunSQL = Application._CurrentDb.RunSQL(pvSQL, pvOption)
Exit_Function:
Utils._ResetCalledSub("RunSQL")
Exit Function
Error_Function:
TraceError(TRACEABORT, Err, "RunSQL", Erl)
GoTo Exit_Function
End Function ' RunSQL V1.1.0
REM -----------------------------------------------------------------------------------------------------------------------
Public Function SelectObject( ByVal Optional pvObjectType As Variant _
, ByVal Optional pvObjectName As Variant _
, ByVal Optional pvInDatabaseWindow As Variant _
) As Boolean
If _ErrorHandler() Then On Local Error Goto Error_Function
Const cstThisSub = "SelectObject"
Utils._SetCalledSub(cstThisSub)
If IsMissing(pvObjectType) Then Call _TraceArguments()
If Not Utils._CheckArgument(pvObjectType, 1, Utils._AddNumeric(), _
Array(acDiagram, acForm, acQuery, acTable, acReport, acBasicIDE, acDatabaseWindow, acDocument) _
) Then Goto Exit_Function
If IsMissing(pvObjectName) Then
Select Case pvObjectType
Case acForm, acQuery, acTable, acReport, acDocument : Call _TraceArguments()
Case Else
End Select
pvObjectName = ""
Else
If Not Utils._CheckArgument(pvObjectName, 2, vbString) Then Goto Exit_Function
End If
If Not IsMissing(pvInDatabaseWindow) Then
If Not Utils._CheckArgument(pvInDatabaseWindow, 3, vbBoolean, False) Then Goto Exit_Function
End If
Dim oWindow As Object
Set oWindow = _SelectWindow(pvObjectType, pvObjectName)
If IsNull(oWindow.Frame) Then Goto Error_NotFound
With oWindow.Frame.ContainerWindow
If .isVisible() = False Then .setVisible(True)
.IsMinimized = False
.setFocus()
.setEnable(True) ' Added to try to bypass desynchro issue in Linux
.toFront() ' Added to force window change in Linux
End With
Exit_Function:
Utils._ResetCalledSub(cstThisSub)
Exit Function
Error_NotFound:
TraceError(TRACEFATAL, ERROBJECTNOTFOUND, Utils._CalledSub(), 0, , Array(_GetLabel("OBJECT"), pvObjectName))
Goto Exit_Function
Error_Function:
TraceError(TRACEABORT, Err, cstThisSub, Erl)
GoTo Exit_Function
End Function ' SelectObject V1.1.0
REM -----------------------------------------------------------------------------------------------------------------------
Public Function SendObject(ByVal Optional pvObjectType As Variant _
, ByVal Optional pvObjectName As Variant _
, ByVal Optional pvOutputFormat As Variant _
, ByVal Optional pvTo As Variant _
, ByVal Optional pvCc As Variant _
, ByVal Optional pvBcc As Variant _
, ByVal Optional pvSubject As Variant _
, ByVal Optional pvMessageText As Variant _
, ByVal Optional pvEditMessage As Variant _
, ByVal Optional pvTemplateFile As Variant _
) As Boolean
'Supported: acFormatPDF, acFormatODT, acFormatDOC, acFormatHTML for forms
'To be prepared: acFormatCSV and acFormatODS for tables/queries ?
If _ErrorHandler() Then On Local Error Goto Error_Function
Utils._SetCalledSub("SendObject")
SendObject = False
If IsMissing(pvObjectType) Then pvObjectType = acSendNoObject
If Not Utils._CheckArgument(pvObjectType, 1, Utils._AddNumeric(), Array(acSendNoObject, acSendForm)) Then Goto Exit_Function
If IsMissing(pvObjectName) Then pvObjectName = ""
If Not Utils._CheckArgument(pvObjectName, 2,vbString) Then Goto Exit_Function
If IsMissing(pvOutputFormat) Then pvOutputFormat = ""
If Not Utils._CheckArgument(pvOutputFormat, 3, vbString) Then Goto Exit_Function
If pvOutputFormat <> "" Then
If Not Utils._CheckArgument(UCase(pvOutputFormat), 3, vbString, Array( _
UCase(acFormatPDF), UCase(acFormatODT), UCase(acFormatDOC), UCase(acFormatHTML) _
, "PDF", "ODT", "DOC", "HTML", "" _
)) Then Goto Exit_Function ' A 2nd time to allow case unsensitivity
End If
If IsMissing(pvTo) Then pvTo = ""
If Not Utils._CheckArgument(pvTo, 4, vbString) Then Goto Exit_Function
If IsMissing(pvCc) Then pvCc = ""
If Not Utils._CheckArgument(pvCc, 5, vbString) Then Goto Exit_Function
If IsMissing(pvBcc) Then pvBcc = ""
If Not Utils._CheckArgument(pvBcc, 6, vbString) Then Goto Exit_Function
If IsMissing(pvSubject) Then pvSubject = ""
If Not Utils._CheckArgument(pvSubject, 7, vbString) Then Goto Exit_Function
If IsMissing(pvMessageText) Then pvMessageText = ""
If Not Utils._CheckArgument(pvMessageText, 8, vbString) Then Goto Exit_Function
If IsMissing(pvEditMessage) Then pvEditMessage = True
If Not Utils._CheckArgument(pvEditMessage, 9, vbBoolean) Then Goto Exit_Function
If IsMissing(pvTemplateFile) Then pvTemplateFile = ""
If Not Utils._CheckArgument(pvTemplateFile,10, vbString, "") Then Goto Exit_Function
Dim vTo() As Variant, vCc() As Variant, vBcc() As Variant, oWindow As Object
Dim sDirectory As String, sOutputFile As String, sSuffix As String, sOutputFormat As String
Const cstSemiColon = ";"
If pvTo <> "" Then vTo() = Split(pvTo, cstSemiColon) Else vTo() = Array()
If pvCc <> "" Then vCc() = Split(pvCc, cstSemiColon) Else vCc() = Array()
If pvBcc <> "" Then vBcc() = Split(pvBcc, cstSemiColon) Else vBcc() = Array()
Select Case True
Case pvObjectType = acSendNoObject And pvObjectName = ""
SendObject = _SendWithoutAttachment(vTo, vCc, vBcc, pvSubject, pvMessageText)
Case Else
If pvObjectType = acSendNoObject And pvObjectName <> "" Then
If Not FileExists(pvObjectName) Then Goto Error_File
sOutputFile = pvObjectName
Else ' OutputFile has to be created
If pvObjectType <> acSendNoObject And pvObjectName = "" Then
oWindow = _SelectWindow()
If oWindow.WindowType <> acSendForm Then Goto Error_Action
pvObjectType = acSendForm
pvObjectName = oWindow._Name
End If
sDirectory = _getTempDirectoryURL()
If Right(sDirectory, 1) <> "/" Then sDirectory = sDirectory & "/"
If pvOutputFormat = "" Then
sOutputFormat = _PromptFormat() ' Prompt user for format
If sOutputFormat = "" Then Goto Exit_Function
Else
sOutputFormat = UCase(pvOutputFormat)
End If
Select Case sOutputFormat
Case UCase(acFormatPDF), "PDF" : sSuffix = "pdf"
Case UCase(acFormatDOC), "DOC" : sSuffix = "doc"
Case UCase(acFormatODT), "ODT" : sSuffix = "odt"
Case UCase(acFormatHTML), "HTML" : sSuffix = "html"
End Select
sOutputFile = sDirectory & pvObjectName & "." & sSuffix
If Not OutputTo(pvObjectType, pvObjectName, sOutputFormat, sOutputFile, False) Then Goto Exit_Function
End If
SendObject = _SendWithAttachment(vTo, vCc, vBcc, pvSubject, Array(sOutputFile), pvMessageText, pvEditMessage)
End Select
Exit_Function:
Utils._ResetCalledSub("SendObject")
Exit Function
Error_NotFound:
TraceError(TRACEFATAL, ERROBJECTNOTFOUND, Utils._CalledSub(), 0, , Array(_GetLabel("OBJECT"), pvObjectName))
Goto Exit_Function
Error_Function:
TraceError(TRACEABORT, Err, "SendObject", Erl)
GoTo Exit_Function
Error_Action:
TraceError(TRACEFATAL, ERRACTION, Utils._CalledSub(), 0)
Goto Exit_Function
Error_File:
TraceError(TRACEFATAL, ERRFILEACCESS, Utils._CalledSub(), 0, , pvObjectName)
Goto Exit_Function
End Function ' SendObject V0.8.5
REM -----------------------------------------------------------------------------------------------------------------------
Public Function SetHiddenAttribute(ByVal Optional pvObjectType As Variant _
, ByVal Optional pvObjectName As Variant _
, ByVal Optional pvHidden As Variant _
) As Boolean
If _ErrorHandler() Then On Local Error Goto Error_Function
SetHiddenAttribute = False
Const cstThisSub = "SetHiddenAttribute"
Utils._SetCalledSub(cstThisSub)
If IsMissing(pvObjectType) Then Call _TraceArguments()
If Not Utils._CheckArgument(pvObjectType, 1, Utils._AddNumeric(), _
Array(acDiagram, acForm, acQuery, acTable, acReport, acBasicIDE, acDatabaseWindow), acDocument _
) Then Goto Exit_Function
If IsMissing(pvObjectName) Then
Select Case pvObjectType
Case acForm, acQuery, acTable, acReport, acDocument : Call _TraceArguments()
Case Else
End Select
pvObjectName = ""
Else
If Not Utils._CheckArgument(pvObjectName, 2, vbString) Then Goto Exit_Function
End If
If IsMissing(pvHidden) Then
pvHidden = True
Else
If Not Utils._CheckArgument(pvHidden, 3, vbBoolean) Then Goto Exit_Function
End If
Dim oWindow As Object
Set oWindow = _SelectWindow(pvObjectType, pvObjectName)
If IsNull(oWindow.Frame) Then Goto Error_NotFound
oWindow.Frame.ContainerWindow.setVisible(Not pvHidden)
SetHiddenAttribute = True
Exit_Function:
Utils._ResetCalledSub(cstThisSub)
Exit Function
Error_NotFound:
TraceError(TRACEFATAL, ERROBJECTNOTFOUND, Utils._CalledSub(), 0, , Array(_GetLabel("OBJECT"), pvObjectName))
Goto Exit_Function
Error_Function:
TraceError(TRACEABORT, Err, cstThisSub, Erl)
GoTo Exit_Function
End Function ' SetHiddenAttribute V1.1.0
REM -----------------------------------------------------------------------------------------------------------------------
Public Function ShowAllrecords() As Boolean
' Removes any existing filter that exists on the current table, query or form
Const cstThisSub = "ShowAllRecords"
Utils._SetCalledSub(cstThisSub)
If _ErrorHandler() Then On Local Error Goto Error_Function
ShowAllRecords = False
Dim oWindow As Object, oDatabase As Object
Set oDatabase = Application._CurrentDb()
If oDatabase._DbConnect <> DBCONNECTBASE Then Goto Error_NotApplicable
Set oWindow = _SelectWindow()
Select Case oWindow.WindowType
Case acForm, acQuery, acTable
RunCommand(acCmdRemoveFilterSort)
ShowAllrecords = True
Case Else ' Ignore action
End Select
Exit_Function:
Utils._ResetCalledSub(cstThisSub)
Exit Function
Error_NotApplicable:
TraceError(TRACEFATAL, ERRACTION, Utils._CalledSub(), 0, 1, cstThisSub)
Goto Exit_Function
Error_Function:
TraceError(TRACEABORT, Err, cstThisSub, Erl)
GoTo Exit_Function
End Function ' ShowAllrecords V1.1.0
REM -----------------------------------------------------------------------------------------------------------------------
REM --- PRIVATE FUNCTIONS ---
REM -----------------------------------------------------------------------------------------------------------------------
Private Function _CheckColumnType(pvFindWhat As Variant, vDataField As Variant) As Boolean
' Return true if both arguments of the same type
' vDataField is a ResultSet column
Dim bFound As Boolean
bFound = False
With com.sun.star.sdbc.DataType
Select Case vDataField.Type
Case .DATE, .TIME, .TIMESTAMP
If VarType(pvFindWhat) = vbDate Then bFound = True
Case .TINYINT, .SMALLINT, .INTEGER, .BIGINT, .FLOAT, .REAL, .DOUBLE, .NUMERIC, .DECIMAL
If Utils._InList(VarType(pvFindWhat), Utils._AddNumeric()) Then bFound = True
Case .CHAR, .VARCHAR, .LONGVARCHAR
If VarType(pvFindWhat) = vbString Then bFound = True
Case Else
End Select
End With
_CheckColumnType = bFound
End Function ' _CheckColumnType V0.9.1
REM -----------------------------------------------------------------------------------------------------------------------
Private Function _getTempDirectoryURL() As String
' Return the tempry directory defined in the OO Options (Paths)
Dim sDirectory As String, oSettings As Object, oPathSettings As Object
If _ErrorHandler() Then On Local Error Goto Error_Function
_getTempDirectoryURL = ""
oPathSettings = createUnoService( "com.sun.star.util.PathSettings" )
sDirectory = oPathSettings.GetPropertyValue( "Temp" )
_getTempDirectoryURL = sDirectory
Exit_Function:
Exit Function
Error_Function:
TraceError("ERROR", Err, "_getTempDirectoryURL", Erl)
_getTempDirectoryURL = ""
Goto Exit_Function
End Function ' _getTempDirectoryURL V0.8.5
REM -----------------------------------------------------------------------------------------------------------------------
Public Function _getUpperShortcut(ByVal psShortcut As String, ByVal psLastComponent As String) As String
' Return "Forms!myForm" from "Forms!myForm!datField" and "datField"
If Len(psShortcut) > Len(psLastComponent) Then
_getUpperShortcut = Split(psShortcut, "!" & Utils._Surround(psLastComponent))(0)
Else
_getUpperShortcut = psShortcut
End If
End Function ' _getUpperShortcut
REM -----------------------------------------------------------------------------------------------------------------------
Public Function _MakePropertyValue(ByVal Optional psName As String, ByVal Optional pvValue As Variant) As com.sun.star.beans.PropertyValue
'Build PropertyValue(s) array
Dim oPropertyValue As New com.sun.star.beans.PropertyValue
If Not IsMissing(psName) Then oPropertyValue.Name = psName
If Not IsMissing(pvValue) Then oPropertyValue.Value = pvValue
_MakePropertyValue() = oPropertyValue
End Function ' _MakePropertyValue
REM -----------------------------------------------------------------------------------------------------------------------
Private Function _OpenObject(ByVal psObjectType As String _
, ByVal pvObjectName As Variant _
, ByVal pvView As Variant _
, ByVal pvDataMode As Variant _
) As Boolean
If _ErrorHandler() Then On Local Error Goto Error_Function
_OpenObject = False
If Not (Utils._CheckArgument(pvObjectName, 1, vbString) _
And Utils._CheckArgument(pvView, 2, Utils._AddNumeric(), Array(acViewNormal, acViewPreview, acViewDesign)) _
And Utils._CheckArgument(pvDataMode, 3, Utils._AddNumeric(), Array(acEdit)) _
) Then Goto Exit_Function
Dim oDatabase As Object
Set oDatabase = Application._CurrentDb()
If oDatabase._DbConnect <> DBCONNECTBASE Then Goto Error_NotApplicable
Dim sObjects() As String, sObjectName As String, oController As Object, oObject As Object
Dim i As Integer, bFound As Boolean, lComponent As Long
' Check existence of object and find its exact (case-sensitive) name
Select Case psObjectType
Case "Table"
sObjects = oDatabase.Connection.getTables.ElementNames()
lComponent = com.sun.star.sdb.application.DatabaseObject.TABLE
Case "Query"
sObjects = oDatabase.Connection.getQueries.ElementNames()
lComponent = com.sun.star.sdb.application.DatabaseObject.QUERY
Case "Report"
sObjects = oDatabase.Document.getReportDocuments.ElementNames()
lComponent = com.sun.star.sdb.application.DatabaseObject.REPORT
End Select
bFound = False
For i = 0 To UBound(sObjects)
If UCase(pvObjectName) = UCase(sObjects(i)) Then
sObjectName = sObjects(i)
bFound = True
Exit For
End If
Next i
If Not bFound Then Goto Trace_NotFound
Set oController = oDatabase.Document.CurrentController
Set oObject = oController.loadComponent(lComponent, sObjectName, ( pvView = acViewDesign ))
_OpenObject = True
Exit_Function:
Set oObject = Nothing
Set oController = Nothing
Exit Function
Error_Function:
TraceError(TRACEABORT, Err, "OpenObject", Erl)
GoTo Exit_Function
Trace_Error:
TraceError(TRACEFATAL, ERROPENOBJECT, Utils._CalledSub(), 0, , Array(_GetLabel(psObjectType), pvObjectName))
Goto Exit_Function
Error_NotApplicable:
TraceError(TRACEFATAL, ERRACTION, Utils._CalledSub(), 0, 1)
Goto Exit_Function
Trace_NotFound:
TraceError(TRACEFATAL, ERROBJECTNOTFOUND, Utils._CalledSub(), 0, , Array(_GetLabel(psObjectType), pvObjectName))
Goto Exit_Function
End Function ' _OpenObject V0.8.9
REM -----------------------------------------------------------------------------------------------------------------------
Private Function _PromptFormat() As String
' Return user selection in Format dialog
Dim oDialog As Object, oDialogLib As Object, iOKCancel As Integer, oControl As Object
Set oDialogLib = DialogLibraries
If oDialogLib.hasByName("Access2BaseDev") Then
If Not oDialogLib.IsLibraryLoaded("Access2BaseDev") Then oDialogLib.loadLibrary("Access2BaseDev")
Set oDialog = CreateUnoDialog(DialogLibraries.Access2BaseDev.dlgFormat)
Else
If Not oDialogLib.IsLibraryLoaded("Access2Base") Then oDialogLib.loadLibrary("Access2Base")
Set oDialog = CreateUnoDialog(DialogLibraries.Access2Base.dlgFormat)
End If
oDialog.Title = _GetLabel("DLGFORMAT_TITLE")
Set oControl = oDialog.Model.getByName("lblFormat")
oControl.Label = _GetLabel("DLGFORMAT_LBLFORMAT_LABEL")
oControl.HelpText = _GetLabel("DLGFORMAT_LBLFORMAT_HELP")
Set oControl = oDialog.Model.getByName("cboFormat")
oControl.HelpText = _GetLabel("DLGFORMAT_LBLFORMAT_HELP")
Set oControl = oDialog.Model.getByName("cmdOK")
oControl.Label = _GetLabel("DLGFORMAT_CMDOK_LABEL")
oControl.HelpText = _GetLabel("DLGFORMAT_CMDOK_HELP")
Set oControl = oDialog.Model.getByName("cmdCancel")
oControl.Label = _GetLabel("DLGFORMAT_CMDCANCEL_LABEL")
oControl.HelpText = _GetLabel("DLGFORMAT_CMDCANCEL_HELP")
iOKCancel = oDialog.Execute()
Select Case iOKCancel
Case 1 ' OK
_PromptFormat = oDialog.Model.getByName("cboFormat").Text
Case 0 ' Cancel
_PromptFormat = ""
Case Else
End Select
oDialog.Dispose()
End Function ' _PromptFormat V0.8.5
REM -----------------------------------------------------------------------------------------------------------------------
Public Function _SelectWindow(Optional ByVal piWindowType As Integer, Optional ByVal psWindow As String) As Object
' No argument: find active window
' 2 arguments: find corresponding window
' Return a _Window object type describing the found window
Dim oEnum As Object, oDesk As Object, oComp As Object, oFrame As Object, i As Integer
Dim bFound As Boolean, bActive As Boolean, bName As Boolean, sName As String, iType As Integer
Dim sImplementation As String, vLocation() As Variant
Dim oWindow As _Window
If _ErrorHandler() Then On Local Error Goto Error_Function
bActive = IsMissing(piWindowType)
If IsMissing(psWindow) Then psWindow = ""
Set oWindow.Frame = Nothing
If bActive Then
oWindow.WindowType = -1
oWindow._Name = ""
Else
oWindow.WindowType = piWindowType
Select Case piWindowType
Case acBasicIDE, acDatabaseWindow : oWindow._Name = ""
Case Else : oWindow._Name = psWindow
End Select
End If
Set oDesk = CreateUnoService("com.sun.star.frame.Desktop")
Set oEnum = oDesk.Components().createEnumeration
Do While oEnum.hasMoreElements
Set oComp = oEnum.nextElement
If Utils._hasUNOProperty(oComp, "ImplementationName") Then sImplementation = oComp.ImplementationName Else sImplementation = ""
Select Case sImplementation
Case "com.sun.star.comp.basic.BasicIDE"
Set oFrame = oComp.CurrentController.Frame
iType = acBasicIDE
sName = ""
Case "com.sun.star.comp.dba.ODatabaseDocument"
Set oFrame = oComp.CurrentController.Frame
iType = acDatabaseWindow
sName = ""
Case "SwXTextDocument"
bName = False
If HasUnoInterfaces(oComp, "com.sun.star.frame.XModule") Then
Select Case oComp.Identifier
Case "com.sun.star.sdb.FormDesign" ' Form
iType = acForm
Case "com.sun.star.sdb.TextReportDesign" ' Report
iType = acReport
Case "com.sun.star.text.TextDocument" ' Writer
vLocation = Split(oComp.getLocation(), "/")
sName = Join(Split(vLocation(UBound(vLocation)), "%20"), " ")
bName = True
iType = acDocument
End Select
If Not bName Then ' Identify Form or Report name
For i = 0 To UBound(oComp.Args())
If oComp.Args(i).Name = "DocumentTitle" Then
sName = oComp.Args(i).Value
Exit For
End If
Next i
End If
Set oFrame = oComp.CurrentController.Frame
End If
Case "org.openoffice.comp.dbu.ODatasourceBrowser"
Set oFrame = oComp.Frame
If Not IsEmpty(oComp.Selection) Then ' Empty for (F4) DatasourceBrowser !!
For i = 0 To UBound(oComp.Selection())
If oComp.Selection(i).Name = "Command" Then
sName = oComp.Selection(i).Value
ElseIf oComp.Selection(i).Name = "CommandType" Then
Select Case oComp.selection(i).Value
Case com.sun.star.sdb.CommandType.TABLE
iType = acTable
Case com.sun.star.sdb.CommandType.QUERY
iType = acQuery
Case com.sun.star.sdb.CommandType.COMMAND
iType = acQuery ' SQL for future use ?
End Select
End If
Next i
' Else ignore
End If
Case "org.openoffice.comp.dbu.OTableDesign", "org.openoffice.comp.dbu.OQueryDesign" ' Table or Query in Edit mode
If Not bActive Then
If UCase(Right(oComp.Title, Len(psWindow))) = UCase(psWindow) Then ' No rigorous mean found to identify Name
Set oFrame = oComp.Frame
Select Case sImplementation
Case "org.openoffice.comp.dbu.OTableDesign" : iType = acTable
Case "org.openoffice.comp.dbu.OQueryDesign" : iType = acQuery
End Select
sName = Right(oComp.Title, Len(psWindow))
End If
Else
Set oFrame = Nothing
End If
Case "org.openoffice.comp.dbu.ORelationDesign"
Set oFrame = oComp.Frame
iType = acDiagram
sName = ""
Case Else ' Other Calc, ..., whatever documents
If Utils._hasUNOProperty(oComp, "Location") Then
vLocation = Split(oComp.getLocation(), "/")
sName = Join(Split(vLocation(UBound(vLocation)), "%20"), " ")
iType = acDocument
Set oFrame = oComp.CurrentController.Frame
End If
End Select
If bActive And Not IsNull(oFrame) Then
If oFrame.ContainerWindow.IsActive() Then
bFound = True
Exit Do
End If
ElseIf iType = piWindowType And UCase(sName) = UCase(psWindow) Then
bFound = True
Exit Do
End If
Loop
If bFound Then
Set oWindow.Frame = oFrame
oWindow._Name = sName
oWindow.WindowType = iType
Else
Set oWindow.Frame = Nothing
End If
Exit_Function:
Set _SelectWindow = oWindow
Exit Function
Error_Function:
TraceError(TRACEABORT, Err, "SelectWindow", Erl)
GoTo Exit_Function
End Function ' _SelectWindow V1.1.0
REM -----------------------------------------------------------------------------------------------------------------------
Private Function _SendWithAttachment( _
ByVal pvRecipients() As Variant _
, ByVal pvCcRecipients() As Variant _
, ByVal pvBccRecipients() As Variant _
, ByVal psSubject As String _
, ByVal pvAttachments() As Variant _
, ByVal pvBody As String _
, ByVal pbEditMessage As Boolean _
) As Boolean
' Send message with attachments
If _ErrorHandler() Then On Local Error Goto Error_Function
_SendWithAttachment = False
Const cstWindows = 1
Const cstLinux = 4
Const cstSemiColon = ";"
Dim oServiceMail as Object, oMail As Object, oMessage As Object, vFlag As Variant
Dim vCc() As Variant, i As Integer, iOS As Integer, sProduct As String, bMailProvider As Boolean
'OPENOFFICE <= 3.6 and LIBREOFFICE have XSimple...Mail interface while OPENOFFICE >= 4.0 has XSystemMailProvider interface
sProduct = UCase(Utils._GetProductName())
bMailProvider = ( Left(sProduct, 4) = "OPEN" And Left(_GetProductName("VERSION"), 3) >= "4.0" )
iOS = GetGuiType()
Select Case iOS
Case cstLinux
oServiceMail = createUnoService("com.sun.star.system.SimpleCommandMail")
Case cstWindows
If bMailProvider Then oServiceMail = createUnoService("com.sun.star.system.SystemMailProvider") _
Else oServiceMail = createUnoService("com.sun.star.system.SimpleSystemMail")
Case Else
Goto Error_Mail
End Select
If bMailProvider Then Set oMail = oServiceMail.queryMailClient() _
Else Set oMail = oServiceMail.querySimpleMailClient()
If IsNull(oMail) Then Goto Error_Mail
'Reattribute Recipients >= 2nd to ccRecipients
If UBound(pvRecipients) <= 0 Then
If UBound(pvCcRecipients) >= 0 Then vCc = pvCcRecipients
Else
ReDim vCc(0 To UBound(pvRecipients) - 1 + UBound(pvCcRecipients) + 1)
For i = 0 To UBound(pvRecipients) - 1
vCc(i) = pvRecipients(i + 1)
Next i
For i = UBound(pvRecipients) To UBound(vCc)
vCc(i) = pvCcRecipients(i - UBound(pvRecipients))
Next i
End If
If bMailProvider Then
Set oMessage = oMail.createMailMessage()
If UBound(pvRecipients) >= 0 Then oMessage.Recipient = pvRecipients(0)
If psSubject <> "" Then oMessage.Subject = psSubject
Select Case iOS ' Not published differences between com.sun.star.system.SimpleCommandMail and SimpleSystemMail
Case cstLinux
If UBound(vCc) >= 0 Then oMessage.CcRecipient = Array(Join(vCc, cstSemiColon))
If UBound(pvBccRecipients) >= 0 Then oMessage.BccRecipient = Array(Join(pvBccRecipients, cstSemiColon))
Case cstWindows
If UBound(vCc) >= 0 Then oMessage.CcRecipient = vCc
If UBound(pvBccRecipients) >= 0 Then oMessage.BccRecipient = pvBccRecipients
End Select
If UBound(pvAttachments) >= 0 Then oMessage.Attachement = pvAttachments
If pvBody <> "" Then oMessage.Body = pvBody
If pbEditMessage Then
vFlag = com.sun.star.system.MailClientFlags.DEFAULTS
Else
vFlag = com.sun.star.system.MailClientFlags.NO_USER_INTERFACE
End If
oMail.sendMailMessage(oMessage, vFlag)
Else
Set oMessage = oMail.createSimpleMailMessage() ' Body NOT SUPPORTED !
If UBound(pvRecipients) >= 0 Then oMessage.setRecipient(pvRecipients(0))
If psSubject <> "" Then oMessage.setSubject(psSubject)
Select Case iOS
Case cstLinux
If UBound(vCc) >= 0 Then oMessage.setCcRecipient(Array(Join(vCc, cstSemiColon)))
If UBound(pvBccRecipients) >= 0 Then oMessage.setBccRecipient(Array(Join(pvBccRecipients, cstSemiColon)))
Case cstWindows
If UBound(vCc) >= 0 Then oMessage.setCcRecipient(vCc)
If UBound(pvBccRecipients) >= 0 Then oMessage.setBccRecipient(pvBccRecipients)
End Select
If UBound(pvAttachments) >= 0 Then oMessage.setAttachement(pvAttachments)
If pbEditMessage Then
vFlag = com.sun.star.system.SimpleMailClientFlags.DEFAULTS
Else
vFlag = com.sun.star.system.SimpleMailClientFlags.NO_USER_INTERFACE
End If
oMail.sendSimpleMailMessage(oMessage, vFlag)
End If
_SendWithAttachment = True
Exit_Function:
Exit Function
Error_Function:
TraceError(TRACEABORT, Err, "_SendWithAttachment", Erl)
Goto Exit_Function
Error_Mail:
TraceError(TRACEFATAL, ERRSENDMAIL, Utils._CalledSub(), 0)
Goto Exit_Function
End Function ' _SendWithAttachment V0.9.5
REM -----------------------------------------------------------------------------------------------------------------------
Private Function _SendWithoutAttachment(ByVal pvTo As Variant _
, ByVal pvCc As Variant _
, ByVal pvBcc As Variant _
, ByVal psSubject As String _
, ByVal psBody As String _
) As Boolean
'Send simple message with mailto: syntax
Dim sMailTo As String, sTo As String, sCc As String, sBcc As String, sSubject As String, sBody As String, oDispatch As Object
Const cstComma = ","
Const cstSpace = "%20"
Const cstCR = "%0A"
If _ErrorHandler() Then On Local Error Goto Error_Function
If UBound(pvTo) >= 0 Then sTo = Trim(Join(pvTo, cstComma)) Else sTo = ""
If UBound(pvCc) >= 0 Then sCc = Trim(Join(pvCc, cstComma)) Else sCc = ""
If UBound(pvBcc) >= 0 Then sBcc = Trim(Join(pvBcc, cstComma)) Else sBcc = ""
If psSubject <> "" Then sSubject = Join(Split(psSubject, " "), cstSpace) Else sSubject = ""
If psBody <> "" Then
sBody = Join(Split(psBody, Chr(13)), cstCR)
sBody = Join(Split(sBody, " "), cstSpace)
End If
sMailTo = "mailto:" _
& sTo & "?" _
& Iif(sCc = "", "", "cc=" & sCc & "&") _
& Iif(sBcc = "", "", "bcc=" & sBcc & "&") _
& Iif(sSubject = "", "", "subject=" & sSubject & "&") _
& Iif(sBody = "", "", "body=" & sBody & "&")
If Right(sMailTo, 1) = "&" Or Right(sMailTo, 1) = "?" Then sMailTo = Left(sMailTo, Len(sMailTo) - 1)
oDispatch = createUnoService( "com.sun.star.frame.DispatchHelper")
oDispatch.executeDispatch(StarDesktop, sMailTo, "", 0, Array())
_SendWithoutAttachment = True
Exit_Function:
Exit Function
Error_Function:
TraceError(TRACEABORT, Err, "_SendWithoutAttachments", Erl)
_SendWithoutAttachment = False
Goto Exit_Function
End Function ' _SendWithoutAttachment V0.8.5
REM -----------------------------------------------------------------------------------------------------------------------
Private Sub _ShellExecute(sCommand As String)
' Execute shell command
Dim oShell As Object
Set oShell = createUnoService("com.sun.star.system.SystemShellExecute")
oShell.execute(sCommand, "" , com.sun.star.system.SystemShellExecuteFlags.DEFAULTS)
End Sub ' _ShellExecute V0.8.5
</script:module>
|