axiom-source 20170501-3 / usr / share / axiom-20170501 / src / algebra / UTSCAT.spad

)abbrev category UTSCAT UnivariateTaylorSeriesCategory
++ Author: Clifton J. Williamson
++ Date Created: 21 December 1989
++ Date Last Updated: 26 May 1994
++ Description:
++ \spadtype{UnivariateTaylorSeriesCategory} is the category of Taylor
++ series in one variable.

UnivariateTaylorSeriesCategory(Coef) : Category == SIG where
  Coef  : Ring

  I    ==> Integer
  L    ==> List
  NNI  ==> NonNegativeInteger
  OUT  ==> OutputForm
  RN   ==> Fraction Integer
  STTA ==> StreamTaylorSeriesOperations Coef
  STTF ==> StreamTranscendentalFunctions Coef
  STNC ==> StreamTranscendentalFunctionsNonCommutative Coef
  Term ==> Record(k:NNI,c:Coef)

  SIG ==> UnivariatePowerSeriesCategory(Coef,NNI) with

    series : Stream Term -> %
      ++ \spad{series(st)} creates a series from a stream of non-zero terms,
      ++ where a term is an exponent-coefficient pair.  The terms in the
      ++ stream should be ordered by increasing order of exponents.

    coefficients : % -> Stream Coef
      ++ \spad{coefficients(a0 + a1 x + a2 x**2 + ...)} returns a stream
      ++ of coefficients: \spad{[a0,a1,a2,...]}. The entries of the stream
      ++ may be zero.

    series : Stream Coef -> %
      ++ \spad{series([a0,a1,a2,...])} is the Taylor series
      ++ \spad{a0 + a1 x + a2 x**2 + ...}.

    quoByVar : % -> %
      ++ \spad{quoByVar(a0 + a1 x + a2 x**2 + ...)}
      ++ returns \spad{a1 + a2 x + a3 x**2 + ...}
      ++ Thus, this function substracts the constant term and divides by
      ++ the series variable.  This function is used when Laurent series
      ++ are represented by a Taylor series and an order.

    multiplyCoefficients : (I -> Coef,%) -> %
      ++ \spad{multiplyCoefficients(f,sum(n = 0..infinity,a[n] * x**n))}
      ++ returns \spad{sum(n = 0..infinity,f(n) * a[n] * x**n)}.
      ++ This function is used when Laurent series are represented by
      ++ a Taylor series and an order.

    polynomial : (%,NNI) -> Polynomial Coef
      ++ \spad{polynomial(f,k)} returns a polynomial consisting of the sum
      ++ of all terms of f of degree \spad{<= k}.

    polynomial : (%,NNI,NNI) -> Polynomial Coef
      ++ \spad{polynomial(f,k1,k2)} returns a polynomial consisting of the
      ++ sum of all terms of f of degree d with \spad{k1 <= d <= k2}.

    if Coef has Field then

      "**" : (%,Coef) -> %
        ++ \spad{f(x) ** a} computes a power of a power series.
        ++ When the coefficient ring is a field, we may raise a series
        ++ to an exponent from the coefficient ring provided that the
        ++ constant coefficient of the series is 1.

    if Coef has Algebra Fraction Integer then

      integrate : % -> %
        ++ \spad{integrate(f(x))} returns an anti-derivative of the power
        ++ series \spad{f(x)} with constant coefficient 0.
        ++ We may integrate a series when we can divide coefficients
        ++ by integers.

      if Coef has integrate: (Coef,Symbol) -> Coef and _
         Coef has variables: Coef -> List Symbol then

        integrate : (%,Symbol) -> %
          ++ \spad{integrate(f(x),y)} returns an anti-derivative of the
          ++ power series \spad{f(x)} with respect to the variable \spad{y}.

      if Coef has TranscendentalFunctionCategory and _
         Coef has PrimitiveFunctionCategory and _
         Coef has AlgebraicallyClosedFunctionSpace Integer then

        integrate : (%,Symbol) -> %
          ++ \spad{integrate(f(x),y)} returns an anti-derivative of
          ++ the power series \spad{f(x)} with respect to the variable
          ++ \spad{y}.

      RadicalCategory
        --++ We provide rational powers when we can divide coefficients
        --++ by integers.

      TranscendentalFunctionCategory
        --++ We provide transcendental functions when we can divide
        --++ coefficients by integers.

   add

     zero? x ==
       empty? (coefs := coefficients x) => true
       (zero? frst coefs) and (empty? rst coefs) => true
       false
 
 --% OutputForms
 
 --  We provide defaulr output functions on UTSCAT using the functions
 --  'coefficients', 'center', and 'variable'.
 
     factorials?: () -> Boolean
     -- check a global Lisp variable
     factorials?() == false
 
     termOutput: (I,Coef,OUT) -> OUT
     termOutput(k,c,vv) ==
     -- creates a term c * vv ** k
       k = 0 => c :: OUT
       mon := (k = 1 => vv; vv ** (k :: OUT))
       c = 1 => mon
       c = -1 => -mon
       (c :: OUT) * mon
 
     showAll?: () -> Boolean
     -- check a global Lisp variable
     showAll?() == true
 
     coerce(p:%):OUT ==
       empty? (uu := coefficients p) => (0$Coef) :: OUT
       var := variable p; cen := center p
       vv :=
         zero? cen => var :: OUT
         paren(var :: OUT - cen :: OUT)
       n : NNI ; count : NNI := _$streamCount$Lisp
       l : L OUT := empty()
       for n in 0..count while not empty? uu repeat
         if frst(uu) ^= 0 then
           l := concat(termOutput(n :: I,frst uu,vv),l)
         uu := rst uu
       if showAll?() then
         for n in (count + 1).. while explicitEntries? uu and _
                not eq?(uu,rst uu) repeat
           if frst(uu) ^= 0 then
             l := concat(termOutput(n :: I,frst uu,vv),l)
           uu := rst uu
       l :=
         explicitlyEmpty? uu => l
         eq?(uu,rst uu) and frst uu = 0 => l
         concat(prefix("O" :: OUT,[vv ** (n :: OUT)]),l)
       empty? l => (0$Coef) :: OUT
       reduce("+",reverse_! l)
 
     if Coef has Field then

       (x:%) ** (r:Coef) == series power(r,coefficients x)$STTA
 
     if Coef has Algebra Fraction Integer then

       if Coef has CommutativeRing then

         (x:%) ** (y:%)    == series(coefficients x **$STTF coefficients y)
 
         (x:%) ** (r:RN)   == series powern(r,coefficients x)$STTA
 
         exp x == series exp(coefficients x)$STTF
 
         log x == series log(coefficients x)$STTF
 
         sin x == series sin(coefficients x)$STTF
 
         cos x == series cos(coefficients x)$STTF
 
         tan x == series tan(coefficients x)$STTF
 
         cot x == series cot(coefficients x)$STTF
 
         sec x == series sec(coefficients x)$STTF
 
         csc x == series csc(coefficients x)$STTF
 
         asin x == series asin(coefficients x)$STTF
 
         acos x == series acos(coefficients x)$STTF
 
         atan x == series atan(coefficients x)$STTF
 
         acot x == series acot(coefficients x)$STTF
 
         asec x == series asec(coefficients x)$STTF
 
         acsc x == series acsc(coefficients x)$STTF
 
         sinh x == series sinh(coefficients x)$STTF
 
         cosh x == series cosh(coefficients x)$STTF
 
         tanh x == series tanh(coefficients x)$STTF
 
         coth x == series coth(coefficients x)$STTF
 
         sech x == series sech(coefficients x)$STTF
 
         csch x == series csch(coefficients x)$STTF
 
         asinh x == series asinh(coefficients x)$STTF
 
         acosh x == series acosh(coefficients x)$STTF
 
         atanh x == series atanh(coefficients x)$STTF
 
         acoth x == series acoth(coefficients x)$STTF
 
         asech x == series asech(coefficients x)$STTF
 
         acsch x == series acsch(coefficients x)$STTF
 
       else

         (x:%) ** (y:%) == series(coefficients x **$STNC coefficients y)
 
         (x:%) ** (r:RN) ==
           coefs := coefficients x
           empty? coefs =>
             positive? r => 0
             zero? r => error "0**0 undefined"
             error "0 raised to a negative power"
           not (frst coefs = 1) =>
             error "**: constant coefficient should be 1"
           coefs := concat(0,rst coefs)
           onePlusX := monom(1,0)$STTA + $STTA monom(1,1)$STTA
           ratPow := powern(r,onePlusX)$STTA
           series compose(ratPow,coefs)$STTA
 
         exp x == series exp(coefficients x)$STNC
 
         log x == series log(coefficients x)$STNC
 
         sin x == series sin(coefficients x)$STNC
 
         cos x == series cos(coefficients x)$STNC
 
         tan x == series tan(coefficients x)$STNC
 
         cot x == series cot(coefficients x)$STNC
 
         sec x == series sec(coefficients x)$STNC
 
         csc x == series csc(coefficients x)$STNC
 
         asin x == series asin(coefficients x)$STNC
 
         acos x == series acos(coefficients x)$STNC
 
         atan x == series atan(coefficients x)$STNC
 
         acot x == series acot(coefficients x)$STNC
 
         asec x == series asec(coefficients x)$STNC
 
         acsc x == series acsc(coefficients x)$STNC
 
         sinh x == series sinh(coefficients x)$STNC
 
         cosh x == series cosh(coefficients x)$STNC
 
         tanh x == series tanh(coefficients x)$STNC
 
         coth x == series coth(coefficients x)$STNC
 
         sech x == series sech(coefficients x)$STNC
 
         csch x == series csch(coefficients x)$STNC
 
         asinh x == series asinh(coefficients x)$STNC
 
         acosh x == series acosh(coefficients x)$STNC
 
         atanh x == series atanh(coefficients x)$STNC
 
         acoth x == series acoth(coefficients x)$STNC
 
         asech x == series asech(coefficients x)$STNC
 
         acsch x == series acsch(coefficients x)$STNC