/usr/share/gettext-lint/report.xsl is in gettext-lint 0.4-2.1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 | <?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns="http://www.w3.org/1999/xhtml">
<xsl:output method="xml" media-type="text/html"
doctype-system="http://www.w3.org/TR/xhtml11/DTD/xhtml11.dtd"
doctype-public="-//W3C//DTD XHTML 1.1//EN"/>
<xsl:param name="css"/>
<xsl:param name="basefileurl"/>
<xsl:template match="/">
<xsl:apply-templates select="*"/>
</xsl:template>
<!-- html structure -->
<xsl:template match="report|po-file-status|po-file-checker|pot-file-checker|po-file-spell|po-file-spell-overview|po-file-consistency|po-file-equiv">
<html>
<head>
<title><xsl:apply-templates select="current()" mode="title"/></title>
<xsl:if test="string-length($css) > 0">
<link rel="stylesheet" type="text/css" href="{$css}"/>
</xsl:if>
</head>
<body>
<xsl:apply-templates select="current()" mode="body"/>
</body>
</html>
</xsl:template>
<!-- meta report -->
<xsl:template match="report" mode="title">
<xsl:text>Report</xsl:text>
</xsl:template>
<xsl:template match="report" mode="body">
<xsl:apply-templates select="*" mode="body"/>
</xsl:template>
<!-- po file status -->
<xsl:template match="po-file-status" mode="title">
<xsl:text>PO File Status Report</xsl:text>
</xsl:template>
<xsl:template match="po-file-status" mode="body">
<h1><xsl:apply-templates select="current()" mode="title"/></h1>
<xsl:variable name="p" select="file[@untranslated or @fuzzy or error or @not-found or @obsolete]"/>
<p>
<em>
<xsl:call-template name="problems">
<xsl:with-param name="c" select="count($p)"/>
</xsl:call-template>
</em>
</p>
<xsl:if test="count($p)">
<table>
<tr>
<td>file</td>
<td>fuzzy</td>
<td>untranslated</td>
</tr>
<xsl:apply-templates select="$p" mode="status">
<xsl:sort select="@name"/>
</xsl:apply-templates>
</table>
</xsl:if>
</xsl:template>
<xsl:template match="file[error]" mode="status">
<tr>
<td><xsl:apply-templates select="current()" mode="link"/></td>
<td span="2"><xsl:value-of select="error"/></td>
</tr>
</xsl:template>
<xsl:template match="file[@obsolete = 'true']" mode="status">
<tr>
<td><xsl:apply-templates select="current()" mode="link"/></td>
<td span="2">obsolete</td>
</tr>
</xsl:template>
<xsl:template match="file[@not-found = 'true']" mode="status">
<tr>
<td><xsl:apply-templates select="current()" mode="link"/></td>
<td span="2">totally untranslated</td>
</tr>
</xsl:template>
<xsl:template match="file" mode="status">
<tr>
<td><xsl:apply-templates select="current()" mode="link"/></td>
<td><xsl:value-of select="@fuzzy"/></td>
<td><xsl:value-of select="@untranslated"/></td>
</tr>
</xsl:template>
<!-- po file checker -->
<xsl:template match="po-file-checker" mode="title">
<xsl:text>PO File Checker Report</xsl:text>
</xsl:template>
<xsl:template match="po-file-checker" mode="body">
<h1><xsl:apply-templates select="current()" mode="title"/></h1>
<em>
<xsl:call-template name="problems">
<xsl:with-param name="c" select="count(file/error)"/>
</xsl:call-template>
</em>
<xsl:if test="file">
<table>
<tr>
<td>file</td>
<td>message</td>
<td>line</td>
<td>problem</td>
</tr>
<xsl:apply-templates select="file" mode="checker"/>
</table>
</xsl:if>
</xsl:template>
<!-- pot file checker -->
<xsl:template match="pot-file-checker" mode="title">
<xsl:text>POT File Checker Report</xsl:text>
</xsl:template>
<xsl:template match="pot-file-checker" mode="body">
<h1><xsl:apply-templates select="current()" mode="title"/></h1>
<em>
<xsl:call-template name="problems">
<xsl:with-param name="c" select="count(file/error)"/>
</xsl:call-template>
</em>
<xsl:if test="file">
<table>
<tr>
<td>file</td>
<td>message</td>
<td>line</td>
<td>problem</td>
</tr>
<xsl:apply-templates select="file" mode="checker"/>
</table>
</xsl:if>
</xsl:template>
<!-- po/pot checker common code -->
<xsl:template match="file" mode="checker">
<tr>
<td rowspan="{count(error)}"><xsl:value-of select="@name"/></td>
<xsl:apply-templates select="error[position() = 1]" mode="checker"/>
</tr>
<xsl:for-each select="error[position() > 1]">
<tr>
<xsl:apply-templates select="current()" mode="checker"/>
</tr>
</xsl:for-each>
</xsl:template>
<xsl:template match="error" mode="checker">
<td><xsl:value-of select="@message"/></td>
<td><xsl:value-of select="@line"/></td>
<td><xsl:value-of select="current()"/></td>
</xsl:template>
<!-- po file spell -->
<xsl:template match="po-file-spell" mode="title">
<xsl:text>PO File Spell Report</xsl:text>
</xsl:template>
<xsl:template match="po-file-spell" mode="body">
<h1><xsl:apply-templates select="current()" mode="title"/></h1>
<em>
<xsl:call-template name="problems">
<xsl:with-param name="c" select="count(file/error)"/>
</xsl:call-template>
</em>
<xsl:if test="file">
<table>
<tr>
<td>file</td>
<td>errors</td>
</tr>
<xsl:apply-templates select="file" mode="spell"/>
</table>
</xsl:if>
</xsl:template>
<xsl:template match="file" mode="spell">
<tr>
<td><xsl:apply-templates select="current()" mode="link"/></td>
<td><xsl:apply-templates select="error" mode="spell"/></td>
</tr>
</xsl:template>
<xsl:template match="error" mode="spell">
<xsl:value-of select="current()"/><xsl:text> </xsl:text>
</xsl:template>
<!-- po file spell overview -->
<xsl:template match="po-file-spell-overview" mode="title">
<xsl:text>PO File Spell Overview Report</xsl:text>
</xsl:template>
<xsl:template match="po-file-spell-overview" mode="body">
<h1><xsl:apply-templates select="current()" mode="title"/></h1>
<em>
<xsl:call-template name="problems">
<xsl:with-param name="c" select="count(error)"/>
</xsl:call-template>
</em>
<xsl:if test="error">
<table>
<tr>
<td>number of files</td>
<td>error</td>
</tr>
<xsl:apply-templates select="error" mode="spell-overview">
<xsl:sort select="@count" data-type="number" order="descending"/>
</xsl:apply-templates>
</table>
</xsl:if>
</xsl:template>
<xsl:template match="error" mode="spell-overview">
<tr>
<td><xsl:value-of select="@count"/></td>
<td><xsl:value-of select="current()"/></td>
</tr>
</xsl:template>
<!-- po file consistency -->
<xsl:template match="po-file-consistency" mode="title">
<xsl:text>PO File Consistency Report</xsl:text>
</xsl:template>
<xsl:template match="po-file-consistency" mode="body">
<h1><xsl:apply-templates select="current()" mode="title"/></h1>
<em>
<xsl:call-template name="problems">
<xsl:with-param name="c" select="count(inconsistency)"/>
</xsl:call-template>
</em>
<xsl:if test="inconsistency">
<table>
<tr>
<td>msgid</td>
<td>file</td>
<td>msgstr</td>
</tr>
<xsl:apply-templates select="inconsistency"/>
</table>
</xsl:if>
</xsl:template>
<xsl:template match="inconsistency">
<tr>
<td rowspan="{count(msgstr)}"><xsl:value-of select="msgid"/></td>
<xsl:apply-templates select="msgstr[position() = 1]"/>
</tr>
<xsl:for-each select="msgstr[position() > 1]">
<tr>
<xsl:apply-templates select="current()"/>
</tr>
</xsl:for-each>
</xsl:template>
<xsl:template match="msgstr">
<td><xsl:apply-templates select="filename"/></td>
<td><xsl:value-of select="content"/></td>
</xsl:template>
<xsl:template match="filename">
<xsl:choose>
<xsl:when test="string-length($basefileurl) > 0">
<a href="{$basefileurl}{current()}">
<xsl:value-of select="current()"/>
</a>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="current()"/>
</xsl:otherwise>
</xsl:choose>
<xsl:if test="position()!=last()"><br/></xsl:if>
</xsl:template>
<!-- po file equiv -->
<xsl:template match="po-file-equiv" mode="title">
<xsl:text>PO File Glossary</xsl:text>
</xsl:template>
<xsl:template match="po-file-equiv" mode="body">
<h1><xsl:apply-templates select="current()" mode="title"/></h1>
<xsl:if test="entry">
<table>
<tr>
<td>original</td>
<td>translation</td>
</tr>
<xsl:apply-templates select="entry">
<xsl:sort select="original" data-type="text" order="ascending"/>
</xsl:apply-templates>
</table>
</xsl:if>
</xsl:template>
<xsl:template match="entry">
<tr>
<td><xsl:value-of select="original"/></td>
<td>
<xsl:for-each select="translation">
<xsl:value-of select="current()"/>
<xsl:if test="position() != last()">, </xsl:if>
</xsl:for-each>
</td>
</tr>
</xsl:template>
<!-- utility templates -->
<xsl:template name="problems">
<xsl:param name="c"/>
<xsl:choose>
<xsl:when test="$c > 1">
<xsl:value-of select="$c"/>
<xsl:text> problems found</xsl:text>
</xsl:when>
<xsl:when test="$c = 1">
<xsl:text>1 problem found</xsl:text>
</xsl:when>
<xsl:otherwise>
<xsl:text>no problems found</xsl:text>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="file" mode="link">
<xsl:choose>
<xsl:when test="string-length($basefileurl) > 0">
<a href="{$basefileurl}{@name}">
<xsl:value-of select="@name"/>
</a>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="@name"/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>
|