/usr/share/gnu-smalltalk/kernel/RecursionLock.st is in gnu-smalltalk-common 3.2.5-1.1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 | "======================================================================
|
| RecursionLock Method Definitions
|
|
======================================================================"
"======================================================================
|
| Copyright 2002 Free Software Foundation, Inc.
| Written by Paolo Bonzini.
|
| This file is part of the GNU Smalltalk class library.
|
| The GNU Smalltalk class library is free software; you can redistribute it
| and/or modify it under the terms of the GNU Lesser General Public License
| as published by the Free Software Foundation; either version 2.1, or (at
| your option) any later version.
|
| The GNU Smalltalk class library is distributed in the hope that it will be
| useful, but WITHOUT ANY WARRANTY; without even the implied warranty of
| MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser
| General Public License for more details.
|
| You should have received a copy of the GNU Lesser General Public License
| along with the GNU Smalltalk class library; see the file COPYING.LIB.
| If not, write to the Free Software Foundation, 59 Temple Place - Suite
| 330, Boston, MA 02110-1301, USA.
|
======================================================================"
Object subclass: RecursionLock [
| owner sema |
<category: 'Language-Processes'>
<comment: nil>
RecursionLock class >> new [
"Answer a new semaphore"
<category: 'instance creation'>
^self basicNew initialize
]
printOn: aStream [
"Print a human-readable represention of the receiver on aStream."
<category: 'printing'>
aStream
nextPutAll: self class name;
nextPut: $(;
print: self name;
nextPut: $:;
nextPutAll: (sema signals = 1 ifTrue: ['free'] ifFalse: ['held']);
nextPut: $)
]
isOwnerProcess [
"Answer whether the receiver is the owner of the lock."
<category: 'accessing'>
^owner == Processor activeProcess
]
name [
"Answer a user-defined name for the lock."
<category: 'accessing'>
^sema name
]
name: aString [
"Set to aString the user-defined name for the lock."
<category: 'accessing'>
sema name: aString
]
waitingProcesses [
"Answer the set of processes that are waiting on the semaphore."
<category: 'accessing'>
^sema asArray
]
wouldBlock [
"Answer whether sending #wait to the receiver would suspend the
active process."
<category: 'accessing'>
^sema wouldBlock and: [owner ~~ Processor activeProcess]
]
critical: aBlock [
"Wait for the receiver to be free, execute aBlock and signal the receiver
again. Return the result of evaluating aBlock."
<category: 'mutual exclusion'>
self isOwnerProcess ifTrue: [^aBlock value].
"Look out for race conditions!"
sema critical: [
[owner := Processor activeProcess.
aBlock value]
ensure: [owner := nil]].
]
initialize [
<category: 'private'>
sema := Semaphore forMutualExclusion
]
]
|