/usr/lib/x86_64-linux-gnu/perl5/5.24/Devel/Cover/DB/IO/JSON.pm is in libdevel-cover-perl 1.23-2+b1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 | # Copyright 2011-2016, Paul Johnson (paul@pjcj.net)
# This software is free. It is licensed under the same terms as Perl itself.
# The latest version of this software should be available from my homepage:
# http://www.pjcj.net
package Devel::Cover::DB::IO::JSON;
use strict;
use warnings;
use Fcntl ":flock";
our $VERSION = '1.23'; # VERSION
my $Format;
BEGIN {
$Format = "JSON" if eval "use JSON; 1";
$Format = "JSON::PP" if !$Format and eval "use JSON::PP; 1";
die "Can't load either JSON or JSON::PP" unless $Format;
}
sub new {
my $class = shift;
my $self = { options => "", @_ };
bless $self, $class
}
sub read {
my $self = shift;
my ($file) = @_;
open my $fh, "<", $file or die "Can't open $file: $!\n";
flock $fh, LOCK_SH or die "Can't lock $file: $!\n";
local $/;
my $data;
eval {
$data = $Format eq "JSON"
? JSON::decode_json(<$fh>)
: JSON::PP::decode_json(<$fh>);
};
die "Can't read $file with $Format: $@" if $@;
close $fh or die "Can't close $file: $!\n";
$data
}
sub write {
my $self = shift;
my ($data, $file) = @_;
my $json = $Format eq "JSON" ? JSON->new : JSON::PP->new;
$json->utf8->allow_blessed;
$json->ascii->pretty->canonical if $self->{options} =~ /\bpretty\b/i;
open my $fh, ">", $file or die "Can't open $file: $!\n";
flock $fh, LOCK_EX or die "Can't lock $file: $!\n";
print $fh $json->encode($data);
close $fh or die "Can't close $file: $!\n";
$self
}
1
__END__
=head1 NAME
Devel::Cover::DB::IO::JSON - JSON based IO routines for Devel::Cover::DB
=head1 VERSION
version 1.23
=head1 SYNOPSIS
use Devel::Cover::DB::IO::JSON;
my $io = Devel::Cover::DB::IO::JSON->new;
my $data = $io->read($file);
$io->write($data, $file);
=head1 DESCRIPTION
This module provides JSON based IO routines for Devel::Cover::DB.
=head1 SEE ALSO
Devel::Cover
=head1 METHODS
=head2 new
my $io = Devel::Cover::DB::IO::JSON->new;
Constructs the IO object.
=head2 read
my $data = $io->read($file);
Returns a perl data structure representing the data read from $file.
=head2 write
$io->write($data, $file);
Writes $data to $file in the format specified when creating $io.
=head1 BUGS
Huh?
=head1 LICENCE
Copyright 2011-2016, Paul Johnson (paul@pjcj.net)
This software is free. It is licensed under the same terms as Perl itself.
The latest version of this software should be available from my homepage:
http://www.pjcj.net
=cut
|