libcatmandu-perl 1.0700-1 / usr / share / perl5 / Catmandu / Fix / Inlineable.pm

This file is indexed.

/usr/share/perl5/Catmandu/Fix/Inlineable.pm is in libcatmandu-perl 1.0700-1.

This file is owned by root:root, with mode 0o644.

The actual contents of the file can be viewed below. 

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
package Catmandu::Fix::Inlineable;

use Catmandu::Sane;

our $VERSION = '1.07';

use Clone qw(clone);
use Moo::Role;
use namespace::clean;

requires 'fix';

sub import {
    my $target = caller;
    my ($pkg, %opts) = @_;

    if (my $sym = $opts{as}) {
        $opts{cache} //= 1;

        my $sub = sub {
            my $data = shift;
            my $fixer;

            state $cache = {};
            if ($opts{cache}) {
                my $key = join('--', @_);
                $fixer = $cache->{$key} ||= do {
                    my $f = $pkg->new(@_);

                    # memoize instance of Fix.pm if it's an emitting fix
                    $f = $f->fixer if $f->can('fixer');
                    $f;
                };
            }

            $fixer ||= $pkg->new(@_);

            if ($opts{clone}) {
                $data = clone($data);
            }

            $fixer->fix($data);
        };
        no strict 'refs';
        *{"${target}::$sym"} = $sub;
    }
}

1;

__END__

=pod

=head1 NAME

Catmandu::Fix::Inlineable - Role for all Catmandu fixes that can be inlined

=head1 SYNOPSIS

    package Catmandu::Fix::my_fix1;

    use Catmandu::Sane;
    use Moo;

    with 'Catmandu::Fix::Inlineable';

    sub fix {
        my ($self, $data) = @_;
        ....FIXER GENERATING CODE....
        $data
    }

    package Catmandu::Fix::my_fix2;

    use Catmandu::Sane;
    use Moo;

    # Catmandu::Fix::Base automatically is Inlineable
    with 'Catmandu::Fix::Base';

    sub emit {
        my ($self, $fixer) = @_;
        ....FIXER GENERATING CODE....
    }

    package main;

    use Catmandu::Fix::my_fix1 as => 'my_fix1';
    # disabling caching may be desirable with fixes that have side effects like
    # writing to a file, the downside is that a new instance of the fix will be
    # created with each invocation
    use Catmandu::Fix::my_fix2 as => 'my_fix2', cache => 0;

    my $data = {};

    $data = my_fix1($data);
    $data = my_fix2($data);

=head1 SEE ALSO

For more information how to create fixes read the following two blog posts:

http://librecat.org/catmandu/2014/03/14/create-a-fixer.html
http://librecat.org/catmandu/2014/03/26/creating-a-fixer-2.html

=cut

APT Browse - Built by Thomas Orozco.