/usr/share/dia/xslt/dia-uml2haxe.xsl is in dia-common 0.97.3+git20160930-8.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 | <?xml version="1.0"?>
<!--
Transform dia UML objects to Haxe classes
Copyright(c) 2011 Frank Endres / Education Nationale <frank.endres@ac-nantes.fr>
This program is free software; you can redistribute it and/or modify
it under the terms of the CeCill License version 2 of the License
(http://www.cecill.info/licences/Licence_CeCILL_V2-en.txt)
-->
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output method="text"/>
<xsl:param name="directory"/>
<xsl:param name="ident">
<xsl:text> </xsl:text>
</xsl:param>
<xsl:template match="package">
<xsl:text>package </xsl:text>
<xsl:value-of select="name"/>
<xsl:text>;
</xsl:text>
<xsl:apply-templates/>
</xsl:template>
<xsl:template match="class">
<xsl:document href="{$directory}{@name}.hx" method="text">
<xsl:if test="comment">
<xsl:text>/* 
 </xsl:text>
<xsl:value-of select="comment"/>
<xsl:text>
 */</xsl:text>
</xsl:if>
<xsl:text>
</xsl:text>
<xsl:choose>
<xsl:when test="@abstract">
<xsl:text>interface </xsl:text>
</xsl:when>
<xsl:otherwise>
<xsl:text>class </xsl:text>
</xsl:otherwise>
</xsl:choose>
<xsl:value-of select="@name"/>
<xsl:if test="@stereotype!=''">
<xsl:text>, implements </xsl:text>
<xsl:value-of select="@stereotype"/>
</xsl:if>
<xsl:text> {
</xsl:text>
<xsl:apply-templates select="attributes"/>
<xsl:text>
</xsl:text>
<xsl:apply-templates select="operations"/>
<xsl:text>}
</xsl:text>
</xsl:document>
</xsl:template>
<xsl:template match="operations|attributes">
<xsl:if test="*[@visibility='private']">
<xsl:apply-templates select="*[@visibility='private']"/>
</xsl:if>
<xsl:if test="*[@visibility='public']">
<xsl:apply-templates select="*[@visibility='public']"/>
</xsl:if>
</xsl:template>
<xsl:template match="attribute">
<xsl:if test="comment!=''">
<xsl:text>
</xsl:text>
<xsl:value-of select="$ident"/>
<xsl:text>/*
</xsl:text>
<xsl:value-of select="$ident"/>
<xsl:text> * </xsl:text>
<xsl:value-of select="comment"/>
<xsl:text>
</xsl:text>
<xsl:value-of select="$ident"/>
<xsl:text> */
</xsl:text>
</xsl:if>
<xsl:value-of select="$ident"/>
<xsl:if test="@class_scope">
<xsl:text>static </xsl:text>
</xsl:if>
<xsl:if test="@visibility='public'">
<xsl:text>public </xsl:text>
</xsl:if>
<xsl:text>var </xsl:text>
<xsl:value-of select="name"/>
<xsl:text> : </xsl:text>
<xsl:value-of select="type"/>
<xsl:if test="value">
<xsl:text> = </xsl:text>
<xsl:value-of select="value"/>
</xsl:if>
<xsl:text>;
</xsl:text>
</xsl:template>
<xsl:template match="operation">
<xsl:if test="comment!=''">
<xsl:text>
</xsl:text>
<xsl:value-of select="$ident"/>
<xsl:text>/*
</xsl:text>
<xsl:value-of select="$ident"/>
<xsl:text> * </xsl:text>
<xsl:value-of select="comment"/>
<xsl:text>
</xsl:text>
<!--<xsl:for-each select="parameters/parameter/comment">
<xsl:value-of select="$ident"/>
<xsl:text> * @</xsl:text>
<xsl:value-of select="../name"/>
<xsl:text>
</xsl:text>
</xsl:for-each>-->
<xsl:value-of select="$ident"/>
<xsl:text> */
</xsl:text>
</xsl:if>
<xsl:value-of select="$ident"/>
<xsl:if test="@class_scope">
<xsl:text>static </xsl:text>
</xsl:if>
<xsl:if test="@visibility='public'">
<xsl:text>public </xsl:text>
</xsl:if>
<xsl:text>function </xsl:text>
<xsl:value-of select="name"/>
<xsl:text>(</xsl:text>
<xsl:for-each select="parameters/*">
<xsl:if test="value">
<xsl:text>?</xsl:text>
</xsl:if>
<xsl:value-of select="name"/>
<xsl:text> : </xsl:text>
<xsl:value-of select="type"/>
<xsl:if test="value">
<xsl:text> = </xsl:text>
<xsl:value-of select="value"/>
</xsl:if>
<xsl:if test="not(position()=last())">
<xsl:text>, </xsl:text>
</xsl:if>
</xsl:for-each>
<xsl:text>)</xsl:text>
<xsl:if test="type">
<xsl:text> : </xsl:text>
<xsl:value-of select="type"/>
</xsl:if>
<xsl:choose>
<xsl:when test="../../@abstract">
<xsl:text>;

</xsl:text>
</xsl:when>
<xsl:otherwise>
<xsl:text> {
</xsl:text>
<xsl:value-of select="$ident"/>
<xsl:text>
</xsl:text>
<xsl:value-of select="$ident"/>
<xsl:text>}

</xsl:text>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="text()">
</xsl:template>
<xsl:template match="node()|@*">
<xsl:apply-templates select="node()|@*"/>
</xsl:template>
</xsl:stylesheet>
|