/usr/share/augeas/lenses/dist/openvpn.aug is in augeas-lenses 1.10.1-2.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535 536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576 577 578 579 580 581 582 583 584 585 586 587 588 589 590 591 592 593 594 595 596 597 598 599 600 601 602 603 604 605 606 607 608 609 610 611 612 613 614 615 616 617 618 619 620 621 622 623 624 625 626 627 628 629 630 631 632 633 634 635 636 637 638 639 640 641 642 643 644 645 646 647 648 649 650 651 652 | (* OpenVPN module for Augeas
Author: Raphael Pinson <raphink@gmail.com>
Author: Justin Akers <dafugg@gmail.com>
Reference: http://openvpn.net/index.php/documentation/howto.html
Reference: https://community.openvpn.net/openvpn/wiki/Openvpn23ManPage
TODO: Inline file support
*)
module OpenVPN =
autoload xfm
(************************************************************************
* USEFUL PRIMITIVES
*************************************************************************)
let eol = Util.eol
let indent = Util.indent
(* Define separators *)
let sep = Util.del_ws_spc
(* Define value regexps.
Custom simplified ipv6 used instead of Rx.ipv6 as the augeas Travis instances
are limited to 2GB of memory. Using 'ipv6_re = Rx.ipv6' consumes an extra
2GB of memory and thus the test is OOM-killed.
*)
let ipv6_re = /[0-9A-Fa-f:]+/
let ipv4_re = Rx.ipv4
let ip_re = ipv4_re|ipv6_re
let num_re = Rx.integer
let fn_re = /[^#; \t\n][^#;\n]*[^#; \t\n]|[^#; \t\n]/
let fn_safe_re = /[^#; \t\r\n]+/
let an_re = /[a-z][a-z0-9_-]*/
let hn_re = Rx.hostname
let port_re = /[0-9]+/
let host_re = ip_re|hn_re
let proto_re = /(tcp|udp)/
let proto_ext_re = /(udp|tcp-client|tcp-server)/
let alg_re = /(none|[A-Za-z][A-Za-z0-9-]+)/
let ipv6_bits_re = ipv6_re . /\/[0-9]+/
(* Define store aliases *)
let ip = store ip_re
let num = store num_re
let filename = store fn_re
let filename_safe = store fn_safe_re
let hostname = store hn_re
let sto_to_dquote = store /[^"\n]+/ (* " Emacs, relax *)
let port = store port_re
let host = store host_re
let proto = store proto_re
let proto_ext = store proto_ext_re
(* define comments and empty lines *)
let comment = Util.comment_generic /[ \t]*[;#][ \t]*/ "# "
let comment_or_eol = eol | Util.comment_generic /[ \t]*[;#][ \t]*/ " # "
let empty = Util.empty
(************************************************************************
* SINGLE VALUES
*
* - local => IP|hostname
* - port => num
* - proto => udp|tcp-client|tcp-server
* - proto-force => udp|tcp
* - mode => p2p|server
* - dev => (tun|tap)\d*
* - dev-node => filename
* - ca => filename
* - config => filename
* - cert => filename
* - key => filename
* - dh => filename
* - ifconfig-pool-persist => filename
* - learn-address => filename
* - cipher => [A-Z0-9-]+
* - max-clients => num
* - user => alphanum
* - group => alphanum
* - status => filename
* - log => filename
* - log-append => filename
* - client-config-dir => filename
* - verb => num
* - mute => num
* - fragment => num
* - mssfix => num
* - connect-retry num
* - connect-retry-max num
* - connect-timeout num
* - http-proxy-timeout num
* - max-routes num
* - ns-cert-type => "server"
* - resolv-retry => "infinite"
* - script-security => [0-3] (execve|system)?
* - ipchange => command
* - topology => type
*************************************************************************)
let single_host = "local" | "tls-remote"
let single_ip = "lladdr"
let single_ipv6_bits = "iroute-ipv6"
| "server-ipv6"
| "ifconfig-ipv6-pool"
let single_num = "port"
| "max-clients"
| "verb"
| "mute"
| "fragment"
| "mssfix"
| "connect-retry"
| "connect-retry-max"
| "connect-timeout"
| "http-proxy-timeout"
| "resolv-retry"
| "lport"
| "rport"
| "max-routes"
| "max-routes-per-client"
| "route-metric"
| "tun-mtu"
| "tun-mtu-extra"
| "shaper"
| "ping"
| "ping-exit"
| "ping-restart"
| "sndbuf"
| "rcvbuf"
| "txqueuelen"
| "link-mtu"
| "nice"
| "management-log-cache"
| "bcast-buffers"
| "tcp-queue-limit"
| "server-poll-timeout"
| "keysize"
| "pkcs11-pin-cache"
| "tls-timeout"
| "reneg-bytes"
| "reneg-pkts"
| "reneg-sec"
| "hand-window"
| "tran-window"
let single_fn = "ca"
| "cert"
| "extra-certs"
| "config"
| "key"
| "dh"
| "log"
| "log-append"
| "client-config-dir"
| "dev-node"
| "cd"
| "chroot"
| "writepid"
| "client-config-dir"
| "tmp-dir"
| "replay-persist"
| "ca"
| "capath"
| "pkcs12"
| "pkcs11-id"
| "askpass"
| "tls-export-cert"
| "x509-track"
let single_an = "user"
| "group"
| "management-client-user"
| "management-client-group"
let single_cmd = "ipchange"
| "iproute"
| "route-up"
| "route-pre-down"
| "mark"
| "up"
| "down"
| "setcon"
| "echo"
| "client-connect"
| "client-disconnect"
| "learn-address"
| "tls-verify"
let single_entry (kw:regexp) (re:regexp)
= [ key kw . sep . store re . comment_or_eol ]
let single_opt_entry (kw:regexp) (re:regexp)
= [ key kw . (sep . store re)? .comment_or_eol ]
let single = single_entry single_num num_re
| single_entry single_fn fn_re
| single_entry single_an an_re
| single_entry single_host host_re
| single_entry single_ip ip_re
| single_entry single_ipv6_bits ipv6_bits_re
| single_entry single_cmd fn_re
| single_entry "proto" proto_ext_re
| single_entry "proto-force" proto_re
| single_entry "mode" /(p2p|server)/
| single_entry "dev" /(tun|tap)[0-9]*|null/
| single_entry "dev-type" /(tun|tap)/
| single_entry "topology" /(net30|p2p|subnet)/
| single_entry "cipher" alg_re
| single_entry "auth" alg_re
| single_entry "resolv-retry" "infinite"
| single_entry "script-security" /[0-3]( execve| system)?/
| single_entry "route-gateway" (host_re|/dhcp/)
| single_entry "mtu-disc" /(no|maybe|yes)/
| single_entry "remap-usr1" /SIG(HUP|TERM)/
| single_entry "socket-flags" /(TCP_NODELAY)/
| single_entry "auth-retry" /(none|nointeract|interact)/
| single_entry "tls-version-max" Rx.decimal
| single_entry "verify-hash" /([A-Za-z0-9]{2}:)+[A-Za-z0-9]{2}/
| single_entry "pkcs11-cert-private" /[01]/
| single_entry "pkcs11-protected-authentication" /[01]/
| single_entry "pkcs11-private-mode" /[A-Za-z0-9]+/
| single_entry "key-method" /[12]/
| single_entry "ns-cert-type" /(client|server)/
| single_entry "remote-cert-tls" /(client|server)/
let single_opt = single_opt_entry "comp-lzo" /(yes|no|adaptive)/
| single_opt_entry "syslog" fn_re
| single_opt_entry "daemon" fn_re
| single_opt_entry "auth-user-pass" fn_re
| single_opt_entry "explicit-exit-notify" num_re
| single_opt_entry "engine" fn_re
(************************************************************************
* DOUBLE VALUES
*************************************************************************)
let double_entry (kw:regexp) (a:string) (aval:regexp) (b:string) (bval:regexp)
= [ key kw
. sep . [ label a . store aval ]
. sep . [ label b . store bval ]
. comment_or_eol
]
let double_secopt_entry (kw:regexp) (a:string) (aval:regexp) (b:string) (bval:regexp)
= [ key kw
. sep . [ label a . store aval ]
. (sep . [ label b . store bval ])?
. comment_or_eol
]
let double = double_entry "keepalive" "ping" num_re "timeout" num_re
| double_entry "hash-size" "real" num_re "virtual" num_re
| double_entry "ifconfig" "local" ip_re "remote" ip_re
| double_entry "connect-freq" "num" num_re "sec" num_re
| double_entry "verify-x509-name" "name" hn_re "type"
/(subject|name|name-prefix)/
| double_entry "ifconfig-ipv6" "address" ipv6_bits_re "remote" ipv6_re
| double_entry "ifconfig-ipv6-push" "address" ipv6_bits_re "remote" ipv6_re
| double_secopt_entry "iroute" "local" ip_re "netmask" ip_re
| double_secopt_entry "stale-routes-check" "age" num_re "interval" num_re
| double_secopt_entry "ifconfig-pool-persist"
"file" fn_safe_re "seconds" num_re
| double_secopt_entry "secret" "file" fn_safe_re "direction" /[01]/
| double_secopt_entry "prng" "algorithm" alg_re "nsl" num_re
| double_secopt_entry "replay-window" "window-size" num_re "seconds" num_re
(************************************************************************
* FLAGS
*************************************************************************)
let flag_words = "client-to-client"
| "duplicate-cn"
| "persist-key"
| "persist-tun"
| "client"
| "remote-random"
| "nobind"
| "mute-replay-warnings"
| "http-proxy-retry"
| "socks-proxy-retry"
| "remote-random-hostname"
| "show-proxy-settings"
| "float"
| "bind"
| "nobind"
| "tun-ipv6"
| "ifconfig-noexec"
| "ifconfig-nowarn"
| "route-noexec"
| "route-nopull"
| "allow-pull-fqdn"
| "mtu-test"
| "ping-timer-rem"
| "persist-tun"
| "persist-local-ip"
| "persist-remote-ip"
| "mlock"
| "up-delay"
| "down-pre"
| "up-restart"
| "disable-occ"
| "errors-to-stderr"
| "passtos"
| "suppress-timestamps"
| "fast-io"
| "multihome"
| "comp-noadapt"
| "management-client"
| "management-query-passwords"
| "management-query-proxy"
| "management-query-remote"
| "management-forget-disconnect"
| "management-hold"
| "management-signal"
| "management-up-down"
| "management-client-auth"
| "management-client-pf"
| "push-reset"
| "push-peer-info"
| "disable"
| "ifconfig-pool-linear"
| "client-to-client"
| "duplicate-cn"
| "ccd-exclusive"
| "tcp-nodelay"
| "opt-verify"
| "auth-user-pass-optional"
| "client-cert-not-required"
| "username-as-common-name"
| "pull"
| "key-direction"
| "no-replay"
| "mute-replay-warnings"
| "no-iv"
| "use-prediction-resistance"
| "test-crypto"
| "tls-server"
| "tls-client"
| "pkcs11-id-management"
| "single-session"
| "tls-exit"
| "auth-nocache"
| "show-ciphers"
| "show-digests"
| "show-tls"
| "show-engines"
| "genkey"
| "mktun"
| "rmtun"
let flag_entry (kw:regexp)
= [ key kw . comment_or_eol ]
let flag = flag_entry flag_words
(************************************************************************
* OTHER FIELDS
*
* - server => IP IP [nopool]
* - server-bridge => IP IP IP IP
* - route => host host [host [num]]
* - push => "string"
* - tls-auth => filename [01]
* - remote => hostname/IP [num] [(tcp|udp)]
* - management => IP num filename
* - http-proxy => host port [filename|keyword] [method]
* - http-proxy-option => (VERSION decimal|AGENT string)
* ...
* and many others
*
*************************************************************************)
let server = [ key "server"
. sep . [ label "address" . ip ]
. sep . [ label "netmask" . ip ]
. (sep . [ key "nopool" ]) ?
. comment_or_eol
]
let server_bridge =
let ip_params = [ label "address" . ip ] . sep
. [ label "netmask" . ip ] . sep
. [ label "start" . ip ] . sep
. [ label "end" . ip ] in
[ key "server-bridge"
. sep . (ip_params|store /(nogw)/)
. comment_or_eol
]
let route =
let route_net_kw = store (/(vpn_gateway|net_gateway|remote_host)/|host_re) in
[ key "route" . sep
. [ label "address" . route_net_kw ]
. (sep . [ label "netmask" . store (ip_re|/default/) ]
. (sep . [ label "gateway" . route_net_kw ]
. (sep . [ label "metric" . store (/default/|num_re)] )?
)?
)?
. comment_or_eol
]
let route_ipv6 =
let route_net_re = /(vpn_gateway|net_gateway|remote_host)/ in
[ key "route-ipv6" . sep
. [ label "network" . store (route_net_re|ipv6_bits_re) ]
. (sep . [ label "gateway" . store (route_net_re|ipv6_re) ]
. (sep . [ label "metric" . store (/default/|num_re)] )?
)?
. comment_or_eol
]
let push = [ key "push" . sep
. Quote.do_dquote sto_to_dquote
. comment_or_eol
]
let tls_auth = [ key "tls-auth" . sep
. [ label "key" . filename ] . sep
. [ label "is_client" . store /[01]/ ] . comment_or_eol
]
let remote = [ key "remote" . sep
. [ label "server" . host ]
. (sep . [label "port" . port]
. (sep . [label "proto" . proto]) ? ) ?
. comment_or_eol
]
let http_proxy =
let auth_method_re = /(none|basic|ntlm)/ in
let auth_method = store auth_method_re in
[ key "http-proxy"
. sep . [ label "server" . host ]
. sep . [ label "port" . port ]
. (sep . [ label "auth" . filename_safe ]
. (sep . [ label "auth-method" . auth_method ]) ? )?
. comment_or_eol
]
let http_proxy_option = [ key "http-proxy-option"
. sep . [ label "option" . store /(VERSION|AGENT)/ ]
. sep . [ label "value" . filename ]
. comment_or_eol
]
let socks_proxy = [ key "socks-proxy"
. sep . [ label "server" . host ]
. (sep . [ label "port" . port ]
. (sep . [ label "auth" . filename_safe ])? )?
. comment_or_eol
]
let port_share = [ key "port-share"
. sep . [ label "host" . host ]
. sep . [ label "port" . port ]
. (sep . [ label "dir" . filename ])?
. comment_or_eol
]
let route_delay = [ key "route-delay"
. (sep . [ label "seconds" . num ]
. (sep . [ label "win-seconds" . num ] ) ?
)?
. comment_or_eol
]
let inetd = [ key "inetd"
. (sep . [label "mode" . store /(wait|nowait)/ ]
. (sep . [ label "progname" . filename ] ) ?
)?
. comment_or_eol
]
let inactive = [ key "inactive"
. sep . [ label "seconds" . num ]
. (sep . [ label "bytes" . num ] ) ?
. comment_or_eol
]
let client_nat = [ key "client-nat"
. sep . [ label "type" . store /(snat|dnat)/ ]
. sep . [ label "network" . ip ]
. sep . [ label "netmask" . ip ]
. sep . [ label "alias" . ip ]
. comment_or_eol
]
let status = [ key "status"
. sep . [ label "file" . filename_safe ]
. (sep . [ label "repeat-seconds" . num ]) ?
. comment_or_eol
]
let plugin = [ key "plugin"
. sep . [ label "file" . filename_safe ]
. (sep . [ label "init-string" . filename ]) ?
. comment_or_eol
]
let management = [ key "management" . sep
. [ label "server" . ip ]
. sep . [ label "port" . port ]
. (sep . [ label "pwfile" . filename ] ) ?
. comment_or_eol
]
let auth_user_pass_verify = [ key "auth-user-pass-verify"
. sep . [ Quote.quote_spaces (label "command") ]
. sep . [ label "method" . store /via-(env|file)/ ]
. comment_or_eol
]
let static_challenge = [ key "static-challenge"
. sep . [ Quote.quote_spaces (label "text") ]
. sep . [ label "echo" . store /[01]/ ]
. comment_or_eol
]
let cryptoapicert = [ key "cryptoapicert" . sep . Quote.dquote
. [ key /[A-Z]+/ . Sep.colon . store /[A-Za-z _-]+/ ]
. Quote.dquote . comment_or_eol
]
let setenv =
let envvar = /[^#;\/ \t\n][A-Za-z0-9_-]+/ in
[ key ("setenv"|"setenv-safe")
. sep . [ key envvar . sep . store fn_re ]
. comment_or_eol
]
let redirect =
let redirect_flag = /(local|autolocal|def1|bypass-dhcp|bypass-dns|block-local)/ in
let redirect_key = "redirect-gateway" | "redirect-private" in
[ key redirect_key
. (sep . [ label "flag" . store redirect_flag ] ) +
. comment_or_eol
]
let tls_cipher =
let ciphername = /[A-Za-z0-9!_-]+/ in
[ key "tls-cipher" . sep
. [label "cipher" . store ciphername]
. (Sep.colon . [label "cipher" . store ciphername])*
. comment_or_eol
]
let remote_cert_ku =
let usage = [label "usage" . store /[A-Za-z0-9]{1,2}/] in
[ key "remote-cert-ku" . sep . usage . (sep . usage)* . comment_or_eol ]
(* FIXME: Surely there's a nicer way to do this *)
let remote_cert_eku =
let oid = [label "oid" . store /[0-9]+\.([0-9]+\.)*[0-9]+/] in
let symbolic = [Quote.do_quote_opt
(label "symbol" . store /[A-Za-z0-9][A-Za-z0-9 _-]*[A-Za-z0-9]/)] in
[ key "remote-cert-eku" . sep . (oid|symbolic) . comment_or_eol ]
let status_version = [ key "status-version"
. (sep . num) ?
. comment_or_eol
]
let ifconfig_pool = [ key "ifconfig-pool"
. sep . [ label "start" . ip ]
. sep . [ label "end" . ip ]
. (sep . [ label "netmask" . ip ])?
. comment_or_eol
]
let ifconfig_push = [ key "ifconfig-push"
. sep . [ label "local" . ip ]
. sep . [ label "remote-netmask" . ip ]
. (sep . [ label "alias" . store /[A-Za-z0-9_-]+/ ] )?
. comment_or_eol
]
let ignore_unknown_option = [ key "ignore-unknown-option"
. (sep . [ label "opt" . store /[A-Za-z0-9_-]+/ ] ) +
. comment_or_eol
]
let tls_version_min = [ key "tls-version-min"
. sep . store Rx.decimal
. (sep . [ key "or-highest" ]) ?
. comment_or_eol
]
let crl_verify = [ key "crl-verify"
. sep . filename_safe
. (sep . [ key "dir" ]) ?
. comment_or_eol
]
let x509_username_field =
let fieldname = /[A-Za-z0-9_-]+/ in
let extfield = ([key /ext/ . Sep.colon . store fieldname]) in
let subjfield = ([label "subj" . store fieldname]) in
[ key "x509-username-field"
. sep . (extfield|subjfield)
. comment_or_eol
]
let other = server
| server_bridge
| route
| push
| tls_auth
| remote
| http_proxy
| http_proxy_option
| socks_proxy
| management
| route_delay
| client_nat
| redirect
| inactive
| setenv
| inetd
| status
| status_version
| plugin
| ifconfig_pool
| ifconfig_push
| ignore_unknown_option
| auth_user_pass_verify
| port_share
| static_challenge
| tls_version_min
| tls_cipher
| cryptoapicert
| x509_username_field
| remote_cert_ku
| remote_cert_eku
| crl_verify
| route_ipv6
(************************************************************************
* LENS & FILTER
*************************************************************************)
let lns = ( comment | empty | single | single_opt | double | flag | other )*
let filter = (incl "/etc/openvpn/client.conf")
. (incl "/etc/openvpn/server.conf")
let xfm = transform lns filter
|