/usr/lib/x86_64-linux-gnu/perl5/5.24/FFI/Platypus/Record.pm is in libffi-platypus-perl 0.45-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 | package FFI::Platypus::Record;
use strict;
use warnings;
use Carp qw( croak );
use FFI::Platypus;
use base qw( Exporter );
use constant 1.32 ();
our @EXPORT = qw( record_layout );
# ABSTRACT: FFI support for structured records data
our $VERSION = '0.45'; # VERSION
sub record_layout
{
my $ffi = ref($_[0]) ? shift : FFI::Platypus->new;
my $offset = 0;
my $record_align = 0;
croak "uneven number of arguments!" if scalar(@_) % 2;
my($caller, $filename, $line) = caller;
if($caller->can("_ffi_record_size")
|| $caller->can("ffi_record_size"))
{
croak "record already defined for the class $caller";
}
my @destroy;
while(@_)
{
my $type = shift;
my $name = shift;
croak "illegal name $name"
unless $name =~ /^[A-Za-z_][A-Za-z_0-9]*$/
|| $name eq ':';
croak "accessor/method $name already exists"
if $caller->can($name);
my $size = $ffi->sizeof($type);
my $align = $ffi->alignof($type);
$record_align = $align if $align > $record_align;
my $meta = $ffi->type_meta($type);
$offset++ while $offset % $align;
if($name ne ':')
{
if($meta->{type} eq 'string'
&& $meta->{access} eq 'rw'
&& $meta->{fixed_size} == 0)
{
push @destroy, eval '# line '. __LINE__ . ' "' . __FILE__ . qq("\n) .qq{
sub {
shift->$name(undef);
};
};
die $@ if $@;
}
$name = join '::', $caller, $name;
my $error_str =_accessor
$name,
"$filename:$line",
$ffi->_type_lookup($type),
$offset;
croak($error_str) if $error_str;
};
$offset += $size;
}
my $size = $offset;
no strict 'refs';
constant->import("${caller}::_ffi_record_size", $size);
constant->import("${caller}::_ffi_record_align", $record_align);
*{join '::', $caller, 'new'} = sub {
my $class = shift;
my $args = ref($_[0]) ? [%{$_[0]}] : \@_;
croak "uneven number of arguments to record constructor"
if @$args % 2;
my $record = "\0" x $class->_ffi_record_size;
my $self = bless \$record, $class;
while(@$args)
{
my $key = shift @$args;
my $value = shift @$args;
$self->$key($value);
}
$self;
};
my $destroy_sub = sub {};
if(@destroy)
{
$destroy_sub = sub {
$_->($_[0]) for @destroy;
};
}
do {
no strict 'refs';
*{"${caller}::DESTROY"} = $destroy_sub;
};
();
}
1;
__END__
=pod
=encoding UTF-8
=head1 NAME
FFI::Platypus::Record - FFI support for structured records data
=head1 VERSION
version 0.45
=head1 SYNOPSIS
C:
struct my_person {
int age;
const char title[3];
const char *name
};
void process_person(struct my_person *person)
{
/* ... */
}
Perl:
package MyPerson;
use FFI::Platypus::Record;
record_layout(qw(
int age
string(3) title
string_rw name
);
package main;
use FFI::Platypus;
my $ffi = FFI::Platypus->new;
$ffi->lib("myperson.so");
$ffi->type("record(MyPerson)" => 'MyPerson');
my $person = MyPerson->new(
age => 40,
title => "Mr.",
name => "John Smith",
);
$ffi->attach( process_person => [ 'MyPerson' ] => 'void' );
process_person($person);
$person->age($person->age + 1); # another year older
process_person($person);
=head1 DESCRIPTION
[version 0.21]
This module provides a mechanism for building classes that can be used
to mange structured data records (known as C as "structs" and in some
languages as "records"). A structured record is a series of bytes that
have structure understood by the C or other foreign language library
that you are interfacing with. It is designed for use with FFI and
L<FFI::Platypus>, though it may have other applications.
=head1 FUNCTIONS
=head2 record_layout
record_layout($ffi, $type => $name, ... );
record_layout($type => $name, ... );
Define the layout of the record. You may optionally provide an instance
of L<FFI::Platypus> as the first argument in order to use its type
aliases. Then you provide members as type/name pairs.
For each member you declare, C<record_layout> will create an accessor
which can be used to read and write its value. For example imagine a
class C<Foo>:
package Foo;
use FFI::Platypus::Record;
record_layout(
int => 'bar', # int bar;
'string(10)' => 'baz', # char baz[10];
);
You can get and set its fields with like named C<bar> and C<baz>
accessors:
my $foo = Foo->new;
$foo->bar(22);
my $value = $foo->bar;
$foo->baz("grimlock\0\0"); # should be 10 characters long
my $string_value = $foo->baz; # includes the trailing \0\0
You can also pass initial values in to the constructor, either passing
as a list of key value pairs or by passing a hash reference:
$foo = Foo->new(
bar => 22,
baz => "grimlock\0\0",
);
# same as:
$foo = Foo->new( {
bar => 22,
baz => "grimlock\0\0",
} );
If there are members of a record that you need to account for in terms
of size and alignment, but do not want to have an accessor for, you can
use C<:> as a place holder for its name:
record_layout(
'int' => ':',
'string(10)' => 'baz',
);
=head3 strings
So far I've shown fixed length strings. These are declared with the
word C<string> followed by the length of the string in parentheticals.
Fixed length strings are included inside the record itself and do not
need to be allocated or deallocated separately from the record.
Variable length strings must be allocated on the heap, and thus require
a sense of "ownership", that is whomever allocates variable length
strings should be responsible for also free'ing them. To handle this,
you can add a C<ro> or C<rw> trait to a string field. The default is
C<ro>, means that you can get, but not set its value:
package Foo;
record_layout(
'string ro' => 'bar', # same type as 'string' and 'string_ro'
);
package main;
my $foo = Foo->new;
my $string = $foo->bar; # GOOD
$foo->bar("starscream"); # BAD
If you specify a field is C<rw>, then you can set its value:
package Foo;
record_layout(
'string rw' => 'bar', # same type as 'string_rw'
);
package main;
my $foo = Foo->new;
my $string = $foo->bar; # GOOD
$foo->bar("starscream"); # GOOD
Any string value that is pointed to by the record will be free'd when it
falls out of scope, so you must be very careful that any C<string rw>
fields are not set or modified by C code. You should also take care not
to copy any record that has a C<rw> string in it because its values will
be free'd twice!
use Clone qw( clone );
my $foo2 = clone $foo; # BAD bar will be free'd twice
=head3 arrays
Arrays of integer, floating points and opaque pointers are supported.
package Foo;
record_layout(
'int[10]' => 'bar',
);
my $foo = Foo->new;
$foo->bar([1,2,3,4,5,6,7,8,9,10]); # sets the values for the array
my $list = $foo->bar; # returns a list reference
$foo->bar(5, -6); # sets the 5th element in the array to -6
my $item = $foo->bar(5); gets the 5th element in the array
=head1 TODO
These useful features (and probably more) are missing:
=over 4
=item Unions
=item Nested records
=back
=head1 SEE ALSO
=over 4
=item L<FFI::Platypus>
The main platypus documentation.
=item L<FFI::Platypus::Record::TieArray>
Tied array interface for record array members.
=item L<Convert::Binary::C>
Another method for constructing and dissecting structured data records.
=item L<pack and unpack|perlpacktut>
Built-in Perl functions for constructing and dissecting structured data
records.
=back
=head1 AUTHOR
Author: Graham Ollis E<lt>plicease@cpan.orgE<gt>
Contributors:
Bakkiaraj Murugesan (bakkiaraj)
Dylan Cali (calid)
pipcet
Zaki Mughal (zmughal)
Fitz Elliott (felliott)
Vickenty Fesunov (vyf)
Gregor Herrmann (gregoa)
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2015 by Graham Ollis.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut
|