/usr/lib/obs/server/BSSSL.pm is in obs-server 2.7.1-10.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 | #
# Copyright (c) 2007 Michael Schroeder, Novell Inc.
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License version 2 as
# published by the Free Software Foundation.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program (see the file COPYING); if not, write to the
# Free Software Foundation, Inc.,
# 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA
#
################################################################
#
# SSL Socket wrapper. Like Net::SSLeay::Handle, but can tie
# inplace and also supports servers. Plus, it uses the more useful
# Net::SSLeay::read instead of Net::SSLeay::ssl_read_all.
#
package BSSSL;
use Socket;
use Net::SSLeay;
use strict;
my $sslctx;
sub initctx {
my ($keyfile, $certfile) = @_;
Net::SSLeay::load_error_strings();
Net::SSLeay::SSLeay_add_ssl_algorithms();
Net::SSLeay::randomize();
$sslctx = Net::SSLeay::CTX_new() or die("CTX_new failed!\n");
Net::SSLeay::CTX_set_options($sslctx, &Net::SSLeay::OP_ALL);
if ($keyfile) {
Net::SSLeay::CTX_use_RSAPrivateKey_file($sslctx, $keyfile, &Net::SSLeay::FILETYPE_PEM) || die("RSAPrivateKey $keyfile failed\n");
}
if ($certfile) {
Net::SSLeay::CTX_use_certificate_file($sslctx, $certfile, &Net::SSLeay::FILETYPE_PEM) || die("certificate $keyfile failed\n");
}
}
sub freectx {
Net::SSLeay::CTX_free($sslctx);
undef $sslctx;
}
sub tossl {
local *S = $_[0];
tie(*S, 'BSSSL', @_);
}
sub TIEHANDLE {
my ($self, $socket, $keyfile, $certfile, $forceconnect) = @_;
initctx() unless $sslctx;
my $ssl = Net::SSLeay::new($sslctx) or die("SSL_new failed\n");
Net::SSLeay::set_fd($ssl, fileno($socket));
if ($keyfile) {
Net::SSLeay::use_RSAPrivateKey_file($ssl, $keyfile, &Net::SSLeay::FILETYPE_PEM) || die("RSAPrivateKey $keyfile failed\n");
}
if ($certfile) {
Net::SSLeay::use_certificate_file($ssl, $certfile, &Net::SSLeay::FILETYPE_PEM) || die("certificate $certfile failed\n");
}
if (defined($keyfile) && !$forceconnect) {
Net::SSLeay::accept($ssl) == 1 || die("SSL_accept\n");
} else {
Net::SSLeay::connect($ssl) || die("SSL_connect");
}
return bless [$ssl, $socket];
}
sub PRINT {
my $sslr = shift;
my $r = 0;
for my $msg (@_) {
next unless defined $msg;
$r = Net::SSLeay::write($sslr->[0], $msg) or last;
}
return $r;
}
sub READLINE {
my ($sslr) = @_;
return Net::SSLeay::ssl_read_until($sslr->[0]);
}
sub READ {
my ($sslr, undef, $len, $offset) = @_;
my $buf = \$_[1];
my $r = Net::SSLeay::read($sslr->[0], $len);
return undef unless defined $r;
return length($$buf = $r) unless defined $offset;
my $bl = length($$buf);
$$buf .= chr(0) x ($offset - $bl) if $offset > $bl;
substr($$buf, $offset) = $r;
return length($r);
}
sub WRITE {
my ($sslr, $buf, $len, $offset) = @_;
return $len unless $len;
return Net::SSLeay::write($sslr->[0], substr($buf, $offset || 0, $len)) ? $len : undef;
}
sub FILENO {
my ($sslr) = @_;
return Net::SSLeay::get_fd($sslr->[0]);
}
sub CLOSE {
my ($sslr) = @_;
if (tied($sslr->[1]) && tied($sslr->[1]) eq $sslr) {
untie($sslr->[1]);
close($sslr->[1]);
} else {
Net::SSLeay::free($sslr->[0]);
undef $sslr->[0];
}
undef $sslr->[1];
}
sub UNTIE {
my ($sslr) = @_;
Net::SSLeay::free($sslr->[0]);
undef $sslr->[0];
}
sub DESTROY {
my ($sslr) = @_;
UNTIE($sslr) if $sslr && $sslr->[0];
}
sub peerfingerprint {
my ($sslr, $type) = @_;
my $cert = Net::SSLeay::get_peer_certificate($sslr->[0]);
return undef unless $cert;
my $fp = Net::SSLeay::X509_get_fingerprint($cert, lc($type));
Net::SSLeay::X509_free($cert);
return undef unless $fp;
$fp =~ s/://g;
return lc($fp);
}
1;
|