/usr/share/perl5/Mojo/Transaction.pm is in libmojolicious-perl 2.98+dfsg-2.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 | package Mojo::Transaction;
use Mojo::Base 'Mojo::EventEmitter';
use Carp 'croak';
use Mojo::Message::Request;
use Mojo::Message::Response;
has [qw(kept_alive local_address local_port previous remote_port)];
has req => sub { Mojo::Message::Request->new };
has res => sub { Mojo::Message::Response->new };
# "Please don't eat me! I have a wife and kids. Eat them!"
sub client_close { shift->server_close(@_) }
sub client_read { croak 'Method "client_read" not implemented by subclass' }
sub client_write { croak 'Method "client_write" not implemented by subclass' }
sub connection {
my ($self, $c) = @_;
return $self->emit(connection => $self->{connection} = $c) if $c;
return $self->{connection};
}
sub error {
my $self = shift;
my $req = $self->req;
return $req->error if $req->error;
my $res = $self->res;
return $res->error ? $res->error : undef;
}
sub is_finished { (shift->{state} || '') eq 'finished' }
sub is_websocket {undef}
sub is_writing {
return 1 unless my $state = shift->{state};
return $state ~~ [qw(write write_start_line write_headers write_body)];
}
sub remote_address {
my $self = shift;
# New address
if (@_) {
$self->{remote_address} = shift;
return $self;
}
# Reverse proxy
if ($ENV{MOJO_REVERSE_PROXY}) {
return $self->{forwarded_for} if $self->{forwarded_for};
($self->req->headers->header('X-Forwarded-For') || '') =~ /([^,\s]+)$/
and return $self->{forwarded_for} = $1;
}
return $self->{remote_address};
}
sub resume {
my $self = shift;
if (($self->{state} || '') eq 'paused') { $self->{state} = 'write_body' }
elsif (!$self->is_writing) { $self->{state} = 'write' }
return $self->emit('resume');
}
sub server_close { shift->emit('finish') }
sub server_read { croak 'Method "server_read" not implemented by subclass' }
sub server_write { croak 'Method "server_write" not implemented by subclass' }
sub success {
my $self = shift;
return $self->error ? undef : $self->res;
}
1;
=head1 NAME
Mojo::Transaction - Transaction base class
=head1 SYNOPSIS
use Mojo::Base 'Mojo::Transaction';
=head1 DESCRIPTION
L<Mojo::Transaction> is an abstract base class for transactions.
=head1 EVENTS
L<Mojo::Transaction> can emit the following events.
=head2 C<connection>
$tx->on(connection => sub {
my ($tx, $connection) = @_;
...
});
Emitted when a connection has been assigned to transaction.
=head2 C<finish>
$tx->on(finish => sub {
my $tx = shift;
...
});
Emitted when transaction is finished.
=head2 C<resume>
$tx->on(resume => sub {
my $tx = shift;
...
});
Emitted when transaction is resumed.
=head1 ATTRIBUTES
L<Mojo::Transaction> implements the following attributes.
=head2 C<kept_alive>
my $kept_alive = $tx->kept_alive;
$tx = $tx->kept_alive(1);
Connection has been kept alive.
=head2 C<local_address>
my $local_address = $tx->local_address;
$tx = $tx->local_address($address);
Local interface address.
=head2 C<local_port>
my $local_port = $tx->local_port;
$tx = $tx->local_port($port);
Local interface port.
=head2 C<previous>
my $previous = $tx->previous;
$tx = $tx->previous(Mojo::Transaction->new);
Previous transaction that triggered this followup transaction.
# Path of previous request
say $tx->previous->req->url->path;
=head2 C<remote_address>
my $remote_address = $tx->remote_address;
$tx = $tx->remote_address($address);
Remote interface address.
=head2 C<remote_port>
my $remote_port = $tx->remote_port;
$tx = $tx->remote_port($port);
Remote interface port.
=head2 C<req>
my $req = $tx->req;
$tx = $tx->req(Mojo::Message::Request->new);
HTTP 1.1 request, defaults to a L<Mojo::Message::Request> object.
=head2 C<res>
my $res = $tx->res;
$tx = $tx->res(Mojo::Message::Response->new);
HTTP 1.1 response, defaults to a L<Mojo::Message::Response> object.
=head1 METHODS
L<Mojo::Transaction> inherits all methods from L<Mojo::EventEmitter> and
implements the following new ones.
=head2 C<client_close>
$tx->client_close;
Transaction closed.
=head2 C<client_read>
$tx->client_read($chunk);
Read and process client data. Meant to be overloaded in a subclass.
=head2 C<client_write>
my $chunk = $tx->client_write;
Write client data. Meant to be overloaded in a subclass.
=head2 C<connection>
my $connection = $tx->connection;
$tx = $tx->connection($connection);
Connection identifier or socket.
=head2 C<error>
my $message = $tx->error;
my ($message, $code) = $tx->error;
Parser errors and codes.
=head2 C<is_finished>
my $success = $tx->is_finished;
Check if transaction is finished.
=head2 C<is_websocket>
my $false = $tx->is_websocket;
False.
=head2 C<is_writing>
my $success = $tx->is_writing;
Check if transaction is writing.
=head2 C<resume>
$tx = $tx->resume;
Resume transaction.
=head2 C<server_close>
$tx->server_close;
Transaction closed.
=head2 C<server_read>
$tx->server_read($chunk);
Read and process server data. Meant to be overloaded in a subclass.
=head2 C<server_write>
my $chunk = $tx->server_write;
Write server data. Meant to be overloaded in a subclass.
=head2 C<success>
my $res = $tx->success;
Returns the L<Mojo::Message::Response> object (C<res>) if transaction was
successful or C<undef> otherwise. Connection and parser errors have only a
message in C<error>, 400 and 500 responses also a code.
# Sensible exception handling
if (my $res = $tx->success) {
say $res->body;
}
else {
my ($message, $code) = $tx->error;
if ($code) {
say "$code $message response.";
}
else {
say "Connection error: $message";
}
}
Error messages can be accessed with the C<error> method of the transaction
object.
=head1 SEE ALSO
L<Mojolicious>, L<Mojolicious::Guides>, L<http://mojolicio.us>.
=cut
|