/usr/share/gnu-smalltalk/kernel/Message.st is in gnu-smalltalk-common 3.2.5-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 | "======================================================================
|
| Message Method Definitions
|
|
======================================================================"
"======================================================================
|
| Copyright 1988,92,94,95,99,2000,2001,2008
| Free Software Foundation, Inc.
| Written by Steve Byrne.
|
| This file is part of the GNU Smalltalk class library.
|
| The GNU Smalltalk class library is free software; you can redistribute it
| and/or modify it under the terms of the GNU Lesser General Public License
| as published by the Free Software Foundation; either version 2.1, or (at
| your option) any later version.
|
| The GNU Smalltalk class library is distributed in the hope that it will be
| useful, but WITHOUT ANY WARRANTY; without even the implied warranty of
| MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser
| General Public License for more details.
|
| You should have received a copy of the GNU Lesser General Public License
| along with the GNU Smalltalk class library; see the file COPYING.LIB.
| If not, write to the Free Software Foundation, 59 Temple Place - Suite
| 330, Boston, MA 02110-1301, USA.
|
======================================================================"
Object subclass: Message [
| selector args |
<category: 'Language-Implementation'>
<comment: 'I represent a message send. My instances are created to hold a message
that has failed, so that error reporting methods can examine the sender
and arguments, but also to represent method attributes (like
<primitive: 111> since their syntax is isomorphic to that of a
message send.'>
Message class >> selector: aSymbol argument: anObject [
"Create a new Message with the given selector and argument"
<category: 'creating instances'>
^(self new)
selector: aSymbol;
arguments: { anObject }
]
Message class >> selector: aSymbol arguments: anArray [
"Create a new Message with the given selector and arguments"
<category: 'creating instances'>
^(self new)
selector: aSymbol;
arguments: anArray
]
printAsAttributeOn: aStream [
"Print a representation of the receiver on aStream, modeling
it after the source code for a attribute."
<category: 'basic'>
aStream nextPut: $<.
(self selector includes: $:)
ifFalse:
[aStream nextPutAll: self selector.
self arguments do: [:arg | aStream store: arg]]
ifTrue:
[(self selector substrings: $:) with: self arguments
do:
[:sel :arg |
aStream
nextPutAll: sel;
nextPutAll: ': ';
store: arg;
nextPut: $ ]].
aStream nextPut: $>
]
printOn: aStream [
"Print a representation of the receiver on aStream"
<category: 'printing'>
(self selector includes: $:)
ifFalse:
[aStream nextPutAll: self selector.
self arguments do:
[:arg |
aStream
nextPutAll: ' <';
print: arg;
nextPutAll: '> ']]
ifTrue:
[(self selector substrings: $:) with: self arguments
do:
[:sel :arg |
aStream
nextPutAll: sel;
nextPutAll: ': <';
print: arg;
nextPutAll: '> ']]
]
sendTo: aReceiver [
"Resend to aReceiver"
<category: 'printing'>
^aReceiver perform: selector withArguments: args
]
reinvokeFor: aReceiver [
"Resend to aReceiver - present for compatibility"
<category: 'printing'>
^aReceiver perform: selector withArguments: args
]
selector: aSymbol [
"Set the receiver's selector"
<category: 'accessing'>
selector := aSymbol
]
arguments: anArray [
"Set the receiver's arguments"
<category: 'accessing'>
args := anArray
]
selector [
"Answer the receiver's selector"
<category: 'accessing'>
^selector
]
argument [
"Answer the first of the receiver's arguments"
<category: 'accessing'>
^args at: 1
]
arguments [
"Answer the receiver's arguments"
<category: 'accessing'>
^args
]
]
|