/usr/share/perl5/Furl/Headers.pm is in libfurl-perl 3.13-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 | package Furl::Headers;
use strict;
use warnings;
use utf8;
use Carp ();
sub new {
my ($class, $headers) = @_; # $headers is HashRef or ArrayRef
my $self = {};
if (ref $headers eq 'ARRAY') {
my @h = @$headers; # copy
while (my ($k, $v) = splice @h, 0, 2) {
push @{$self->{lc $k}}, $v;
}
}
elsif(ref $headers eq 'HASH') {
while (my ($k, $v) = each %$headers) {
push @{$self->{$k}}, ref($v) eq 'ARRAY' ? @$v : $v;
}
}
else {
Carp::confess($class . ': $headers must be an ARRAY or HASH reference');
}
bless $self, $class;
}
sub header {
my ($self, $key, $new) = @_;
if ($new) { # setter
$new = [$new] unless ref $new;
$self->{lc $key} = $new;
return;
} else {
my $val = $self->{lc $key};
return unless $val;
return wantarray ? @$val : join(", ", @$val);
}
}
sub remove_header {
my ($self, $key) = @_;
delete $self->{lc $key};
}
sub flatten {
my $self = shift;
my @ret;
while (my ($k, $v) = each %$self) {
for my $e (@$v) {
push @ret, $k, $e;
}
}
return @ret;
}
sub keys :method {
my $self = shift;
keys %$self;
}
sub header_field_names { shift->keys }
sub as_string {
my $self = shift;
my $ret = '';
for my $k (sort keys %$self) {
for my $e (@{$self->{$k}}) {
$ret .= "$k: $e\015\012";
}
}
return $ret;
}
sub as_http_headers {
my ($self, $key) = @_;
require HTTP::Headers;
return HTTP::Headers->new($self->flatten);
}
# shortcut for popular headers.
sub referer { [ shift->header( 'Referer' => @_ ) ]->[0] }
sub expires { [ shift->header( 'Expires' => @_ ) ]->[0] }
sub last_modified { [ shift->header( 'Last-Modified' => @_ ) ]->[0] }
sub if_modified_since { [ shift->header( 'If-Modified-Since' => @_ ) ]->[0] }
sub content_type { [ shift->header( 'Content-Type' => @_ ) ]->[0] }
sub content_length { [ shift->header( 'Content-Length' => @_ ) ]->[0] }
sub content_encoding { [ shift->header( 'Content-Encoding' => @_ ) ]->[0] }
sub clone {
require Storable;
Storable::dclone($_[0]);
}
1;
__END__
=head1 NAME
Furl::Headers - HTTP Headers object
=head1 SYNOPSIS
=head1 CONSTRUCTOR
=over 4
=item my $headers = Furl::Headers->new(\%headers);
The constructor takes one argument. It is a hashref.
Every key of hashref must be lower-cased.
The format of the argument is like following:
+{
'content-length' => [30],
'set-cookies' => ['auth_token=; path=/; expires=Thu, 01 Jan 1970 00:00:00 GMT', '_twitter_sess=JKLJBNBLKSFJBLKSJBLKSJLKJFLSDJFjkDKFUFIOSDUFSDVjOTUzNzUwNTE2%250AZWFiMWRiNDZhMDcwOWEwMWQ5IgpmbGFzaElDOidBY3Rpb25Db250cm9sbGVy%250AOjpGbGFzaDo6Rmxhc2hIYXNoewAGOgpAdXNlZHsA--d9ce07496a22525bc178jlkhafklsdjflajfl411; domain=.twitter.com; path=/'],
}
=back
=head1 INSTANCE METHODS
=over 4
=item my @values = $headers->header($key);
Get the header value in array.
=item my $values_joined = $headers->header($key);
Get the header value in scalar. This is not a first value of header. This is same as:
my $values = join(", ", $headers->header($key))
=item $headers->header($key, $val);
=item $headers->header($key, \@val);
Set the new value of headers.
=item $headers->remove_header($key);
Delete key from headers.
=item my @h = $headers->flatten();
Gets pairs of keys and values.
=item my @keys = $headers->keys();
=item my @keys = $headers->header_field_names();
Returns keys of headers in array. The return value do not contains duplicated value.
=item my $str = $headers->as_string();
Return the header fields as a formatted MIME header.
=item my $val = $headers->referer()
=item my $val = $headers->expires()
=item my $val = $headers->last_modified()
=item my $val = $headers->if_modified_since()
=item my $val = $headers->content_type()
=item my $val = $headers->content_length()
=item my $val = $headers->content_encoding()
These methods are shortcut for popular headers.
=item $headers->clone();
Returns a copy of this "Furl::Headers" object.
=back
=head1 SEE ALSO
L<HTTP::Headers>
=cut
|