/usr/share/perl5/PPI/Token/Number/Version.pm is in libppi-perl 1.236-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 | package PPI::Token::Number::Version;
=pod
=head1 NAME
PPI::Token::Number::Version - Token class for a byte-packed number
=head1 SYNOPSIS
$n = 1.1.0;
$n = 127.0.0.1;
$n = 10_000.10_000.10_000;
$n = v1.2.3.4
=head1 INHERITANCE
PPI::Token::Number::Version
isa PPI::Token::Number
isa PPI::Token
isa PPI::Element
=head1 DESCRIPTION
The C<PPI::Token::Number::Version> class is used for tokens that have
multiple decimal points. In truth, these aren't treated like numbers
at all by Perl, but they look like numbers to a parser.
=head1 METHODS
=cut
use strict;
use PPI::Token::Number ();
use vars qw{$VERSION @ISA};
BEGIN {
$VERSION = '1.236';
@ISA = 'PPI::Token::Number';
}
=pod
=head2 base
Returns the base for the number: 256.
=cut
sub base() { 256 }
=pod
=head2 literal
Return the numeric value of this token.
=cut
sub literal {
my $self = shift;
my $content = $self->{content};
$content =~ s/^v//;
return join '', map { chr $_ } ( split /\./, $content );
}
#####################################################################
# Tokenizer Methods
sub __TOKENIZER__on_char {
my $class = shift;
my $t = shift;
my $char = substr( $t->{line}, $t->{line_cursor}, 1 );
# Allow digits
return 1 if $char =~ /\d/o;
# Is this a second decimal point in a row? Then the '..' operator
if ( $char eq '.' ) {
if ( $t->{token}->{content} =~ /\.$/ ) {
# We have a .., which is an operator.
# Take the . off the end of the token..
# and finish it, then make the .. operator.
chop $t->{token}->{content};
$t->{class} = $t->{token}->set_class( 'Number::Float' );
$t->_new_token('Operator', '..');
return 0;
} else {
return 1;
}
}
# Doesn't fit a special case, or is after the end of the token
# End of token.
$t->_finalize_token->__TOKENIZER__on_char( $t );
}
sub __TOKENIZER__commit {
my $t = $_[1];
# Capture the rest of the token
pos $t->{line} = $t->{line_cursor};
if ( $t->{line} !~ m/\G(v\d+(?:\.\d+)+|v\d+\b)/gc ) {
# This was not a v-string after all (it's a word)
return PPI::Token::Word->__TOKENIZER__commit($t);
}
my $content = $1;
# If there are no periods this could be a word starting with v\d
# Forced to be a word. Done.
return PPI::Token::Word->__TOKENIZER__commit($t)
if $content !~ /\./ and $t->__current_token_is_forced_word($content);
# This is a v-string
$t->{line_cursor} += length $content;
$t->_new_token( 'Number::Version', $content );
$t->_finalize_token->__TOKENIZER__on_char($t);
}
1;
=pod
=head1 BUGS
- Does not handle leading minus sign correctly. Should translate to a DashedWord.
See L<http://perlmonks.org/?node_id=574573>
-95.0.1.0 --> "-_\000\cA\000"
-96.0.1.0 --> Argument "`\0^A\0" isn't numeric in negation (-)
=head1 SUPPORT
See the L<support section|PPI/SUPPORT> in the main module.
=head1 AUTHOR
Chris Dolan E<lt>cdolan@cpan.orgE<gt>
=head1 COPYRIGHT
Copyright 2006 Chris Dolan.
This program is free software; you can redistribute
it and/or modify it under the same terms as Perl itself.
The full text of the license can be found in the
LICENSE file included with this module.
=cut
|