/usr/share/perl5/Tree/Simple/Visitor/ToNestedArray.pm is in libtree-simple-visitorfactory-perl 0.15-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 | package Tree::Simple::Visitor::ToNestedArray;
use strict;
use warnings;
our $VERSION = '0.15';
use Scalar::Util qw(blessed);
use base qw(Tree::Simple::Visitor);
sub new {
my ($_class) = @_;
my $class = ref($_class) || $_class;
my $visitor = {};
bless($visitor, $class);
$visitor->_init();
return $visitor;
}
sub visit {
my ($self, $tree) = @_;
(blessed($tree) && $tree->isa("Tree::Simple"))
|| die "Insufficient Arguments : You must supply a valid Tree::Simple object";
# grab our filter (if we have one)
my $filter = $self->getNodeFilter();
my @results;
# get the array
$self->_buildArray($tree, \@results, $filter);
# add the trunk if we need to
@results = (
((defined($filter)) ?
$filter->($tree)
:
$tree->getNodeValue()),
[ @results ]
) if $self->includeTrunk();
# set results
$self->setResults(\@results);
}
sub _buildArray {
my ($self, $tree, $accumulator, $filter) = @_;
foreach my $child ($tree->getAllChildren()) {
push @{$accumulator} => (defined($filter) ? $filter->($child) : $child->getNodeValue());
push @{$accumulator} => $self->_buildArray($child, [], $filter) unless $child->isLeaf();
}
return $accumulator;
}
1;
__END__
=head1 NAME
Tree::Simple::Visitor::ToNestedArray - A Visitor for creating nested array trees from Tree::Simple objects.
=head1 SYNOPSIS
use Tree::Simple::Visitor::ToNestedArray;
my $visitor = Tree::Simple::Visitor::ToNestedArray->new();
# given this Tree::Simple tree
my $tree = Tree::Simple->new("Root")
->addChildren(
Tree::Simple->new("Child1")
->addChildren(
Tree::Simple->new("GrandChild1"),
Tree::Simple->new("GrandChild2")
),
Tree::Simple->new("Child2"),
);
# include the trunk (Root)
$visitor->includeTrunk(1);
# visit the tree
$tree->accept($visitor);
my $array_tree = $visitor->getResults();
# this then creates the equivalent nested array tree:
# [
# 'Root', [
# 'Child1', [
# 'GrandChild1',
# 'GrandChild2'
# ],
# 'Child2'
# ]
# ]
# if you don't include the trunk (Root) then ...
$tree->accept($visitor);
my $array_tree = $visitor->getResults();
# this then creates the following nested array tree:
# [
# 'Child1', [
# 'GrandChild1',
# 'GrandChild2'
# ],
# 'Child2'
# ]
=head1 DESCRIPTION
Given a tree constructed from a Tree::Simple hierarchy, this Visitor will create the equivalent tree of nested arrays.
=head1 METHODS
=over 4
=item B<new>
There are no arguments to the constructor the object will be in its default state. You can use the C<setNodeFilter> and C<includTrunk> methods to customize its behavior.
=item B<includTrunk ($boolean)>
Setting the C<$boolean> value to true (C<1>) will cause the node value of the tree's root to be included in the nested array output, setting it to false will do the opposite.
=item B<setNodeFilter ($filter_function)>
This method accepts a CODE reference as its C<$filter_function> argument and throws an exception if it is not a code reference. This code reference is used to filter the tree nodes as they are placed into the array tree. The C<$filter_function> is passed a Tree::Simple object, and is expected to return the value desired for inclusion into the array tree.
=item B<visit ($tree)>
This is the method that is used by Tree::Simple's C<accept> method. It can also be used on its own, it requires the C<$tree> argument to be a Tree::Simple object (or derived from a Tree::Simple object), and will throw and exception otherwise.
=item B<getResults>
This method will return the array tree constructed.
=back
=head1 BUGS
None that I am aware of. Of course, if you find a bug, let me know, and I will be sure to fix it.
=head1 CODE COVERAGE
See the B<CODE COVERAGE> section in L<Tree::Simple::VisitorFactory> for more information.
=head1 SEE ALSO
These Visitor classes are all subclasses of B<Tree::Simple::Visitor>, which can be found in the B<Tree::Simple> module, you should refer to that module for more information.
=head1 AUTHOR
stevan little, E<lt>stevan@iinteractive.comE<gt>
=head1 COPYRIGHT AND LICENSE
Copyright 2004, 2005 by Infinity Interactive, Inc.
L<http://www.iinteractive.com>
This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.
=cut
|