/usr/share/common-lisp/source/clsql/sql/loop-extension.lisp is in cl-sql 6.7.0-1.1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 | ;;;; -*- Mode: LISP; Syntax: ANSI-Common-Lisp; Base: 10 -*-
;;;; *************************************************************************
;;;; FILE IDENTIFICATION
;;;;
;;;; Name: loop-extension.lisp
;;;; Purpose: Extensions to the Loop macro for CLSQL
;;;;
;;;; Copyright (c) 2001-2006 Kevin Rosenberg and (c) 1999-2001 Pierre R. Mai
;;;;
;;;; *************************************************************************
(in-package #:clsql-sys)
#+(or allegro sbcl)
(eval-when (:compile-toplevel :load-toplevel :execute)
(defpackage #:ansi-loop
(:import-from #+sbcl #:sb-loop #+allegro #:excl
#:*loop-epilogue*
#:*loop-ansi-universe*
#:add-loop-path)))
#+(or allegro sbcl)
(defun ansi-loop::loop-gentemp (&optional (pref 'loopva-))
(gensym (string pref)))
#+clisp
(eval-when (:compile-toplevel :load-toplevel :execute)
(when (find-package "ANSI-LOOP") (push :clisp-aloop cl:*features*)))
#+(or allegro clisp-aloop cmu openmcl sbcl scl)
(defun loop-record-iteration-path (variable data-type prep-phrases)
(let ((in-phrase nil)
(from-phrase nil))
(loop for (prep . rest) in prep-phrases
do
(case prep
((:in :of)
(when in-phrase
(error 'clsql:sql-user-error
:message
(format nil
"Duplicate OF or IN iteration path: ~S."
(cons prep rest))))
(setq in-phrase rest))
((:from)
(when from-phrase
(error 'clsql:sql-user-error
:message
(format nil
"Duplicate FROM iteration path: ~S."
(cons prep rest))))
(setq from-phrase rest))
(t
(error 'clsql:sql-user-error
:message
(format nil"Unknown preposition: ~S." prep)))))
(unless in-phrase
(error 'clsql:sql-user-error
:message "Missing OF or IN iteration path."))
(unless from-phrase
(setq from-phrase '(*default-database*)))
(unless (consp variable)
(setq variable (list variable)))
(cond
;; object query
((and (consp (first in-phrase))
(string-equal "sql-query" (symbol-name (caar in-phrase)))
(consp (second (first in-phrase)))
(eq 'quote (first (second (first in-phrase))))
(symbolp (second (second (first in-phrase)))))
(let ((result-var (ansi-loop::loop-gentemp
'loop-record-result-))
(step-var (ansi-loop::loop-gentemp 'loop-record-step-)))
`(((,variable nil ,@(and data-type (list data-type)))
(,result-var (query ,(first in-phrase)))
(,step-var nil))
()
()
()
(if (null ,result-var)
t
(progn
(setq ,step-var (first ,result-var))
(setq ,result-var (rest ,result-var))
nil))
(,variable ,step-var)
(null ,result-var)
()
(if (null ,result-var)
t
(progn
(setq ,step-var (first ,result-var))
(setq ,result-var (rest ,result-var))
nil))
(,variable ,step-var))))
((consp variable)
(let ((query-var (ansi-loop::loop-gentemp 'loop-record-))
(db-var (ansi-loop::loop-gentemp 'loop-record-database-))
(result-set-var (ansi-loop::loop-gentemp
'loop-record-result-set-))
(step-var (ansi-loop::loop-gentemp 'loop-record-step-)))
(push `(when ,result-set-var
(database-dump-result-set ,result-set-var ,db-var))
ansi-loop::*loop-epilogue*)
`(((,variable nil ,@(and data-type (list data-type)))
(,query-var ,(first in-phrase))
(,db-var ,(first from-phrase))
(,result-set-var t)
(,step-var nil))
((multiple-value-bind (%rs %cols)
(database-query-result-set ,query-var ,db-var :result-types :auto)
(setq ,result-set-var %rs ,step-var (make-list %cols))))
()
()
(not (database-store-next-row ,result-set-var ,db-var ,step-var))
(,variable ,step-var)
(not ,result-set-var)
()
(not (database-store-next-row ,result-set-var ,db-var ,step-var))
(,variable ,step-var)))))))
#+(or allegro clisp-aloop cmu openmcl sbcl scl)
(ansi-loop::add-loop-path '(record records tuple tuples)
'loop-record-iteration-path
ansi-loop::*loop-ansi-universe*
:preposition-groups '((:of :in) (:from))
:inclusive-permitted nil)
#+lispworks
(cl-user::define-loop-method (loop::record loop::records loop::tuple loop::tuples)
clsql-loop-method
(loop::in loop::of loop::from))
#+lispworks
(defun clsql-loop-method (method-name iter-var iter-var-data-type
prep-phrases inclusive? allowed-preps
method-specific-data)
(declare (ignore method-name iter-var-data-type inclusive? allowed-preps method-specific-data))
(let ((in-phrase nil)
(from-phrase nil))
(loop for (prep . rest) in prep-phrases
do
(cond
((or (eq prep 'loop::in) (eq prep 'loop::of))
(when in-phrase
(error 'clsql:sql-user-error
:message
(format nil "Duplicate OF or IN iteration path: ~S."
(cons prep rest))))
(setq in-phrase rest))
((eq prep 'loop::from)
(when from-phrase
(error 'clsql:sql-user-error
:message
(format nil "Duplicate FROM iteration path: ~S."
(cons prep rest))))
(setq from-phrase rest))
(t
(error 'clsql:sql-user-error
:message (format nil "Unknown preposition: ~S." prep)))))
(unless in-phrase
(error 'clsql:sql-user-error
:message "Missing OF or IN iteration path."))
(unless from-phrase
(setq from-phrase '(clsql:*default-database*)))
(unless (consp iter-var)
(setq iter-var (list iter-var)))
(cond
;; object query
((and (consp in-phrase)
(string-equal "sql-query" (symbol-name (car in-phrase)))
(consp (second in-phrase))
(eq 'quote (first (second in-phrase)))
(symbolp (second (second in-phrase))))
(let ((result-var (gensym "LOOP-RECORD-RESULT-"))
(step-var (gensym "LOOP-RECORD-STEP-")))
(values
t
nil
`(,@(mapcar (lambda (v) `(,v nil)) iter-var)
(,result-var (clsql:query ,in-phrase))
(,step-var nil))
()
()
()
`((if (null ,result-var)
t
(progn
(setq ,step-var (first ,result-var))
(setq ,result-var (rest ,result-var))
nil)))
`(,iter-var ,step-var)
`((if (null ,result-var)
t
(progn
(setq ,step-var (first ,result-var))
(setq ,result-var (rest ,result-var))
nil)))
`(,iter-var ,step-var)
()
()
)))
((consp iter-var)
(let ((query-var (gensym "LOOP-RECORD-"))
(db-var (gensym "LOOP-RECORD-DATABASE-"))
(result-set-var (gensym "LOOP-RECORD-RESULT-SET-"))
(step-var (gensym "LOOP-RECORD-STEP-")))
(values
t
nil
`(,@(mapcar (lambda (v) `(,v nil)) iter-var)
(,query-var ,in-phrase)
(,db-var ,(first from-phrase))
(,result-set-var nil)
(,step-var nil))
`((multiple-value-bind (%rs %cols)
(clsql-sys:database-query-result-set ,query-var ,db-var :result-types :auto)
(setq ,result-set-var %rs ,step-var (make-list %cols))))
()
()
`((unless (clsql-sys:database-store-next-row ,result-set-var ,db-var ,step-var)
(when ,result-set-var
(clsql-sys:database-dump-result-set ,result-set-var ,db-var))
t))
`(,iter-var ,step-var)
`((unless (clsql-sys:database-store-next-row ,result-set-var ,db-var ,step-var)
(when ,result-set-var
(clsql-sys:database-dump-result-set ,result-set-var ,db-var))
t))
`(,iter-var ,step-var)
()
()))))))
#+clisp-aloop
(eval-when (:compile-toplevel :load-toplevel :execute)
(setq cl:*features* (delete :clisp-aloop cl:*features*)))
|