faust-common 0.9.95~repack1-2 / usr / share / faust / envelope.lib

//################################ envelope.lib ##########################################
// This library contains a collection of envelope generators.
//
// It should be used using the `en` environment:
//
// ```
// en = library("envelope.lib");
// process = en.functionCall;
// ```
//
// Another option is to import `stdfaust.lib` which already contains the `en`
// environment:
//
// ```
// import("stdfaust.lib");
// process = en.functionCall;
// ```
//########################################################################################

/************************************************************************
************************************************************************
FAUST library file
Copyright (C) 2003-2016 GRAME, Centre National de Creation Musicale
----------------------------------------------------------------------
This program is free software; you can redistribute it and/or modify
it under the terms of the GNU Lesser General Public License as
published by the Free Software Foundation; either version 2.1 of the
License, or (at your option) any later version.

This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
GNU Lesser General Public License for more details.

You should have received a copy of the GNU Lesser General Public
License along with the GNU C Library; if not, write to the Free
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
02111-1307 USA.

EXCEPTION TO THE LGPL LICENSE : As a special exception, you may create a
larger FAUST program which directly or indirectly imports this library
file and still distribute the compiled code generated by the FAUST
compiler, or a modified version of this compiled code, under your own
copyright and license. This EXCEPTION TO THE LGPL LICENSE explicitly
grants you the right to freely choose the license for the resulting
compiled code. In particular the resulting compiled code has no obligation
to be LGPL or GPL. For example you are free to choose a commercial or
closed source license or any other license if you decide so.
************************************************************************
************************************************************************/

declare name "Faust Envelope Library";
declare version "0.0";
declare author "GRAME";
declare copyright "GRAME";
declare license "LGPL with exception";

ma = library("math.lib");
ba = library("basic.lib");
si = library("signal.lib");

//=============================Functions Reference========================================
//========================================================================================

//------------------------`smoothEnvelope`------------------------
// An envelope with an exponential attack and release.
// `smoothEnvelope` is a standard Faust function.
//
// #### Usage
//
// ```
// smoothEnvelope(ar,t) : _
// ```
//
// * `ar`: attack and release duration (s)
// * `t`: trigger signal (0-1)
//----------------------------------------------------------------
smoothEnvelope(ar,t) = t : si.smooth(ba.tau2pole(ar));

//-----------------------`ar`--------------------------
// AR (Attack, Release) envelope generator (useful to create percussion envelopes).
// `ar` is a standard Faust function.
//
// #### Usage
// 
// ```
// ar(a,r,t) : _
// ```
//
// Where:
//
// * `a`: attack (sec)
// * `r`: release (sec)
// * `t`: trigger signal (0 or 1)
//-----------------------------------------------------
ar(a,r,t) = ba.countup(attTime+relTime,on) : ba.bpf.start(0,0) : 
	ba.bpf.point(attTime,1) : ba.bpf.end(attTime+relTime,0)
with{
	on = (t-t')==1;
	attTime = ma.SR*a;
	relTime = ma.SR*r;
};


//------------------------`asr`----------------------
// ASR (Attack, Sustain, Release) envelope generator.
// `asr` is a standard Faust function.
//
// #### Usage
//
// ```
// asr(a,s,r,t) : _
// ```
//
// Where:
//
// * `a`, `s`, `r`: attack (sec), sustain (percentage of t), release (sec)
// * `t`: trigger signal ( >0 for attack, then release is when t back to 0)
//-----------------------------------------------------
// TODO: author RM
asr(a,s,r,t) = on*(as) : ba.sAndH(on) : rel
with{
	on = t>0;
	off = t==0;
	attTime = ma.SR*a;
	relTime = ma.SR*r;
	sustainGain = t*s*0.01;
	as = ba.countup(attTime,off) : ba.bpf.start(0,0) : 
		ba.bpf.end(attTime,sustainGain);
	rel = _,ba.countup(relTime,on) : ba.bpf.start(0) : ba.bpf.end(relTime,0);
};


//------------------------`adsr`----------------------
// ADSR (Attack, Decay, Sustain, Release) envelope generator.
// `adsr` is a standard Faust function.
//
// #### Usage
//
// ```
// adsr(a,d,s,r,t) : _
// ```
//
// Where:
//
// * `a`, `d`, `s`, `r`: attack (sec), decay (sec), sustain (percentage of t), release (sec)
// * `t`: trigger signal ( >0 for attack, then release is when t back to 0)
//-----------------------------------------------------
// TODO: author RM
adsr(a,d,s,r,t) = on*(ads) : ba.sAndH(on) : rel
with{
	on = t>0;
	off = t==0;
	attTime = ma.SR*a;
	decTime = ma.SR*d;
	relTime = ma.SR*r;
	sustainGain = t*s*0.01;
	ads = ba.countup(attTime+decTime,off) : ba.bpf.start(0,0) : 
		ba.bpf.point(attTime,1) : ba.bpf.end(attTime+decTime,sustainGain);
	rel = _,ba.countup(relTime,on) : ba.bpf.start(0) : ba.bpf.end(relTime,0);
};

// Old version of ADSR (originally from music.lib)...
/*
adsr(a,d,s,r,t) = env ~ (_,_) : (!,_) // the 2 'state' signals are fed back
with {
    env (p2,y) =
        (t>0) & (p2|(y>=1)),          // p2 = decay-sustain phase
        (y + p1*u - (p2&(y>s))*v*y - p3*w*y)	// y  = envelop signal
	*((p3==0)|(y>=eps)) // cut off tails to prevent denormals
    with {
		p1 = (p2==0) & (t>0) & (y<1);         // p1 = attack phase
		p3 = (t<=0) & (y>0);                  // p3 = release phase
		// #samples in attack, decay, release, must be >0
		na = ma.SR*a+(a==0.0); nd = ma.SR*d+(d==0.0); nr = ma.SR*r+(r==0.0);
		// correct zero sustain level
		z = s+(s==0.0)*ba.db2linear(-60);
		// attack, decay and (-60dB) release rates
		u = 1/na; v = 1-pow(z, 1/nd); w = 1-1/pow(z*ba.db2linear(60), 1/nr);
		// values below this threshold are considered zero in the release phase
		eps = ba.db2linear(-120);
    };
};
*/

////////////////////////////////////////////////////////
// UNDOCUMENTED/DISMISSED ELEMENTS 
////////////////////////////////////////////////////////