/usr/share/ada/adainclude/aws/aws-net-websocket.adb is in libaws3.3.2-dev 3.3.2-2.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 | ------------------------------------------------------------------------------
-- Ada Web Server --
-- --
-- Copyright (C) 2012-2015, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or modify --
-- it under terms of the GNU General Public License as published by the --
-- Free Software Foundation; either version 3, or (at your option) any --
-- later version. This library is distributed in the hope that it will be --
-- useful, but WITHOUT ANY WARRANTY; without even the implied warranty of --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. --
-- --
-- As a special exception under Section 7 of GPL version 3, you are --
-- granted additional permissions described in the GCC Runtime Library --
-- Exception, version 3.1, as published by the Free Software Foundation. --
-- --
-- You should have received a copy of the GNU General Public License and --
-- a copy of the GCC Runtime Library Exception along with this program; --
-- see the files COPYING3 and COPYING.RUNTIME respectively. If not, see --
-- <http://www.gnu.org/licenses/>. --
-- --
-- As a special exception, if other files instantiate generics from this --
-- unit, or you link this unit with other files to produce an executable, --
-- this unit does not by itself cause the resulting executable to be --
-- covered by the GNU General Public License. This exception does not --
-- however invalidate any other reasons why the executable file might be --
-- covered by the GNU Public License. --
------------------------------------------------------------------------------
with Ada.Unchecked_Deallocation;
with AWS.Headers;
with AWS.Messages;
with AWS.Net.WebSocket.Protocol.Draft76;
with AWS.Net.WebSocket.Protocol.RFC6455;
with AWS.Translator;
package body AWS.Net.WebSocket is
WS_UID : Utils.Counter (0);
-- Unique Id for the WebSockets
type Protocol_State is record
State : Net.WebSocket.Protocol.State_Class;
end record;
-----------
-- Close --
-----------
procedure Close
(Socket : in out Object;
Message : String;
Error : Error_Type := Normal_Closure) is
begin
Socket.P_State.State.Close (Socket, Message, Error_Code (Error));
end Close;
------------
-- Create --
------------
function Create
(Socket : Socket_Access;
Request : AWS.Status.Data) return Object'Class
is
Headers : constant AWS.Headers.List := AWS.Status.Header (Request);
Version : Natural := 0;
Protocol : Net.WebSocket.Protocol.State_Class;
WS_UID_Value : Natural := 0;
begin
if Headers.Exist (Messages.Sec_WebSocket_Key1_Token)
and then Headers.Exist (Messages.Sec_WebSocket_Key2_Token)
then
Protocol := new Net.WebSocket.Protocol.Draft76.State;
else
Protocol := new Net.WebSocket.Protocol.RFC6455.State;
end if;
if Headers.Exist (Messages.Sec_WebSocket_Version_Token) then
declare
Value : constant String :=
Headers.Get (Messages.Sec_WebSocket_Version_Token);
begin
if Utils.Is_Number (Value) then
Version := Natural'Value (Value);
end if;
end;
end if;
WS_UID.Increment (Value => WS_UID_Value);
return Object'
(Net.Socket_Type with
Socket => Socket,
Id => UID (WS_UID_Value),
Request => Request,
Version => Version,
State => new Internal_State'
(Kind => Unknown,
Errno => Interfaces.Unsigned_16'Last,
Last_Activity => Calendar.Clock),
P_State => new Protocol_State'(State => Protocol));
end Create;
--------------------
-- End_Of_Message --
--------------------
function End_Of_Message (Socket : Object) return Boolean is
begin
return Socket.P_State.State.End_Of_Message;
end End_Of_Message;
-----------
-- Errno --
-----------
overriding function Errno (Socket : Object) return Integer is
use type Interfaces.Unsigned_16;
E : constant Interfaces.Unsigned_16 := Socket.State.Errno;
begin
if E = Interfaces.Unsigned_16'Last then
return Socket.Socket.Errno;
else
Socket.State.Errno := Interfaces.Unsigned_16'Last;
return Integer (E);
end if;
end Errno;
-----------
-- Error --
-----------
function Error (Socket : Object) return Error_Type is
begin
case Socket.State.Errno is
when 1000 => return Normal_Closure;
when 1001 => return Going_Away;
when 1002 => return Protocol_Error;
when 1003 => return Unsupported_Data;
when 1005 => return No_Status_Received;
when 1006 => return Abnormal_Closure;
when 1007 => return Invalid_Frame_Payload_Data;
when 1008 => return Policy_Violation;
when 1009 => return Message_Too_Big;
when 1010 => return Mandatory_Extension;
when 1011 => return Internal_Server_Error;
when 1015 => return TLS_Handshake;
when others => return Cannot_Resolve_Error;
end case;
end Error;
----------
-- Free --
----------
overriding procedure Free (Socket : in out Object) is
procedure Unchecked_Free is
new Unchecked_Deallocation (Internal_State, Internal_State_Access);
procedure Unchecked_Free is
new Unchecked_Deallocation (Protocol_State, Protocol_State_Access);
procedure Unchecked_Free is new Unchecked_Deallocation
(Net.WebSocket.Protocol.State'Class,
Net.WebSocket.Protocol.State_Class);
begin
Unchecked_Free (Socket.State);
if Socket.P_State /= null then
Unchecked_Free (Socket.P_State.State);
Unchecked_Free (Socket.P_State);
end if;
end Free;
--------------
-- Get_Addr --
--------------
overriding function Get_Addr (Socket : Object) return String is
begin
return Socket.Socket.Get_Addr;
end Get_Addr;
------------
-- Get_FD --
------------
overriding function Get_FD (Socket : Object) return FD_Type is
begin
return Socket.Socket.Get_FD;
end Get_FD;
--------------
-- Get_Port --
--------------
overriding function Get_Port (Socket : Object) return Positive is
begin
return Socket.Socket.Get_Port;
end Get_Port;
-----------------------------
-- Get_Receive_Buffer_Size --
-----------------------------
overriding function Get_Receive_Buffer_Size
(Socket : Object) return Natural is
begin
return Socket.Socket.Get_Receive_Buffer_Size;
end Get_Receive_Buffer_Size;
--------------------------
-- Get_Send_Buffer_Size --
--------------------------
overriding function Get_Send_Buffer_Size (Socket : Object) return Natural is
begin
return Socket.Socket.Get_Send_Buffer_Size;
end Get_Send_Buffer_Size;
-------------
-- Get_UID --
-------------
function Get_UID (Socket : Object) return UID is
begin
return Socket.Id;
end Get_UID;
------------------
-- Is_Listening --
------------------
overriding function Is_Listening (Socket : Object) return Boolean is
pragma Unreferenced (Socket);
begin
return False;
end Is_Listening;
----------
-- Kind --
----------
function Kind (Socket : Object) return Kind_Type is
begin
return Socket.State.Kind;
end Kind;
----------------
-- On_Message --
----------------
procedure On_Message (Socket : in out Object; Message : Unbounded_String) is
begin
On_Message (Object'Class (Socket), To_String (Message));
end On_Message;
------------
-- Origin --
------------
function Origin (Socket : Object) return String is
begin
return Headers.Get
(AWS.Status.Header (Socket.Request), Messages.Origin_Token);
end Origin;
---------------
-- Peer_Addr --
---------------
overriding function Peer_Addr (Socket : Object) return String is
begin
return Socket.Socket.Peer_Addr;
end Peer_Addr;
---------------
-- Peer_Port --
---------------
overriding function Peer_Port (Socket : Object) return Positive is
begin
return Socket.Socket.Peer_Port;
end Peer_Port;
-------------
-- Pending --
-------------
overriding function Pending
(Socket : Object) return Stream_Element_Count is
begin
return Socket.Socket.Pending;
end Pending;
----------------------
-- Protocol_Version --
----------------------
function Protocol_Version (Socket : Object) return Natural is
begin
return Socket.Version;
end Protocol_Version;
-------------
-- Receive --
-------------
overriding procedure Receive
(Socket : Object;
Data : out Stream_Element_Array;
Last : out Stream_Element_Offset) is
begin
Socket.P_State.State.Receive (Socket, Data, Last);
Socket.State.Last_Activity := Calendar.Clock;
end Receive;
-------------
-- Request --
-------------
function Request (Socket : Object) return AWS.Status.Data is
begin
return Socket.Request;
end Request;
----------
-- Send --
----------
overriding procedure Send
(Socket : Object;
Data : Stream_Element_Array;
Last : out Stream_Element_Offset) is
begin
Socket.Socket.Send (Data, Last);
Socket.State.Last_Activity := Calendar.Clock;
end Send;
procedure Send
(Socket : in out Object;
Message : String;
Is_Binary : Boolean := False) is
begin
if Is_Binary then
Socket.State.Kind := Binary;
else
Socket.State.Kind := Text;
end if;
Socket.P_State.State.Send
(Socket, Translator.To_Stream_Element_Array (Message));
end Send;
procedure Send
(Socket : in out Object;
Message : Unbounded_String;
Is_Binary : Boolean := False) is
begin
if Is_Binary then
Socket.State.Kind := Binary;
else
Socket.State.Kind := Text;
end if;
Socket.P_State.State.Send (Socket, Message);
end Send;
procedure Send
(Socket : in out Object;
Message : Stream_Element_Array;
Is_Binary : Boolean := True) is
begin
if Is_Binary then
Socket.State.Kind := Binary;
else
Socket.State.Kind := Text;
end if;
Socket.P_State.State.Send (Socket, Message);
end Send;
--------------
-- Shutdown --
--------------
overriding procedure Shutdown
(Socket : Object;
How : Shutmode_Type := Shut_Read_Write) is
begin
Socket.Socket.Shutdown (How);
end Shutdown;
---------
-- URI --
---------
function URI (Socket : Object) return String is
begin
return AWS.Status.URI (Socket.Request);
end URI;
end AWS.Net.WebSocket;
|