/usr/share/perl5/Excel/Writer/XLSX/Package/Packager.pm is in libexcel-writer-xlsx-perl 0.47-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535 536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576 577 578 579 580 581 582 583 584 585 586 587 588 589 590 591 592 593 594 595 596 597 598 599 600 601 602 603 604 605 606 607 608 609 610 611 612 613 614 615 616 617 618 619 620 621 622 623 624 625 626 627 628 629 630 631 632 633 634 635 636 637 638 639 640 641 642 643 644 645 646 647 648 649 650 651 652 653 654 655 656 657 658 659 660 661 662 663 664 665 666 667 668 669 670 671 672 673 674 675 676 677 678 679 680 681 682 683 684 685 686 687 688 689 690 691 692 693 694 695 696 697 698 699 700 701 702 703 704 705 706 707 708 709 710 711 712 713 714 715 716 717 718 719 720 721 722 723 724 725 726 727 728 729 730 731 732 733 734 735 736 737 738 739 740 741 742 743 744 745 746 747 748 749 750 751 752 753 754 755 756 757 758 759 760 761 762 763 764 765 766 767 768 769 770 771 772 773 774 775 776 777 778 779 780 781 782 783 784 785 786 787 788 789 790 791 792 793 794 795 796 797 798 799 800 801 802 803 804 805 806 807 808 809 810 811 812 813 814 815 816 817 818 819 820 821 822 823 824 825 826 827 828 829 830 831 832 833 834 835 836 837 838 839 840 | package Excel::Writer::XLSX::Package::Packager;
###############################################################################
#
# Packager - A class for creating the Excel XLSX package.
#
# Used in conjunction with Excel::Writer::XLSX
#
# Copyright 2000-2012, John McNamara, jmcnamara@cpan.org
#
# Documentation after __END__
#
# perltidy with the following options: -mbl=2 -pt=0 -nola
use 5.008002;
use strict;
use warnings;
use Exporter;
use Carp;
use File::Copy;
use Excel::Writer::XLSX::Package::App;
use Excel::Writer::XLSX::Package::Comments;
use Excel::Writer::XLSX::Package::ContentTypes;
use Excel::Writer::XLSX::Package::Core;
use Excel::Writer::XLSX::Package::Relationships;
use Excel::Writer::XLSX::Package::SharedStrings;
use Excel::Writer::XLSX::Package::Styles;
use Excel::Writer::XLSX::Package::Theme;
use Excel::Writer::XLSX::Package::VML;
our @ISA = qw(Exporter);
our $VERSION = '0.47';
###############################################################################
#
# Public and private API methods.
#
###############################################################################
###############################################################################
#
# new()
#
# Constructor.
#
sub new {
my $class = shift;
my $self = {
_package_dir => '',
_workbook => undef,
_sheet_names => [],
_worksheet_count => 0,
_chartsheet_count => 0,
_chart_count => 0,
_drawing_count => 0,
_named_ranges => [],
};
bless $self, $class;
return $self;
}
###############################################################################
#
# _set_package_dir()
#
# Set the XLSX OPC package directory.
#
sub _set_package_dir {
my $self = shift;
$self->{_package_dir} = shift;
}
###############################################################################
#
# _add_workbook()
#
# Add the Excel::Writer::XLSX::Workbook object to the package.
#
sub _add_workbook {
my $self = shift;
my $workbook = shift;
my @sheet_names = @{ $workbook->{_sheetnames} };
$self->{_workbook} = $workbook;
$self->{_sheet_names} = \@sheet_names;
$self->{_chart_count} = scalar @{ $workbook->{_charts} };
$self->{_drawing_count} = scalar @{ $workbook->{_drawings} };
$self->{_num_comment_files} = $workbook->{_num_comment_files};
$self->{_named_ranges} = $workbook->{_named_ranges};
for my $worksheet ( @{ $self->{_workbook}->{_worksheets} } ) {
if ( $worksheet->{_is_chartsheet} ) {
$self->{_chartsheet_count}++;
}
else {
$self->{_worksheet_count}++;
}
}
}
###############################################################################
#
# _create_package()
#
# Write the xml files that make up the XLXS OPC package.
#
sub _create_package {
my $self = shift;
$self->_write_worksheet_files();
$self->_write_chartsheet_files();
$self->_write_workbook_file();
$self->_write_chart_files();
$self->_write_drawing_files();
$self->_write_vml_files();
$self->_write_comment_files();
$self->_write_shared_strings_file();
$self->_write_app_file();
$self->_write_core_file();
$self->_write_content_types_file();
$self->_write_styles_file();
$self->_write_theme_file();
$self->_write_root_rels_file();
$self->_write_workbook_rels_file();
$self->_write_worksheet_rels_files();
$self->_write_chartsheet_rels_files();
$self->_write_drawing_rels_files();
$self->_add_image_files();
}
###############################################################################
#
# _write_workbook_file()
#
# Write the workbook.xml file.
#
sub _write_workbook_file {
my $self = shift;
my $dir = $self->{_package_dir};
my $workbook = $self->{_workbook};
_mkdir( $dir . '/xl' );
$workbook->_set_xml_writer( $dir . '/xl/workbook.xml' );
$workbook->_assemble_xml_file();
}
###############################################################################
#
# _write_worksheet_files()
#
# Write the worksheet files.
#
sub _write_worksheet_files {
my $self = shift;
my $dir = $self->{_package_dir};
_mkdir( $dir . '/xl' );
_mkdir( $dir . '/xl/worksheets' );
my $index = 1;
for my $worksheet ( @{ $self->{_workbook}->{_worksheets} } ) {
next if $worksheet->{_is_chartsheet};
$worksheet->_set_xml_writer(
$dir . '/xl/worksheets/sheet' . $index++ . '.xml' );
$worksheet->_assemble_xml_file();
}
}
###############################################################################
#
# _write_chartsheet_files()
#
# Write the chartsheet files.
#
sub _write_chartsheet_files {
my $self = shift;
my $dir = $self->{_package_dir};
my $index = 1;
for my $worksheet ( @{ $self->{_workbook}->{_worksheets} } ) {
next unless $worksheet->{_is_chartsheet};
_mkdir( $dir . '/xl' );
_mkdir( $dir . '/xl/chartsheets' );
$worksheet->_set_xml_writer(
$dir . '/xl/chartsheets/sheet' . $index++ . '.xml' );
$worksheet->_assemble_xml_file();
}
}
###############################################################################
#
# _write_chart_files()
#
# Write the chart files.
#
sub _write_chart_files {
my $self = shift;
my $dir = $self->{_package_dir};
return unless @{ $self->{_workbook}->{_charts} };
_mkdir( $dir . '/xl' );
_mkdir( $dir . '/xl/charts' );
my $index = 1;
for my $chart ( @{ $self->{_workbook}->{_charts} } ) {
$chart->_set_xml_writer(
$dir . '/xl/charts/chart' . $index++ . '.xml' );
$chart->_assemble_xml_file();
}
}
###############################################################################
#
# _write_drawing_files()
#
# Write the drawing files.
#
sub _write_drawing_files {
my $self = shift;
my $dir = $self->{_package_dir};
return unless $self->{_drawing_count};
_mkdir( $dir . '/xl' );
_mkdir( $dir . '/xl/drawings' );
my $index = 1;
for my $drawing ( @{ $self->{_workbook}->{_drawings} } ) {
$drawing->_set_xml_writer(
$dir . '/xl/drawings/drawing' . $index++ . '.xml' );
$drawing->_assemble_xml_file();
}
}
###############################################################################
#
# _write_vml_files()
#
# Write the comment VML files.
#
sub _write_vml_files {
my $self = shift;
my $dir = $self->{_package_dir};
my $index = 1;
for my $worksheet ( @{ $self->{_workbook}->{_worksheets} } ) {
next unless $worksheet->{_has_comments};
my $vml = Excel::Writer::XLSX::Package::VML->new();
_mkdir( $dir . '/xl' );
_mkdir( $dir . '/xl/drawings' );
$vml->_set_xml_writer(
$dir . '/xl/drawings/vmlDrawing' . $index++ . '.vml' );
$vml->_assemble_xml_file(
$worksheet->{_vml_data_id},
$worksheet->{_vml_shape_id},
$worksheet->{_comments_array}
);
}
}
###############################################################################
#
# _write_comment_files()
#
# Write the comment files.
#
sub _write_comment_files {
my $self = shift;
my $dir = $self->{_package_dir};
my $index = 1;
for my $worksheet ( @{ $self->{_workbook}->{_worksheets} } ) {
next unless $worksheet->{_has_comments};
my $comment = Excel::Writer::XLSX::Package::Comments->new();
_mkdir( $dir . '/xl' );
_mkdir( $dir . '/xl/drawings' );
$comment->_set_xml_writer( $dir . '/xl/comments' . $index++ . '.xml' );
$comment->_assemble_xml_file( $worksheet->{_comments_array} );
}
}
###############################################################################
#
# _write_shared_strings_file()
#
# Write the sharedStrings.xml file.
#
sub _write_shared_strings_file {
my $self = shift;
my $dir = $self->{_package_dir};
my $sst = Excel::Writer::XLSX::Package::SharedStrings->new();
my $total = $self->{_workbook}->{_str_total};
my $unique = $self->{_workbook}->{_str_unique};
my $sst_data = $self->{_workbook}->{_str_array};
return unless $total > 0;
_mkdir( $dir . '/xl' );
$sst->_set_string_count( $total );
$sst->_set_unique_count( $unique );
$sst->_add_strings( $sst_data );
$sst->_set_xml_writer( $dir . '/xl/sharedStrings.xml' );
$sst->_assemble_xml_file();
}
###############################################################################
#
# _write_app_file()
#
# Write the app.xml file.
#
sub _write_app_file {
my $self = shift;
my $dir = $self->{_package_dir};
my $properties = $self->{_workbook}->{_doc_properties};
my $app = Excel::Writer::XLSX::Package::App->new();
_mkdir( $dir . '/docProps' );
# Add the Worksheet heading pairs.
$app->_add_heading_pair( [ 'Worksheets', $self->{_worksheet_count} ] );
# Add the Chartsheet heading pairs.
$app->_add_heading_pair( [ 'Charts', $self->{_chartsheet_count} ] );
# Add the Worksheet parts.
for my $worksheet ( @{ $self->{_workbook}->{_worksheets} } ) {
next if $worksheet->{_is_chartsheet};
$app->_add_part_name( $worksheet->get_name() );
}
# Add the Chartsheet parts.
for my $worksheet ( @{ $self->{_workbook}->{_worksheets} } ) {
next unless $worksheet->{_is_chartsheet};
$app->_add_part_name( $worksheet->get_name() );
}
# Add the Named Range heading pairs.
if ( my $range_count = scalar @{ $self->{_named_ranges} } ) {
$app->_add_heading_pair( [ 'Named Ranges', $range_count ] );
}
# Add the Named Ranges parts.
for my $named_range ( @{ $self->{_named_ranges} } ) {
$app->_add_part_name( $named_range );
}
$app->_set_properties( $properties );
$app->_set_xml_writer( $dir . '/docProps/app.xml' );
$app->_assemble_xml_file();
}
###############################################################################
#
# _write_core_file()
#
# Write the core.xml file.
#
sub _write_core_file {
my $self = shift;
my $dir = $self->{_package_dir};
my $properties = $self->{_workbook}->{_doc_properties};
my $core = Excel::Writer::XLSX::Package::Core->new();
_mkdir( $dir . '/docProps' );
$core->_set_properties( $properties );
$core->_set_xml_writer( $dir . '/docProps/core.xml' );
$core->_assemble_xml_file();
}
###############################################################################
#
# _write_content_types_file()
#
# Write the ContentTypes.xml file.
#
sub _write_content_types_file {
my $self = shift;
my $dir = $self->{_package_dir};
my $content = Excel::Writer::XLSX::Package::ContentTypes->new();
$content->_add_image_types( %{ $self->{_workbook}->{_image_types} } );
my $worksheet_index = 1;
my $chartsheet_index = 1;
for my $worksheet ( @{ $self->{_workbook}->{_worksheets} } ) {
if ( $worksheet->{_is_chartsheet} ) {
$content->_add_chartsheet_name( 'sheet' . $chartsheet_index++ );
}
else {
$content->_add_worksheet_name( 'sheet' . $worksheet_index++ );
}
}
for my $i ( 1 .. $self->{_chart_count} ) {
$content->_add_chart_name( 'chart' . $i );
}
for my $i ( 1 .. $self->{_drawing_count} ) {
$content->_add_drawing_name( 'drawing' . $i );
}
if ( $self->{_num_comment_files} ) {
$content->_add_vml_name();
}
for my $i ( 1 .. $self->{_num_comment_files} ) {
$content->_add_comment_name( 'comments' . $i );
}
# Add the sharedString rel if there is string data in the workbook.
if ( $self->{_workbook}->{_str_total} ) {
$content->_add_shared_strings();
}
$content->_set_xml_writer( $dir . '/[Content_Types].xml' );
$content->_assemble_xml_file();
}
###############################################################################
#
# _write_styles_file()
#
# Write the style xml file.
#
sub _write_styles_file {
my $self = shift;
my $dir = $self->{_package_dir};
my $xf_formats = $self->{_workbook}->{_xf_formats};
my $palette = $self->{_workbook}->{_palette};
my $font_count = $self->{_workbook}->{_font_count};
my $num_format_count = $self->{_workbook}->{_num_format_count};
my $border_count = $self->{_workbook}->{_border_count};
my $fill_count = $self->{_workbook}->{_fill_count};
my $custom_colors = $self->{_workbook}->{_custom_colors};
my $dxf_formats = $self->{_workbook}->{_dxf_formats};
my $rels = Excel::Writer::XLSX::Package::Styles->new();
_mkdir( $dir . '/xl' );
$rels->_set_style_properties(
$xf_formats,
$palette,
$font_count,
$num_format_count,
$border_count,
$fill_count,
$custom_colors,
$dxf_formats,
);
$rels->_set_xml_writer( $dir . '/xl/styles.xml' );
$rels->_assemble_xml_file();
}
###############################################################################
#
# _write_theme_file()
#
# Write the style xml file.
#
sub _write_theme_file {
my $self = shift;
my $dir = $self->{_package_dir};
my $rels = Excel::Writer::XLSX::Package::Theme->new();
_mkdir( $dir . '/xl' );
_mkdir( $dir . '/xl/theme' );
$rels->_set_xml_writer( $dir . '/xl/theme/theme1.xml' );
$rels->_assemble_xml_file();
}
###############################################################################
#
# _write_root_rels_file()
#
# Write the _rels/.rels xml file.
#
sub _write_root_rels_file {
my $self = shift;
my $dir = $self->{_package_dir};
my $rels = Excel::Writer::XLSX::Package::Relationships->new();
_mkdir( $dir . '/_rels' );
$rels->_add_document_relationship( '/officeDocument', 'xl/workbook.xml' );
$rels->_add_package_relationship( '/metadata/core-properties',
'docProps/core' );
$rels->_add_document_relationship( '/extended-properties',
'docProps/app.xml' );
$rels->_set_xml_writer( $dir . '/_rels/.rels' );
$rels->_assemble_xml_file();
}
###############################################################################
#
# _write_workbook_rels_file()
#
# Write the _rels/.rels xml file.
#
sub _write_workbook_rels_file {
my $self = shift;
my $dir = $self->{_package_dir};
my $rels = Excel::Writer::XLSX::Package::Relationships->new();
_mkdir( $dir . '/xl' );
_mkdir( $dir . '/xl/_rels' );
my $worksheet_index = 1;
my $chartsheet_index = 1;
for my $worksheet ( @{ $self->{_workbook}->{_worksheets} } ) {
if ( $worksheet->{_is_chartsheet} ) {
$rels->_add_document_relationship( '/chartsheet',
'chartsheets/sheet' . $chartsheet_index++ . '.xml' );
}
else {
$rels->_add_document_relationship( '/worksheet',
'worksheets/sheet' . $worksheet_index++ . '.xml' );
}
}
$rels->_add_document_relationship( '/theme', 'theme/theme1.xml' );
$rels->_add_document_relationship( '/styles', 'styles.xml' );
# Add the sharedString rel if there is string data in the workbook.
if ( $self->{_workbook}->{_str_total} ) {
$rels->_add_document_relationship( '/sharedStrings',
'sharedStrings.xml' );
}
$rels->_set_xml_writer( $dir . '/xl/_rels/workbook.xml.rels' );
$rels->_assemble_xml_file();
}
###############################################################################
#
# _write_worksheet_rels_files()
#
# Write the worksheet .rels files for worksheets that contain links to external
# data such as hyperlinks or drawings.
#
sub _write_worksheet_rels_files {
my $self = shift;
my $dir = $self->{_package_dir};
my $index = 0;
for my $worksheet ( @{ $self->{_workbook}->{_worksheets} } ) {
next if $worksheet->{_is_chartsheet};
$index++;
my @external_links = (
@{ $worksheet->{_external_hyper_links} },
@{ $worksheet->{_external_drawing_links} },
@{ $worksheet->{_external_comment_links} },
);
next unless @external_links;
# Create the worksheet .rels dirs.
_mkdir( $dir . '/xl' );
_mkdir( $dir . '/xl/worksheets' );
_mkdir( $dir . '/xl/worksheets/_rels' );
my $rels = Excel::Writer::XLSX::Package::Relationships->new();
for my $link_data ( @external_links ) {
$rels->_add_worksheet_relationship( @$link_data );
}
# Create the .rels file such as /xl/worksheets/_rels/sheet1.xml.rels.
$rels->_set_xml_writer(
$dir . '/xl/worksheets/_rels/sheet' . $index . '.xml.rels' );
$rels->_assemble_xml_file();
}
}
###############################################################################
#
# _write_chartsheet_rels_files()
#
# Write the chartsheet .rels files for links to drawing files.
#
sub _write_chartsheet_rels_files {
my $self = shift;
my $dir = $self->{_package_dir};
my $index = 0;
for my $worksheet ( @{ $self->{_workbook}->{_worksheets} } ) {
next unless $worksheet->{_is_chartsheet};
$index++;
my @external_links = @{ $worksheet->{_external_drawing_links} };
next unless @external_links;
# Create the chartsheet .rels dir.
_mkdir( $dir . '/xl' );
_mkdir( $dir . '/xl/chartsheets' );
_mkdir( $dir . '/xl/chartsheets/_rels' );
my $rels = Excel::Writer::XLSX::Package::Relationships->new();
for my $link_data ( @external_links ) {
$rels->_add_worksheet_relationship( @$link_data );
}
# Create the .rels file such as /xl/chartsheets/_rels/sheet1.xml.rels.
$rels->_set_xml_writer(
$dir . '/xl/chartsheets/_rels/sheet' . $index . '.xml.rels' );
$rels->_assemble_xml_file();
}
}
###############################################################################
#
# _write_drawing_rels_files()
#
# Write the drawing .rels files for worksheets that contain charts or drawings.
#
sub _write_drawing_rels_files {
my $self = shift;
my $dir = $self->{_package_dir};
my $index = 0;
for my $worksheet ( @{ $self->{_workbook}->{_worksheets} } ) {
next unless @{ $worksheet->{_drawing_links} };
$index++;
# Create the drawing .rels dir.
_mkdir( $dir . '/xl' );
_mkdir( $dir . '/xl/drawings' );
_mkdir( $dir . '/xl/drawings/_rels' );
my $rels = Excel::Writer::XLSX::Package::Relationships->new();
for my $drawing_data ( @{ $worksheet->{_drawing_links} } ) {
$rels->_add_document_relationship( @$drawing_data );
}
# Create the .rels file such as /xl/drawings/_rels/sheet1.xml.rels.
$rels->_set_xml_writer(
$dir . '/xl/drawings/_rels/drawing' . $index . '.xml.rels' );
$rels->_assemble_xml_file();
}
}
###############################################################################
#
# _add_image_files()
#
# Write the workbook.xml file.
#
sub _add_image_files {
my $self = shift;
my $dir = $self->{_package_dir};
my $workbook = $self->{_workbook};
my $index = 1;
for my $image ( @{ $workbook->{_images} } ) {
my $filename = $image->[0];
my $extension = '.' . $image->[1];
_mkdir( $dir . '/xl' );
_mkdir( $dir . '/xl/media' );
copy( $filename, $dir . '/xl/media/image' . $index++ . $extension );
}
}
###############################################################################
#
# _mkdir()
#
# Wrapper function for Perl's mkdir to allow error trapping.
#
sub _mkdir {
my $dir = shift;
return if -e $dir;
my $ret = mkdir( $dir );
if (!$ret) {
croak "Couldn't create sub directory $dir: $!";
}
}
1;
__END__
=pod
=head1 NAME
Packager - A class for creating the Excel XLSX package.
=head1 SYNOPSIS
See the documentation for L<Excel::Writer::XLSX>.
=head1 DESCRIPTION
This module is used in conjunction with L<Excel::Writer::XLSX> to create an Excel XLSX container file.
From Wikipedia: I<The Open Packaging Conventions (OPC) is a container-file technology initially created by Microsoft to store a combination of XML and non-XML files that together form a single entity such as an Open XML Paper Specification (OpenXPS) document>. L<http://en.wikipedia.org/wiki/Open_Packaging_Conventions>.
At its simplest an Excel XLSX file contains the following elements:
____ [Content_Types].xml
|
|____ docProps
| |____ app.xml
| |____ core.xml
|
|____ xl
| |____ workbook.xml
| |____ worksheets
| | |____ sheet1.xml
| |
| |____ styles.xml
| |
| |____ theme
| | |____ theme1.xml
| |
| |_____rels
| |____ workbook.xml.rels
|
|_____rels
|____ .rels
The C<Excel::Writer::XLSX::Package::Packager> class co-ordinates the classes that represent the elements of the package and writes them into the XLSX file.
=head1 AUTHOR
John McNamara jmcnamara@cpan.org
=head1 COPYRIGHT
© MM-MMXII, John McNamara.
All Rights Reserved. This module is free software. It may be used, redistributed and/or modified under the same terms as Perl itself.
=head1 LICENSE
Either the Perl Artistic Licence L<http://dev.perl.org/licenses/artistic.html> or the GPL L<http://www.opensource.org/licenses/gpl-license.php>.
=head1 DISCLAIMER OF WARRANTY
See the documentation for L<Excel::Writer::XLSX>.
=cut
|