/usr/share/perl5/Mojo.pm is in libmojolicious-perl 7.21+dfsg-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 | package Mojo;
use Mojo::Base -base;
# "Professor: These old Doomsday devices are dangerously unstable. I'll rest
# easier not knowing where they are."
use Carp ();
use Mojo::Home;
use Mojo::Log;
use Mojo::Transaction::HTTP;
use Mojo::UserAgent;
use Mojo::Util;
use Scalar::Util ();
has home => sub { Mojo::Home->new->detect(ref shift) };
has log => sub { Mojo::Log->new };
has ua => sub {
my $ua = Mojo::UserAgent->new;
Scalar::Util::weaken $ua->server->app(shift)->{app};
return $ua;
};
sub build_tx { Mojo::Transaction::HTTP->new }
sub config { Mojo::Util::_stash(config => @_) }
sub handler { Carp::croak 'Method "handler" not implemented in subclass' }
1;
=encoding utf8
=head1 NAME
Mojo - Web development toolkit
=head1 SYNOPSIS
package MyApp;
use Mojo::Base 'Mojo';
# All the complexities of CGI, PSGI, HTTP and WebSockets get reduced to a
# single method call!
sub handler {
my ($self, $tx) = @_;
# Request
my $method = $tx->req->method;
my $path = $tx->req->url->path;
# Response
$tx->res->code(200);
$tx->res->headers->content_type('text/plain');
$tx->res->body("$method request for $path!");
# Resume transaction
$tx->resume;
}
=head1 DESCRIPTION
A powerful web development toolkit, with all the basic tools and helpers needed
to write simple web applications and higher level web frameworks, such as
L<Mojolicious>. Some of the most commonly used tools are L<Mojo::UserAgent>,
L<Mojo::DOM>, L<Mojo::JSON>, L<Mojo::Server::Daemon>, L<Mojo::Server::Prefork>,
L<Mojo::IOLoop> and L<Mojo::Template>.
See L<Mojolicious::Guides> for more!
=head1 ATTRIBUTES
L<Mojo> implements the following attributes.
=head2 home
my $home = $app->home;
$app = $app->home(Mojo::Home->new);
The home directory of your application, defaults to a L<Mojo::Home> object
which stringifies to the actual path.
# Portably generate path relative to home directory
my $path = $app->home->child('data', 'important.txt');
=head2 log
my $log = $app->log;
$app = $app->log(Mojo::Log->new);
The logging layer of your application, defaults to a L<Mojo::Log> object.
# Log debug message
$app->log->debug('It works');
=head2 ua
my $ua = $app->ua;
$app = $app->ua(Mojo::UserAgent->new);
A full featured HTTP user agent for use in your applications, defaults to a
L<Mojo::UserAgent> object.
# Perform blocking request
say $app->ua->get('example.com')->res->body;
=head1 METHODS
L<Mojo> inherits all methods from L<Mojo::Base> and implements the following
new ones.
=head2 build_tx
my $tx = $app->build_tx;
Transaction builder, defaults to building a L<Mojo::Transaction::HTTP> object.
=head2 config
my $hash = $app->config;
my $foo = $app->config('foo');
$app = $app->config({foo => 'bar', baz => 23});
$app = $app->config(foo => 'bar', baz => 23);
Application configuration.
# Remove value
my $foo = delete $app->config->{foo};
# Assign multiple values at once
$app->config(foo => 'test', bar => 23);
=head2 handler
$app->handler(Mojo::Transaction::HTTP->new);
The handler is the main entry point to your application or framework and will
be called for each new transaction, which will usually be a
L<Mojo::Transaction::HTTP> or L<Mojo::Transaction::WebSocket> object. Meant to
be overloaded in a subclass.
sub handler {
my ($self, $tx) = @_;
...
}
=head1 SEE ALSO
L<Mojolicious>, L<Mojolicious::Guides>, L<http://mojolicious.org>.
=cut
|