/usr/share/augeas/lenses/dist/pam.aug is in augeas-lenses 1.10.1-2.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 | (*
Module: Pam
Parses /etc/pam.conf and /etc/pam.d/* service files
Author: David Lutterkort <lutter@redhat.com>
About: Reference
This lens tries to keep as close as possible to `man pam.conf` where
possible.
About: Licence
This file is licensed under the LGPL v2+, like the rest of Augeas.
About: Lens Usage
About: Configuration files
This lens autoloads /etc/pam.d/* for service specific files. See <filter>.
It provides a lens for /etc/pam.conf, which is used in the PamConf module.
*)
module Pam =
autoload xfm
let eol = Util.eol
let indent = Util.indent
(* For the control syntax of [key=value ..] we could split the key value *)
(* pairs into an array and generate a subtree control/N/KEY = VALUE *)
let control = /(\[[^]#\n]*\]|[^[ \t][^ \t]*)/
let word = /[^# \t\n]+/
(* Allowed types *)
let types = /(auth|session|account|password)/i
(* This isn't entirely right: arguments enclosed in [ .. ] can contain *)
(* a ']' if escaped with a '\' and can be on multiple lines ('\') *)
let argument = /(\[[^]#\n]+\]|[^[#\n \t][^#\n \t]*)/
let comment = Util.comment
let comment_or_eol = Util.comment_or_eol
let empty = Util.empty
(* Not mentioned in the man page, but Debian uses the syntax *)
(* @include module *)
(* quite a bit *)
let include = [ indent . Util.del_str "@" . key "include" .
Util.del_ws_spc . store word . eol ]
(* Shared with PamConf *)
let record = [ label "optional" . del "-" "-" ]? .
[ label "type" . store types ] .
Sep.space .
[ label "control" . store control] .
Sep.space .
[ label "module" . store word ] .
[ Sep.space . label "argument" . store argument ]* .
comment_or_eol
let record_svc = [ seq "record" . indent . record ]
let lns = ( empty | comment | include | record_svc ) *
let filter = incl "/etc/pam.d/*"
. excl "/etc/pam.d/allow.pamlist"
. excl "/etc/pam.d/README"
. Util.stdexcl
let xfm = transform lns filter
(* Local Variables: *)
(* mode: caml *)
(* End: *)
|