/usr/share/perl5/MooseX/Attribute/Chained.pm is in libmoosex-attribute-chained-perl 1.0.1-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 | #
# This file is part of MooseX-Attribute-Chained
#
# This software is copyright (c) 2012 by Moritz Onken.
#
# This is free software; you can redistribute it and/or modify it under
# the same terms as the Perl 5 programming language system itself.
#
package MooseX::Attribute::Chained;
{
$MooseX::Attribute::Chained::VERSION = '1.0.1';
}
# ABSTRACT: Attribute that returns the instance to allow for chaining
use Moose::Util;
Moose::Util::meta_attribute_alias(
Chained => 'MooseX::Traits::Attribute::Chained' );
package MooseX::Traits::Attribute::Chained;
{
$MooseX::Traits::Attribute::Chained::VERSION = '1.0.1';
}
use Moose::Role;
override accessor_metaclass => sub {
'MooseX::Attribute::Chained::Method::Accessor';
};
package MooseX::Attribute::Chained::Method::Accessor;
{
$MooseX::Attribute::Chained::Method::Accessor::VERSION = '1.0.1';
}
use Carp qw(confess);
use Try::Tiny;
use base 'Moose::Meta::Method::Accessor';
sub _generate_accessor_method_inline {
my $self = shift;
my $attr = $self->associated_attribute;
my $clone
= $attr->associated_class->has_method("clone")
? '$_[0]->clone'
: 'bless { %{$_[0]} }, ref $_[0]';
if ( $Moose::VERSION >= 1.9900 ) {
return try {
$self->_compile_code(
[ 'sub {',
'if (@_ > 1) {',
$attr->_inline_set_value( '$_[0]', '$_[1]' ),
'return $_[0];',
'}',
$attr->_inline_get_value('$_[0]'),
'}',
]
);
}
catch {
confess "Could not generate inline accessor because : $_";
};
}
else {
return $self->next::method(@_);
}
}
sub _generate_writer_method_inline {
my $self = shift;
my $attr = $self->associated_attribute;
my $clone
= $attr->associated_class->has_method("clone")
? '$_[0]->clone'
: 'bless { %{$_[0]} }, ref $_[0]';
if ( $Moose::VERSION >= 1.9900 ) {
return try {
$self->_compile_code(
[ 'sub {', $attr->_inline_set_value( '$_[0]', '$_[1]' ),
'$_[0]', '}',
]
);
}
catch {
confess "Could not generate inline writer because : $_";
};
}
else {
return $self->next::method(@_);
}
}
sub _inline_post_body {
return 'return $_[0] if (scalar(@_) >= 2);' . "\n";
}
1;
__END__
=pod
=head1 NAME
MooseX::Attribute::Chained - Attribute that returns the instance to allow for chaining
=head1 VERSION
version 1.0.1
=head1 SYNOPSIS
package Test;
use Moose;
has debug => (
traits => [ 'Chained' ],
is => 'rw',
isa => 'Bool',
);
sub complex_method
{
my $self = shift;
#...
print "helper message" if $self->debug;
#...
}
1;
Which allows for:
my $test = Test->new;
$test->debug(1)->complex_method;
$test->debug(1); # returns $test
$test->debug; # returns 1
=head1 DESCRIPTION
MooseX::Attribute::Chained is a Moose Trait which allows for method chaining
on accessors by returning $self on write/set operations.
=head1 AUTHORS
=over 4
=item *
Moritz Onken <onken@netcubed.de>
=item *
David McLaughlin <david@dmclaughlin.com>
=back
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2012 by Moritz Onken.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut
|