/usr/share/perl5/Mojolicious/Command/cpanify.pm is in libmojolicious-perl 2.98+dfsg-2.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 | package Mojolicious::Command::cpanify;
use Mojo::Base 'Mojo::Command';
use File::Basename 'basename';
use Getopt::Long qw(GetOptions :config no_auto_abbrev no_ignore_case);
use Mojo::UserAgent;
has description => "Upload distribution to CPAN.\n";
has usage => <<"EOF";
usage: $0 cpanify [OPTIONS] [FILE]
mojo cpanify -u sri -p secr3t Mojolicious-Plugin-MyPlugin-0.01.tar.gz
These options are available:
-p, --password <password> PAUSE password.
-u, --user <name> PAUSE username.
EOF
# "Hooray! A happy ending for the rich people!"
sub run {
my $self = shift;
# Options
local @ARGV = @_;
my $password = my $user = '';
GetOptions(
'p|password=s' => sub { $password = $_[1] },
'u|user=s' => sub { $user = $_[1] }
);
die $self->usage unless my $file = shift @ARGV;
# Upload
my $tx = Mojo::UserAgent->new->detect_proxy->post_form(
"https://$user:$password\@pause.perl.org/pause/authenquery" => {
HIDDENNAME => $user,
CAN_MULTIPART => 1,
pause99_add_uri_upload => basename($file),
SUBMIT_pause99_add_uri_httpupload => ' Upload this file from my disk ',
pause99_add_uri_uri => '',
pause99_add_uri_httpupload => {file => $file},
}
);
# Error
unless ($tx->success) {
my $code = $tx->res->code || '';
my $message = $tx->error;
if ($code eq '401') { $message = 'Wrong username or password.' }
elsif ($code eq '409') { $message = 'File already exists on CPAN.' }
die qq{Problem uploading file "$file". ($message)\n};
}
say 'Upload successful!';
}
1;
=head1 NAME
Mojolicious::Command::cpanify - Cpanify command
=head1 SYNOPSIS
use Mojolicious::Command::cpanify;
my $cpanify = Mojolicious::Command::cpanify->new;
$cpanify->run(@ARGV);
=head1 DESCRIPTION
L<Mojolicious::Command::cpanify> uploads files to CPAN.
=head1 ATTRIBUTES
L<Mojolicious::Command::cpanify> inherits all attributes from L<Mojo::Command>
and implements the following new ones.
=head2 C<description>
my $description = $cpanify->description;
$cpanify = $cpanify->description('Foo!');
Short description of this command, used for the command list.
=head2 C<usage>
my $usage = $cpanify->usage;
$cpanify = $cpanify->usage('Foo!');
Usage information for this command, used for the help screen.
=head1 METHODS
L<Mojolicious::Command::cpanify> inherits all methods from L<Mojo::Command>
and implements the following new ones.
=head2 C<run>
$cpanify->run(@ARGV);
Run this command.
=head1 SEE ALSO
L<Mojolicious>, L<Mojolicious::Guides>, L<http://mojolicio.us>.
=cut
|