/usr/share/perl5/MooseX/Blessed/Reconstruct.pm is in libmoosex-blessed-reconstruct-perl 0.04-2.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 | #!/usr/bin/perl
package MooseX::Blessed::Reconstruct;
use Moose;
use Carp qw(croak);
use Class::MOP 0.66; # well behaved load_class()
use Data::Visitor 0.21; # n-arity visit
use Scalar::Util qw(reftype);
use namespace::clean -except => 'meta';
our $VERSION = "0.04";
extends qw(Data::Visitor);
has load_classes => (
isa => "Bool",
is => "rw",
default => 1,
);
sub visit_object {
my ( $v, $obj ) = @_;
my $class = ref $obj;
Class::MOP::load_class($class) if $v->load_classes;
my $meta = Class::MOP::get_metaclass_by_name($class);
if ( ref $meta ) {
return $v->visit_object_with_meta($obj, $meta);
} else {
return $v->visit_ref($obj);
}
}
sub visit_object_with_meta {
my ( $v, $obj, $meta ) = @_;
my $instance = $meta->get_meta_instance->create_instance;
$v->_register_mapping( $obj => $instance );
my $args = $v->prepare_args( $meta, $obj );
$meta->new_object( %$args, __INSTANCE__ => $instance );
return $instance;
}
sub prepare_args {
my ( $v, $meta, $obj ) = @_;
my @args;
if ( reftype $obj eq 'HASH' ) {
@args = %$obj;
} elsif ( reftype $obj eq 'ARRAY' ) {
@args = @$obj;
} elsif ( reftype $obj eq 'SCALAR' ) {
@args = $$obj;
} else {
croak "unknown ref type $obj";
}
my @processed = $v->visit(@args);
return $meta->name->BUILDARGS(@processed);
}
__PACKAGE__->meta->make_immutable;
__PACKAGE__
__END__
=pod
=head1 NAME
MooseX::Blessed::Reconstruct - A L<Data::Visitor> for creating Moose objects
from blessed placeholders
=head1 SYNOPSIS
use MooseX::Blessed::Reconstruct;
my $obj = bless( {
init_arg_foo => "Blah",
arf => "yay",
}, "Foo" );
my $proper = MooseX::Blessed::Reconstruct->new->visit($obj);
# equivalent to:
my $proper = Foo->meta->new_object(%$obj);
# but recursive (and works with shared references)
=head1 DESCRIPTION
The purpose of this module is to "fix up" blessed data into a real Moose
object.
This is used internally by L<MooseX::YAML> but has no implementation details
having to do with L<YAML> itself.
=head1 METHODS
See L<Data::Visitor>
=over 4
=item visit_object $object
Calls L<Class::MOP/load_class> on the C<ref> of $object.
If there's a metaclass, calls C<visit_object_with_meta>, otherwise C<visit_ref>
is used to walk the object brutishly.
Returns a deep clone of the input structure with all the L<Moose> objects
reconstructed "properly".
=item visit_object_with_meta $obj, $meta
Uses the metaclass C<$meta> to create a new instance, registers the instance
with L<Data::Visitor>'s cycle tracking, and then inflates it using
L<Moose::Meta::Class/new_object>.
=item prepare_args $obj
Collapses $obj into key value pairs to be used as init args to
L<Moose::Meta::Class/new_object>.
=back
=head1 VERSION CONTROL
This module is maintained using Darcs. You can get the latest version from
L<http://nothingmuch.woobling.org/code>, and use C<darcs send> to commit
changes.
=head1 AUTHOR
Jonathan Rockway
Yuval Kogman E<lt>nothingmuch@woobling.orgE<gt>
=head1 COPYRIGHT
Copyright (c) 2008 Infinity Interactive, Yuval Kogman. All rights
reserved This program is free software; you can redistribute
it and/or modify it under the same terms as Perl itself.
=cut
|