/usr/share/gnu-smalltalk/kernel/LookupKey.st is in gnu-smalltalk-common 3.2.5-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 | "======================================================================
|
| LookupKey Method Definitions
|
|
======================================================================"
"======================================================================
|
| Copyright 1999, 2000, 2001, 2002 Free Software Foundation, Inc.
| Written by Paolo Bonzini.
|
| This file is part of the GNU Smalltalk class library.
|
| The GNU Smalltalk class library is free software; you can redistribute it
| and/or modify it under the terms of the GNU Lesser General Public License
| as published by the Free Software Foundation; either version 2.1, or (at
| your option) any later version.
|
| The GNU Smalltalk class library is distributed in the hope that it will be
| useful, but WITHOUT ANY WARRANTY; without even the implied warranty of
| MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser
| General Public License for more details.
|
| You should have received a copy of the GNU Lesser General Public License
| along with the GNU Smalltalk class library; see the file COPYING.LIB.
| If not, write to the Free Software Foundation, 59 Temple Place - Suite
| 330, Boston, MA 02110-1301, USA.
|
======================================================================"
Magnitude subclass: LookupKey [
| key |
<category: 'Language-Data types'>
<comment: 'I represent a key for looking up entries in a data structure. Subclasses
of me, such as Association, typically represent dictionary entries.'>
LookupKey class >> key: aKey [
"Answer a new instance of the receiver with the given key and value"
<category: 'basic'>
^self new key: aKey
]
key: aKey [
"Set the receiver's key to aKey"
<category: 'accessing'>
key := aKey
]
key [
"Answer the receiver's key"
<category: 'accessing'>
^key
]
< aLookupKey [
"Answer whether the receiver's key is less than aLookupKey's"
<category: 'testing'>
^self key < aLookupKey key
]
= aLookupKey [
"Answer whether the receiver's key and value are the same as
aLookupKey's, or false if aLookupKey is not an instance of
the receiver"
<category: 'testing'>
^self class == aLookupKey class and: [self key = aLookupKey key]
]
hash [
"Answer an hash value for the receiver"
<category: 'testing'>
^key hash
]
printOn: aStream [
"Put on aStream a representation of the receiver"
<category: 'printing'>
aStream nextPut: $[.
self key printOn: aStream.
aStream nextPut: $]
]
storeOn: aStream [
"Put on aStream some Smalltalk code compiling to the receiver"
<category: 'storing'>
aStream nextPut: $(.
aStream store: self class.
aStream nextPutAll: ' key: '.
self key storeOn: aStream.
aStream nextPut: $)
]
]
|