/usr/lib/gcc/x86_64-linux-gnu/5/include/d/gc/pooltable.d is in libphobos-5-dev 5.5.0-12ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 | /**
* A sorted array to quickly lookup pools.
*
* Copyright: Copyright Digital Mars 2001 -.
* License: $(WEB www.boost.org/LICENSE_1_0.txt, Boost License 1.0).
* Authors: Walter Bright, David Friedman, Sean Kelly, Martin Nowak
*/
module gc.pooltable;
static import cstdlib=core.stdc.stdlib;
struct PoolTable(Pool)
{
import core.stdc.string : memmove;
nothrow:
void Dtor()
{
cstdlib.free(pools);
pools = null;
npools = 0;
}
bool insert(Pool* pool)
{
auto newpools = cast(Pool **)cstdlib.realloc(pools, (npools + 1) * pools[0].sizeof);
if (!newpools)
return false;
pools = newpools;
// Sort pool into newpooltable[]
size_t i;
for (; i < npools; ++i)
{
if (pool.baseAddr < pools[i].baseAddr)
break;
}
if (i != npools)
memmove(pools + i + 1, pools + i, (npools - i) * pools[0].sizeof);
pools[i] = pool;
++npools;
_minAddr = pools[0].baseAddr;
_maxAddr = pools[npools - 1].topAddr;
return true;
}
@property size_t length() pure const
{
return npools;
}
ref inout(Pool*) opIndex(size_t idx) inout pure
in { assert(idx < length); }
body
{
return pools[idx];
}
inout(Pool*)[] opSlice(size_t a, size_t b) inout pure
in { assert(a <= length && b <= length); }
body
{
return pools[a .. b];
}
alias opDollar = length;
/**
* Find Pool that pointer is in.
* Return null if not in a Pool.
* Assume pooltable[] is sorted.
*/
Pool *findPool(void *p) nothrow
{
if (p >= minAddr && p < maxAddr)
{
assert(npools);
// let dmd allocate a register for this.pools
auto pools = this.pools;
if (npools == 1)
return pools[0];
/* The pooltable[] is sorted by address, so do a binary search
*/
size_t low = 0;
size_t high = npools - 1;
while (low <= high)
{
size_t mid = (low + high) >> 1;
auto pool = pools[mid];
if (p < pool.baseAddr)
high = mid - 1;
else if (p >= pool.topAddr)
low = mid + 1;
else
return pool;
}
}
return null;
}
// semi-stable partition, returns right half for which pred is false
Pool*[] minimize() pure
{
static void swap(ref Pool* a, ref Pool* b)
{
auto c = a; a = b; b = c;
}
size_t i;
// find first bad entry
for (; i < npools; ++i)
if (pools[i].isFree) break;
// move good in front of bad entries
size_t j = i + 1;
for (; j < npools; ++j)
{
if (!pools[j].isFree) // keep
swap(pools[i++], pools[j]);
}
// npooltable[0 .. i] => used pools
// npooltable[i .. npools] => free pools
if (i)
{
_minAddr = pools[0].baseAddr;
_maxAddr = pools[i - 1].topAddr;
}
else
{
_minAddr = _maxAddr = null;
}
immutable len = npools;
npools = i;
// return freed pools to the caller
return pools[npools .. len];
}
void Invariant() const
{
if (!npools) return;
foreach (i, pool; pools[0 .. npools - 1])
assert(pool.baseAddr < pools[i + 1].baseAddr);
assert(_minAddr == pools[0].baseAddr);
assert(_maxAddr == pools[npools - 1].topAddr);
}
@property const(byte)* minAddr() pure const { return _minAddr; }
@property const(byte)* maxAddr() pure const { return _maxAddr; }
private:
Pool** pools;
size_t npools;
byte* _minAddr, _maxAddr;
}
unittest
{
enum NPOOLS = 6;
enum NPAGES = 10;
enum PAGESIZE = 4096;
static struct MockPool
{
byte* baseAddr, topAddr;
size_t freepages, npages;
@property bool isFree() const pure nothrow { return freepages == npages; }
}
PoolTable!MockPool pooltable;
void reset()
{
foreach(ref pool; pooltable[0 .. $])
pool.freepages = pool.npages;
pooltable.minimize();
assert(pooltable.length == 0);
foreach(i; 0 .. NPOOLS)
{
auto pool = cast(MockPool*)cstdlib.malloc(MockPool.sizeof);
*pool = MockPool.init;
assert(pooltable.insert(pool));
}
}
void usePools()
{
foreach(pool; pooltable[0 .. $])
{
pool.npages = NPAGES;
pool.freepages = NPAGES / 2;
}
}
// all pools are free
reset();
assert(pooltable.length == NPOOLS);
auto freed = pooltable.minimize();
assert(freed.length == NPOOLS);
assert(pooltable.length == 0);
// all pools used
reset();
usePools();
assert(pooltable.length == NPOOLS);
freed = pooltable.minimize();
assert(freed.length == 0);
assert(pooltable.length == NPOOLS);
// preserves order of used pools
reset();
usePools();
{
MockPool*[NPOOLS] opools = pooltable[0 .. NPOOLS];
// make the 2nd pool free
pooltable[2].freepages = NPAGES;
pooltable.minimize();
assert(pooltable.length == NPOOLS - 1);
assert(pooltable[0] == opools[0]);
assert(pooltable[1] == opools[1]);
assert(pooltable[2] == opools[3]);
}
// test that PoolTable reduces min/max address span
reset();
usePools();
byte* base, top;
{
// fill with fake addresses
size_t i;
foreach(pool; pooltable[0 .. NPOOLS])
{
pool.baseAddr = cast(byte*)(i++ * NPAGES * PAGESIZE);
pool.topAddr = pool.baseAddr + NPAGES * PAGESIZE;
}
base = pooltable[0].baseAddr;
top = pooltable[NPOOLS - 1].topAddr;
}
freed = pooltable.minimize();
assert(freed.length == 0);
assert(pooltable.length == NPOOLS);
assert(pooltable.minAddr == base);
assert(pooltable.maxAddr == top);
pooltable[NPOOLS - 1].freepages = NPAGES;
pooltable[NPOOLS - 2].freepages = NPAGES;
freed = pooltable.minimize();
assert(freed.length == 2);
assert(pooltable.length == NPOOLS - 2);
assert(pooltable.minAddr == base);
assert(pooltable.maxAddr == pooltable[NPOOLS - 3].topAddr);
pooltable[0].freepages = NPAGES;
freed = pooltable.minimize();
assert(freed.length == 1);
assert(pooltable.length == NPOOLS - 3);
assert(pooltable.minAddr != base);
assert(pooltable.minAddr == pooltable[0].baseAddr);
assert(pooltable.maxAddr == pooltable[NPOOLS - 4].topAddr);
// free all
foreach(pool; pooltable[0 .. $])
pool.freepages = NPAGES;
freed = pooltable.minimize();
assert(freed.length == NPOOLS - 3);
assert(pooltable.length == 0);
pooltable.Dtor();
}
|