/usr/share/perl5/SQL/Translator/Generator/Role/Quote.pm is in libsql-translator-perl 0.11024-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 | package SQL::Translator::Generator::Role::Quote;
use Moo::Role;
=head1 NAME
SQL::Translator::Generator::Role::Quote - Role for dealing with identifier
quoting.
=head1 DESCRIPTION
I<documentation volunteers needed>
=cut
requires qw(quote_chars name_sep);
has escape_char => (
is => 'ro',
lazy => 1,
clearer => 1,
default => sub { $_[0]->quote_chars->[-1] },
);
sub quote {
my ($self, $label) = @_;
return '' unless defined $label;
return $$label if ref($label) eq 'SCALAR';
my @quote_chars = @{$self->quote_chars};
return $label unless scalar @quote_chars;
my ($l, $r);
if (@quote_chars == 1) {
($l, $r) = (@quote_chars) x 2;
} elsif (@quote_chars == 2) {
($l, $r) = @quote_chars;
} else {
die 'too many quote chars!';
}
my $sep = $self->name_sep || '';
my $esc = $self->escape_char;
# parts containing * are naturally unquoted
join $sep, map { (my $n = $_) =~ s/\Q$r/$esc$r/g; "$l$n$r" } ( $sep ? split (/\Q$sep\E/, $label ) : $label )
}
sub quote_string {
my ($self, $string) = @_;
return $string unless defined $string;
$string =~ s/'/''/g;
return qq{'$string'};
}
1;
=head1 AUTHORS
See the included AUTHORS file:
L<http://search.cpan.org/dist/SQL-Translator/AUTHORS>
=head1 COPYRIGHT
Copyright (c) 2012 the SQL::Translator L</AUTHORS> as listed above.
=head1 LICENSE
This code is free software and may be distributed under the same terms as Perl
itself.
=cut
|