/usr/share/ada/adainclude/aws/aws-containers-tables.ads is in libaws3.3.2.2-dev 17.2.2017-2.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 | ------------------------------------------------------------------------------
-- Ada Web Server --
-- --
-- Copyright (C) 2000-2017, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or modify --
-- it under terms of the GNU General Public License as published by the --
-- Free Software Foundation; either version 3, or (at your option) any --
-- later version. This library is distributed in the hope that it will be --
-- useful, but WITHOUT ANY WARRANTY; without even the implied warranty of --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. --
-- --
-- --
-- --
-- --
-- --
-- You should have received a copy of the GNU General Public License and --
-- a copy of the GCC Runtime Library Exception along with this program; --
-- see the files COPYING3 and COPYING.RUNTIME respectively. If not, see --
-- <http://www.gnu.org/licenses/>. --
-- --
-- --
-- --
-- --
-- --
-- --
-- --
------------------------------------------------------------------------------
pragma Ada_2012;
with Ada.Strings.Unbounded;
private with Ada.Containers.Indefinite_Ordered_Maps;
private with Ada.Containers.Indefinite_Vectors;
private with Ada.Containers.Vectors;
package AWS.Containers.Tables is
use Ada.Strings.Unbounded;
type Table_Type is tagged private;
Empty_Table : constant Table_Type;
type Element (Name_Length, Value_Length : Natural) is record
Name : String (1 .. Name_Length);
Value : String (1 .. Value_Length);
end record;
-- Data type to store name/value pair retrieved from a Table_Type
Null_Element : constant Element;
type VString_Array is array (Positive range <>) of Unbounded_String;
function Count (Table : Table_Type) return Natural;
-- Returns the number of items in Table
function Is_Empty (Table : Table_Type) return Boolean;
-- Returns true if table is empty
function Name_Count (Table : Table_Type) return Natural;
-- Returns the number of unique key name in Table
function Case_Sensitive (Table : Table_Type) return Boolean with Inline;
-- Returns case sensitivity flag of the Table
function Count (Table : Table_Type; Name : String) return Natural;
-- Returns the number of value for Key Name in Table. It returns
-- 0 if Key does not exist.
function Exist (Table : Table_Type; Name : String) return Boolean;
-- Returns True if Key exist in Table
function Get
(Table : Table_Type;
Name : String;
N : Positive := 1) return String
with Post => (if N > Count (Table, Name) then Get'Result'Length = 0);
-- Returns the Nth value associated with Key into Table. Returns
-- the emptry string if key does not exist.
function Get_Name
(Table : Table_Type; N : Positive := 1) return String
with Post => (if N > Count (Table) then Get_Name'Result'Length = 0);
-- Returns the Nth Name in Table or the empty string if there is
-- no parameter with this number.
function Get_Value
(Table : Table_Type; N : Positive := 1) return String
with Post => (if N > Count (Table) then Get_Value'Result'Length = 0);
-- Returns the Nth Value in Table or the empty string if there is
-- no parameter with this number.
function Get (Table : Table_Type; N : Positive) return Element with
Post => (if N > Count (Table) then Get'Result = Null_Element);
-- Returns N'th name/value pair. Returns Null_Element if there is no
-- such item in the table.
function Get_Names (Table : Table_Type) return VString_Array
with Post => Get_Names'Result'Length = Name_Count (Table);
-- Returns sorted array of unique key names
function Get_Values
(Table : Table_Type; Name : String) return VString_Array
with Post => Get_Values'Result'Length = Count (Table, Name);
-- Returns all values for the specified parameter key name
generic
with procedure Process (Name, Value : String);
procedure Generic_Iterate_Names
(Table : Table_Type; Separator : String);
-- Iterates over all names in the table.
-- All Values of the same name are separated by Separator string.
procedure Iterate_Names
(Table : Table_Type;
Separator : String;
Process : not null access procedure (Name, Value : String));
function Union
(Left : Table_Type;
Right : Table_Type;
Unique : Boolean) return Table_Type;
-- Concatenates two tables, If Unique is True do not add Right container
-- element into result when element with the same name already exists in
-- the Left container.
procedure Add
(Table : in out Table_Type;
Name, Value : String)
with Post => Count (Table) = Count (Table'Old) + 1
or else
Count (Table, Name) = Count (Table'Old, Name) + 1;
-- Add a new Key/Value pair into Table. A new value is always added,
-- even if there is already an entry with the same name.
procedure Update
(Table : in out Table_Type;
Name : String;
Value : String;
N : Positive := 1)
with
Pre =>
-- Count + 1 means it is added at the end of the table
N <= Count (Table, Name) + 1,
Post =>
-- Value already exists, it is updated
(N <= Count (Table'Old, Name)
and then Count (Table, Name) = Count (Table'Old, Name))
-- New value appended
or else
(N = Count (Table'Old, Name) + 1
and then N = Count (Table, Name));
-- Update the N-th Value with the given Name into the Table.
-- The container could already have more than one value associated with
-- this name.
procedure Case_Sensitive
(Table : in out Table_Type;
Mode : Boolean);
-- If Mode is True it will use all parameters with case sensitivity
procedure Reset (Table : in out Table_Type) with
Post => Count (Table) = 0;
-- Removes all object from Table. Table will be reinitialized and will be
-- ready for new use.
private
Null_Element : constant Element := (0, 0, "", "");
type Key_Positive is new Positive;
package Name_Indexes is
new Ada.Containers.Vectors (Positive, Key_Positive);
subtype Name_Index_Table is Name_Indexes.Vector;
package Data_Table is
new Ada.Containers.Indefinite_Vectors (Key_Positive, Element);
package Index_Table is new Ada.Containers.Indefinite_Ordered_Maps
(String, Name_Index_Table, "<", Name_Indexes."=");
-- Index of the Element_Array
subtype Index_Table_Type is Index_Table.Map;
type Table_Type is tagged record
Case_Sensitive : Boolean := True;
Index : Index_Table.Map;
-- Index to find appropriate Name/Value pairs in Data by the name
Data : Data_Table.Vector;
-- Ordered array of name and value pairs
end record;
Empty_Table : constant Table_Type :=
(True, Index_Table.Empty_Map, Data_Table.Empty_Vector);
function Normalize_Name
(Name : String; To_Upper : Boolean) return String;
-- Returns Name in upper case if To_Upper is set to True and it returns
-- Name unchanged otherwise.
end AWS.Containers.Tables;
|