/usr/share/gnu-smalltalk/kernel/True.st is in gnu-smalltalk-common 3.2.5-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 | "======================================================================
|
| True Method Definitions
|
|
======================================================================"
"======================================================================
|
| Copyright 1988,92,94,95,99,2000,2001
| Free Software Foundation, Inc.
| Written by Steve Byrne.
|
| This file is part of the GNU Smalltalk class library.
|
| The GNU Smalltalk class library is free software; you can redistribute it
| and/or modify it under the terms of the GNU Lesser General Public License
| as published by the Free Software Foundation; either version 2.1, or (at
| your option) any later version.
|
| The GNU Smalltalk class library is distributed in the hope that it will be
| useful, but WITHOUT ANY WARRANTY; without even the implied warranty of
| MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser
| General Public License for more details.
|
| You should have received a copy of the GNU Lesser General Public License
| along with the GNU Smalltalk class library; see the file COPYING.LIB.
| If not, write to the Free Software Foundation, 59 Temple Place - Suite
| 330, Boston, MA 02110-1301, USA.
|
======================================================================"
Boolean subclass: True [
| truthValue |
<category: 'Language-Data types'>
<comment: 'I represent truth and justice in the world. My motto is "semper veritatis".'>
asCBooleanValue [
<category: 'C hacks'>
^1
]
ifTrue: trueBlock ifFalse: falseBlock [
"We are true -- evaluate trueBlock"
<category: 'basic'>
^trueBlock value
]
ifFalse: falseBlock ifTrue: trueBlock [
"We are true -- evaluate trueBlock"
<category: 'basic'>
^trueBlock value
]
ifTrue: trueBlock [
"We are true -- evaluate trueBlock"
<category: 'basic'>
^trueBlock value
]
ifFalse: falseBlock [
"We are true -- answer nil"
<category: 'basic'>
^nil
]
not [
"We are true -- answer false"
<category: 'basic'>
^false
]
& aBoolean [
"We are true -- anded with anything, we always answer the other operand"
<category: 'basic'>
^aBoolean
]
| aBoolean [
"We are true -- ored with anything, we always answer true"
<category: 'basic'>
^true
]
eqv: aBoolean [
"Answer whether the receiver and aBoolean represent the
same boolean value"
<category: 'basic'>
^aBoolean
]
xor: aBoolean [
"Answer whether the receiver and aBoolean represent different
boolean values"
<category: 'basic'>
^aBoolean not
]
and: aBlock [
"We are true -- anded with anything, we always answer the other operand,
so evaluate aBlock"
<category: 'basic'>
^aBlock value
]
or: aBlock [
"We are true -- ored with anything, we always answer true"
<category: 'basic'>
^true
]
printOn: aStream [
"Print a representation of the receiver on aStream"
<category: 'printing'>
aStream nextPutAll: 'true'
]
]
|