/usr/share/perl5/Mojo/Collection.pm is in libmojolicious-perl 2.98+dfsg-2.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 | package Mojo::Collection;
use Mojo::Base 'Exporter';
use overload
'bool' => sub {1},
'""' => sub { shift->join("\n") },
fallback => 1;
use List::Util;
use Mojo::ByteStream;
our @EXPORT_OK = ('c');
sub new {
my $class = shift;
return bless [@_], ref $class || $class;
}
sub c { __PACKAGE__->new(@_) }
sub each {
my ($self, $cb) = @_;
return @$self unless $cb;
my $i = 1;
$_->$cb($i++) for @$self;
return $self;
}
sub first {
my ($self, $cb) = @_;
return $self->[0] unless $cb;
return List::Util::first { $_->$cb } @$self;
}
# "All right, let's not panic.
# I'll make the money by selling one of my livers.
# I can get by with one."
sub grep {
my ($self, $cb) = @_;
return $self->new(grep { $_->$cb } @$self);
}
sub join {
my ($self, $expression) = @_;
return Mojo::ByteStream->new(join $expression, map({"$_"} @$self));
}
sub map {
my ($self, $cb) = @_;
return $self->new(map { $_->$cb } @$self);
}
sub reverse {
my $self = shift;
return $self->new(reverse @$self);
}
sub shuffle {
my $self = shift;
return $self->new(List::Util::shuffle @$self);
}
sub size { scalar @{$_[0]} }
sub slice {
my $self = shift;
return $self->new(@$self[@_]);
}
sub sort {
my ($self, $cb) = @_;
return $self->new(sort @$self) unless $cb;
return $self->new(sort { $a->$cb($b) } @$self);
}
1;
=head1 NAME
Mojo::Collection - Collection
=head1 SYNOPSIS
# Manipulate collections
use Mojo::Collection;
my $collection = Mojo::Collection->new(qw(just works));
unshift @$collection, 'it';
$collection->map(sub { ucfirst })->each(sub {
my ($word, $count) = @_;
say "$count: $word";
});
# Use the alternative constructor
use Mojo::Collection 'c';
c(qw(a b c))->join('/')->url_escape->say;
=head1 DESCRIPTION
L<Mojo::Collection> is a container for collections.
=head1 FUNCTIONS
L<Mojo::Collection> implements the following functions.
=head2 C<c>
my $collection = c(1, 2, 3);
Construct a new L<Mojo::Collection> object.
=head1 METHODS
L<Mojo::Collection> implements the following methods.
=head2 C<new>
my $collection = Mojo::Collection->new(1, 2, 3);
Construct a new L<Mojo::Collection> object.
=head2 C<each>
my @elements = $collection->each;
$collection = $collection->each(sub {...});
Evaluate closure for each element in collection.
$collection->each(sub {
my ($e, $count) = @_;
say "$count: $e";
});
=head2 C<first>
my $first = $collection->first;
my $first = $collection->first(sub {...});
Evaluate closure for each element in collection and return the first one for
which the closure returns true.
my $five = $collection->first(sub { $_ == 5 });
=head2 C<grep>
my $new = $collection->grep(sub {...});
Evaluate closure for each element in collection and create a new collection
with all elements for which the closure returned true.
my $interesting = $collection->grep(sub { /mojo/i });
=head2 C<join>
my $stream = $collection->join("\n");
Turn collection into L<Mojo::ByteStream>.
$collection->join("\n")->say;
=head2 C<map>
my $new = $collection->map(sub {...});
Evaluate closure for each element in collection and create a new collection
from the results.
my $doubled = $collection->map(sub { $_ * 2 });
=head2 C<reverse>
my $new = $collection->reverse;
Create a new collection with all elements in reverse order.
=head2 C<slice>
my $new = $collection->slice(4 .. 7);
Create a new collection with all selected elements.
=head2 C<shuffle>
my $new = $collection->shuffle;
Create a new collection with all elements in random order.
=head2 C<size>
my $size = $collection->size;
Number of elements in collection.
=head2 C<sort>
my $new = $collection->sort;
my $new = $collection->sort(sub {...});
Sort elements based on return value of closure and create a new collection
from the results.
my $insensitive = $collection->sort(sub { uc(shift) cmp uc(shift) });
=head1 SEE ALSO
L<Mojolicious>, L<Mojolicious::Guides>, L<http://mojolicio.us>.
=cut
|