/usr/share/perl5/Type/Tiny/Enum.pm is in libtype-tiny-perl 1.000005-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 | package Type::Tiny::Enum;
use 5.006001;
use strict;
use warnings;
BEGIN {
$Type::Tiny::Enum::AUTHORITY = 'cpan:TOBYINK';
$Type::Tiny::Enum::VERSION = '1.000005';
}
sub _croak ($;@) { require Error::TypeTiny; goto \&Error::TypeTiny::croak }
use overload q[@{}] => 'values';
use Type::Tiny ();
our @ISA = 'Type::Tiny';
sub new
{
my $proto = shift;
my %opts = (@_==1) ? %{$_[0]} : @_;
_croak "Enum type constraints cannot have a parent constraint passed to the constructor" if exists $opts{parent};
_croak "Enum type constraints cannot have a constraint coderef passed to the constructor" if exists $opts{constraint};
_croak "Enum type constraints cannot have a inlining coderef passed to the constructor" if exists $opts{inlined};
_croak "Need to supply list of values" unless exists $opts{values};
my %tmp =
map { $_ => 1 }
@{ ref $opts{values} eq "ARRAY" ? $opts{values} : [$opts{values}] };
$opts{values} = [sort keys %tmp];
if (Type::Tiny::_USE_XS and not grep /[^-\w]/, @{$opts{values}})
{
my $enum = join ",", @{$opts{values}};
my $xsub = Type::Tiny::XS::get_coderef_for("Enum[$enum]");
$opts{compiled_type_constraint} = $xsub if $xsub;
}
return $proto->SUPER::new(%opts);
}
sub values { $_[0]{values} }
sub constraint { $_[0]{constraint} ||= $_[0]->_build_constraint }
sub _build_display_name
{
my $self = shift;
sprintf("Enum[%s]", join q[,], @$self);
}
sub _build_constraint
{
my $self = shift;
my $regexp = join "|", map quotemeta, @$self;
return sub { defined and m{\A(?:$regexp)\z} };
}
sub can_be_inlined
{
!!1;
}
sub inline_check
{
my $self = shift;
if (Type::Tiny::_USE_XS)
{
my $enum = join ",", @{$self->values};
my $xsub = Type::Tiny::XS::get_subname_for("Enum[$enum]");
return "$xsub\($_[0]\)" if $xsub;
}
my $regexp = join "|", map quotemeta, @$self;
$_[0] eq '$_'
? "(defined and !ref and m{\\A(?:$regexp)\\z})"
: "(defined($_[0]) and !ref($_[0]) and $_[0] =~ m{\\A(?:$regexp)\\z})";
}
sub _instantiate_moose_type
{
my $self = shift;
my %opts = @_;
delete $opts{parent};
delete $opts{constraint};
delete $opts{inlined};
require Moose::Meta::TypeConstraint::Enum;
return "Moose::Meta::TypeConstraint::Enum"->new(%opts, values => $self->values);
}
sub has_parent
{
!!1;
}
sub parent
{
require Types::Standard;
Types::Standard::Str();
}
sub validate_explain
{
my $self = shift;
my ($value, $varname) = @_;
$varname = '$_' unless defined $varname;
return undef if $self->check($value);
require Type::Utils;
!defined($value) ? [
sprintf(
'"%s" requires that the value is defined',
$self,
),
] :
@$self < 13 ? [
sprintf(
'"%s" requires that the value is equal to %s',
$self,
Type::Utils::english_list(\"or", map B::perlstring($_), @$self),
),
] :
[
sprintf(
'"%s" requires that the value is one of an enumerated list of strings',
$self,
),
];
}
1;
__END__
=pod
=encoding utf-8
=head1 NAME
Type::Tiny::Enum - string enum type constraints
=head1 STATUS
This module is covered by the
L<Type-Tiny stability policy|Type::Tiny::Manual::Policies/"STABILITY">.
=head1 DESCRIPTION
Enum type constraints.
This package inherits from L<Type::Tiny>; see that for most documentation.
Major differences are listed below:
=head2 Attributes
=over
=item C<values>
Arrayref of allowable value strings. Non-string values (e.g. objects with
overloading) will be stringified in the constructor.
=item C<constraint>
Unlike Type::Tiny, you I<cannot> pass a constraint coderef to the constructor.
Instead rely on the default.
=item C<inlined>
Unlike Type::Tiny, you I<cannot> pass an inlining coderef to the constructor.
Instead rely on the default.
=item C<parent>
Parent is always Types::Standard::Str, and cannot be passed to the
constructor.
=back
=head2 Overloading
=over
=item *
Arrayrefification calls C<values>.
=back
=head1 BUGS
Please report any bugs to
L<http://rt.cpan.org/Dist/Display.html?Queue=Type-Tiny>.
=head1 SEE ALSO
L<Type::Tiny::Manual>.
L<Type::Tiny>.
L<Moose::Meta::TypeConstraint::Enum>.
=head1 AUTHOR
Toby Inkster E<lt>tobyink@cpan.orgE<gt>.
=head1 COPYRIGHT AND LICENCE
This software is copyright (c) 2013-2014 by Toby Inkster.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=head1 DISCLAIMER OF WARRANTIES
THIS PACKAGE IS PROVIDED "AS IS" AND WITHOUT ANY EXPRESS OR IMPLIED
WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
MERCHANTIBILITY AND FITNESS FOR A PARTICULAR PURPOSE.
|