/usr/share/perl5/Mojo/Content/MultiPart.pm is in libmojolicious-perl 2.98+dfsg-2.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 | package Mojo::Content::MultiPart;
use Mojo::Base 'Mojo::Content';
use Mojo::Util 'b64_encode';
has parts => sub { [] };
sub new {
my $self = shift->SUPER::new(@_);
# Default content parser
$self->on(
read => sub {
my ($self, $chunk) = @_;
$self->{multipart} .= $chunk;
$self->_parse_multipart;
}
);
return $self;
}
sub body_contains {
my ($self, $chunk) = @_;
for my $part (@{$self->parts}) {
return 1 if index($part->build_headers, $chunk) >= 0;
return 1 if $part->body_contains($chunk);
}
return;
}
sub body_size {
my $self = shift;
# Check for Content-Lenght header
my $content_length = $self->headers->content_length;
return $content_length if $content_length;
# Calculate length of whole body
my $boundary_length = length($self->build_boundary) + 6;
my $len = 0;
$len += $boundary_length - 2;
for my $part (@{$self->parts}) {
# Header
$len += $part->header_size;
# Body
$len += $part->body_size;
# Boundary
$len += $boundary_length;
}
return $len;
}
sub build_boundary {
my $self = shift;
# Check for existing boundary
my $headers = $self->headers;
my $type = $headers->content_type || '';
my $boundary;
$type =~ /boundary="?([^\s"]+)"?/i and $boundary = $1;
return $boundary if $boundary;
# Generate and check boundary
my $size = 1;
while (1) {
$boundary = b64_encode join('', map chr(rand(256)), 1 .. $size * 3);
$boundary =~ s/\W/X/g;
# Check parts for boundary
last unless $self->body_contains($boundary);
$size++;
}
# Add boundary to Content-Type header
$type =~ m!^(.*multipart/[^;]+)(.*)$!;
my $before = $1 || 'multipart/mixed';
my $after = $2 || '';
$headers->content_type("$before; boundary=$boundary$after");
return $boundary;
}
sub clone {
my $self = shift;
return unless my $clone = $self->SUPER::clone();
return $clone->parts($self->parts);
}
sub get_body_chunk {
my ($self, $offset) = @_;
# Body generator
return $self->generate_body_chunk($offset) if $self->{dynamic};
# First boundary
my $boundary = $self->build_boundary;
my $boundary_length = length($boundary) + 6;
my $len = $boundary_length - 2;
return substr "--$boundary\x0d\x0a", $offset if $len > $offset;
# Parts
my $parts = $self->parts;
for (my $i = 0; $i < @$parts; $i++) {
my $part = $parts->[$i];
# Headers
my $header_length = $part->header_size;
return $part->get_header_chunk($offset - $len)
if ($len + $header_length) > $offset;
$len += $header_length;
# Content
my $content_length = $part->body_size;
return $part->get_body_chunk($offset - $len)
if ($len + $content_length) > $offset;
$len += $content_length;
# Boundary
if (($len + $boundary_length) > $offset) {
# Last boundary
return substr "\x0d\x0a--$boundary--", $offset - $len
if $#{$parts} == $i;
# Middle boundary
return substr "\x0d\x0a--$boundary\x0d\x0a", $offset - $len;
}
$len += $boundary_length;
}
}
sub is_multipart {1}
sub _parse_multipart {
my $self = shift;
# Parse
$self->{multi_state} ||= 'multipart_preamble';
my $boundary = $self->boundary;
until ($self->is_finished) {
# Preamble
if (($self->{multi_state} || '') eq 'multipart_preamble') {
last unless $self->_parse_multipart_preamble($boundary);
}
# Boundary
elsif (($self->{multi_state} || '') eq 'multipart_boundary') {
last unless $self->_parse_multipart_boundary($boundary);
}
# Body
elsif (($self->{multi_state} || '') eq 'multipart_body') {
last unless $self->_parse_multipart_body($boundary);
}
}
}
sub _parse_multipart_body {
my ($self, $boundary) = @_;
# Whole part in buffer
my $pos = index $self->{multipart}, "\x0d\x0a--$boundary";
if ($pos < 0) {
my $len = length($self->{multipart}) - (length($boundary) + 8);
return unless $len > 0;
# Store chunk
my $chunk = substr $self->{multipart}, 0, $len, '';
$self->parts->[-1] = $self->parts->[-1]->parse($chunk);
return;
}
# Store chunk
my $chunk = substr $self->{multipart}, 0, $pos, '';
$self->parts->[-1] = $self->parts->[-1]->parse($chunk);
return $self->{multi_state} = 'multipart_boundary';
}
sub _parse_multipart_boundary {
my ($self, $boundary) = @_;
# Boundary begins
if ((index $self->{multipart}, "\x0d\x0a--$boundary\x0d\x0a") == 0) {
substr $self->{multipart}, 0, length($boundary) + 6, '';
# New part
my $part = Mojo::Content::Single->new(relaxed => 1);
$self->emit(part => $part);
push @{$self->parts}, $part;
return $self->{multi_state} = 'multipart_body';
}
# Boundary ends
my $end = "\x0d\x0a--$boundary--";
if ((index $self->{multipart}, $end) == 0) {
substr $self->{multipart}, 0, length $end, '';
# Finished
$self->{state} = $self->{multi_state} = 'finished';
}
return;
}
sub _parse_multipart_preamble {
my ($self, $boundary) = @_;
# Replace preamble with carriage return and line feed
my $pos = index $self->{multipart}, "--$boundary";
unless ($pos < 0) {
substr $self->{multipart}, 0, $pos, "\x0d\x0a";
# Parse boundary
return $self->{multi_state} = 'multipart_boundary';
}
# No boundary yet
return;
}
1;
=head1 NAME
Mojo::Content::MultiPart - HTTP 1.1 multipart content container
=head1 SYNOPSIS
use Mojo::Content::MultiPart;
my $multi = Mojo::Content::MultiPart->new;
$multi->parse('Content-Type: multipart/mixed; boundary=---foobar');
my $single = $multi->parts->[4];
=head1 DESCRIPTION
L<Mojo::Content::MultiPart> is a container for HTTP 1.1 multipart content as
described in RFC 2616.
=head1 EVENTS
L<Mojo::Content::Multipart> inherits all events from L<Mojo::Content> and can
emit the following new ones.
=head2 C<part>
$multi->on(part => sub {
my ($multi, $single) = @_;
...
});
Emitted when a new L<Mojo::Content::Single> part starts.
$multi->on(part => sub {
my ($multi, $single) = @_;
return unless $single->headers->content_disposition =~ /name="([^"]+)"/;
say "Field: $1";
});
=head1 ATTRIBUTES
L<Mojo::Content::MultiPart> inherits all attributes from L<Mojo::Content> and
implements the following new ones.
=head2 C<parts>
my $parts = $multi->parts;
$multi = $multi->parts([]);
Content parts embedded in this multipart content, usually
L<Mojo::Content::Single> objects.
=head1 METHODS
L<Mojo::Content::MultiPart> inherits all methods from L<Mojo::Content> and
implements the following new ones.
=head2 C<new>
my $multi = Mojo::Content::MultiPart->new;
Construct a new L<Mojo::Content::MultiPart> object and subscribe to C<read>
event with default content parser.
=head2 C<body_contains>
my $success = $multi->body_contains('foobarbaz');
Check if content parts contain a specific string.
=head2 C<body_size>
my $size = $multi->body_size;
Content size in bytes.
=head2 C<build_boundary>
my $boundary = $multi->build_boundary;
Generate a suitable boundary for content.
=head2 C<clone>
my $clone = $multi->clone;
Clone content if possible, otherwise return C<undef>.
=head2 C<get_body_chunk>
my $chunk = $multi->get_body_chunk(0);
Get a chunk of content starting from a specfic position.
=head2 C<is_multipart>
my $true = $multi->is_multipart;
True.
=head1 SEE ALSO
L<Mojolicious>, L<Mojolicious::Guides>, L<http://mojolicio.us>.
=cut
|