/usr/lib/gcc/x86_64-linux-gnu/5/include/d/std/typelist.d is in libphobos-5-dev 5.5.0-12ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 | // Written in the D programming language.
/**
* This module defines a list of types $(D_PARAM TypeList)
* and operations on $(D_PARAM TypeList)s.
* Together they define a compile-time functional programming framework,
* complete with lambdas, higher-order functions, and arbitrary data structures
*
* Macros:
* WIKI = Phobos/StdTypelist
*
* Synopsis:
*
* ----
* // **** BUG **** problems with mutual recursion
* template Synopsis(T...)
* {
* alias TypeList!(T) list;
*
* template IsPtr(U) {
* static if (is(U foo: V*, V))
* enum IsPtr = true;
* else
* enum IsPtr = false;
* }
* enum arePointers = All!(list, IsPtr);
*
* alias Map!(StripPtr, list) StripPointers;
* }
* static assert(is (Synopsis!(char**, void***).StripPointers.toTuple == TypeTuple!(char, void)));
* ----
*
* Copyright: Copyright Bartosz Milewski 2008- 2009.
* License: $(WEB www.boost.org/LICENSE_1_0.txt, Boost License 1.0).
* Authors: $(WEB bartoszmilewski.wordpress.com, Bartosz Milewski)
* Source: $(PHOBOSSRC std/_typelist.d)
*/
/* Copyright Burton Radons 2008 - 2009.
* Distributed under the Boost Software License, Version 1.0.
* (See accompanying file LICENSE_1_0.txt or copy at
* http://www.boost.org/LICENSE_1_0.txt)
*/
deprecated("Please use std.typecons instead. This module will be removed in March 2015.")
module std.typelist;
version(unittest) {
import std.typetuple;
}
/**
* Creates a compile-time list of types from a tuple.
* $(D TypeList)s are more general than tuples because
* you can pass more than one $(D TypeList) to a template.
* You may also combine them into higher-order structures.
* $(D TypeList)s are passed to other templates as alias parameters
* To create an empty list use $(D TypeList!())
*
* $(D TypeList) efines several "methods":
*
* $(D_PARAM toTuple), $(D_PARAM head), $(D_PARAM tail), $(D_PARAM length), $(D_PARAM isEmpty)
*
* Example:
* ---
* template Filter(alias Pred, alias List)
* {
* static if (List.isEmpty)
* alias TypeList!() Filter;
* else static if (Pred!(List.head))
* alias Cons!(List.head, Filter!(Pred, List.tail)) Filter;
* else
* alias Filter!(Pred, List.tail) Filter;
* }
* ---
*/
template TypeList(T...)
{
alias toTuple = T;
static if(T.length != 0)
{
alias head = T[0];
alias tail = TypeList!(T[1..$]);
enum length = T.length;
enum isEmpty = false;
}
else
{
enum length = 0;
enum isEmpty = true;
}
}
unittest {
static assert (is (TypeList!(void*, int).toTuple == TypeTuple!(void*, int)));
static assert (is (TypeList!(void*, int).head == void*));
static assert (is (TypeList!(void*, int).tail.toTuple == TypeTuple!(int)));
static assert (is (TypeList!(int).tail.toTuple == TypeTuple!()));
static assert (TypeList!(int).tail.isEmpty);
static assert (TypeList!(void*, int).length == 2);
static assert (!TypeList!(void*, int).isEmpty);
static assert (TypeList!().length == 0);
static assert (TypeList!().isEmpty);
}
/**
* Appends a type tuple to a $(D TypeList), returns a $(D TypeList)
*/
template AppendTypes(alias List, T...)
{
static if (List.isEmpty)
alias AppendTypes = TypeList!(T);
else
alias AppendTypes = TypeList!(List.toTuple, T);
}
unittest {
static assert (is (AppendTypes!(TypeList!(void*, int), long, short).toTuple
== TypeTuple!(void*, int, long, short)));
static assert (is (AppendTypes!(TypeList!(void*, int)).toTuple
== TypeTuple!(void*, int)));
static assert (AppendTypes!(TypeList!()).isEmpty);
}
/**
* Appends one $(D TypeList) to another, returns a $(D TypeList)
*/
template Append(alias Left, alias Right)
{
alias Append = AppendTypes!(Left, Right.toTuple);
}
unittest {
static assert (is (Append!(TypeList!(void*, int), TypeList!(long, short)).toTuple
== TypeTuple!(void*, int, long, short)));
static assert (is (Append!(TypeList!(void*, int), TypeList!()).toTuple
== TypeTuple!(void*, int)));
static assert (Append!(TypeList!(), TypeList!()).isEmpty);
}
/**
* Prepends a type to a $(D TypeList), returns a $(D TypeList)
*/
template Cons(T, alias List)
{
static if (List.isEmpty)
alias Cons = TypeList!(T);
else
alias Cons = TypeList!(T, List.toTuple);
}
unittest {
static assert (is (Cons!(long, TypeList!(void*, int)).toTuple
== TypeTuple!(long, void*, int)));
static assert (is (Cons!(long, TypeList!(void*, int)).head
== long));
static assert (is (Cons!(int, TypeList!()).toTuple == TypeTuple!(int)));
static assert (is (Cons!(char[], Cons!(int, TypeList!())).toTuple
== TypeTuple!(char[], int)));
}
/**
* Tests if all emements of a $(D TypeList) against a predicate.
* Returns true if all all types satisfy the predicate, false otherwise.
*/
template All(alias List, alias F)
{
static if (List.isEmpty)
enum All = true;
else
enum All = F!(List.head) && All!(List.tail, F);
}
version(unittest) {
template IsPointer(T)
{
static if (is (T foo: U*, U))
enum IsPointer = true;
else
enum IsPointer = false;
}
}
unittest {
static assert (All!(TypeList!(void*, char*, int**), IsPointer));
static assert (!All!(TypeList!(void*, char*, int), IsPointer));
}
/**
* Tests if there is an emement in a $(D TypeList) that satisfies a predicate.
*/
template Any(alias List, alias F)
{
static if (List.isEmpty)
enum Any = false;
else
enum Any = F!(List.head) || Any!(List.tail, F);
}
unittest {
static assert (Any!(TypeList!(int, char*, int**), IsPointer));
static assert (!Any!(TypeList!(char[], char, int), IsPointer));
}
/**
* Applies a given "function" on types to a type tuple. Returns a tuple of results
*/
template Map(alias F, T...)
{
alias Map = Map!(F, TypeList!(T)).toTuple;
}
/**
* Applies a given "function" to a $(D TypeList). Returns a $(D TypeList) of results
*/
private template Map(alias F, alias List)
{
static if (List.isEmpty)
alias Map = TypeList!();
else
alias Map = Cons!(F!(List.head), Map!(F, List.tail));
}
version(unittest) {
template MakePtr(T)
{
alias MakePtr = T*;
}
}
unittest {
static assert (is (MakePtr!(int) == int*));
static assert (is (Map!(MakePtr, void *, char) == TypeTuple!(void**, char*)));
}
/**
* Filters a type tuple using a predicate.
* Takes a predicate and a tuple and returns another tuple
*/
template Filter(alias Pred, T...)
{
alias Filter = Filter!(Pred, TypeList!(T)).toTuple;
}
/**
* Filters a $(D TypeList) using a predicate. Returns a $(D TypeList) of elements that
* satisfy the predicate.
*/
template Filter(alias Pred, alias List)
{
static if (List.isEmpty)
alias Filter = TypeList!();
else static if (Pred!(List.head))
alias Filter = Cons!(List.head, Filter!(Pred, List.tail));
else
alias Filter = Filter!(Pred, List.tail);
}
unittest {
static assert(is(Filter!(IsPointer, int, void*, char[], int*) == TypeTuple!(void*, int*)));
static assert(is(Filter!(IsPointer) == TypeTuple!()));
}
template FoldRight(alias F, alias Init, alias List)
{
static if (List.isEmpty)
alias FoldRight = Init;
else
alias FoldRight = F!(List.head, FoldRight!(F, Init, List.tail));
}
template FoldRight(alias F, int Init, alias List)
{
static if (List.isEmpty)
alias FoldRight = Init;
else
alias FoldRight = F!(List.head, FoldRight!(F, Init, List.tail));
}
version(unittest) {
template snoC(T, alias List)
{
alias snoC = TypeList!(List.toTuple, T);
}
template Inc(T, int i)
{
enum Inc = i + 1;
}
}
unittest {
// *** Compiler bugs
//static assert (snoC!(int, TypeList!(long)).toTuple == TypeTuple!(long, int));
//static assert (FoldRight!(snoC, TypeList!(), TypeList!(int, long)).toTuple == TypeTuple!(long, int));
static assert (!FoldRight!(snoC, TypeList!(), TypeList!(int)).isEmpty);
static assert (FoldRight!(Inc, 0, TypeList!(int, long)) == 2);
}
/** A list of functions operating on types.
* Used to pass multiple type functions to
* a template.
*
* Example:
* ----
* template Or(alias FList)
* {
* template lambda(X)
* {
* static if (FList.isEmpty)
* enum lambda = true;
* else
* enum lambda = FList.head!(X) || Or!(FList.tail).apply!(X);
* }
* alias lambda apply;
* }
* ----
*/
template TypeFunList()
{
enum length = 0;
enum isEmpty = true;
}
template TypeFunList(alias F)
{
alias head = F;
alias tail = TypeFunList!();
enum length = 1;
enum isEmpty = false;
}
template TypeFunList(alias F, alias Tail)
{
alias head = F;
alias tail = Tail;
enum length = 1 + Tail.length;
enum isEmpty = false;
}
unittest {
static assert (TypeFunList!().isEmpty);
static assert (!TypeFunList!(IsPointer).isEmpty);
static assert (TypeFunList!(IsPointer).tail.isEmpty);
static assert (TypeFunList!(IsPointer).head!(void*));
static assert (TypeFunList!(IsPointer, TypeFunList!(IsPointer)).head!(void *));
static assert (TypeFunList!(IsPointer, TypeFunList!(IsPointer)).tail.head!(void *));
}
/** Negates a type predicate.
* The negated predicate is a "member" $(D apply).
*
* Example:
* ----
* static assert (Not!(IsPointer).apply!(int));
* ----
*/
template Not(alias F)
{
template lambda(X)
{
enum lambda = !F!(X);
}
alias apply = lambda;
}
unittest {
static assert (Not!(IsPointer).apply!(int));
}
/** Combines two type predicates using logical OR.
* The resulting predicate is callable through the field $(D apply)
*
* Example:
* ----
* static assert(Or!(IsPointer, Not!(IsPointer).apply).apply!(int));
* ----
*/
template Or(alias F1, alias F2)
{
template lambda(X)
{
enum lambda = F1!(X) || F2!(X);
}
alias apply = lambda;
}
unittest {
static assert(Or!(IsPointer, IsPointer).apply!(int*));
static assert(Or!(IsPointer, Not!(IsPointer).apply).apply!(int));
}
/** Combines a list of type predicates using logical OR.
* The resulting predicate is callable through the field $(D apply)
*/
template Or(alias FList)
{
template lambda(X)
{
static if (FList.isEmpty)
enum lambda = true;
else
enum lambda = FList.head!(X) || Or!(FList.tail).apply!(X);
}
alias apply = lambda;
}
unittest {
static assert (Or!(
TypeFunList!(IsPointer,
TypeFunList!(Not!(IsPointer).apply)
)).apply!(int*));
}
/** Combines two type predicates using logical AND.
* The resulting predicate is callable through the field $(D apply)
*
* Example:
* ----
* static assert(!And!(IsPointer, Not!(IsPointer).apply).apply!(int));
* ----
*/
template And(alias F1, alias F2)
{
template lambda(X)
{
enum lambda = F1!(X) && F2!(X);
}
alias apply = lambda;
}
unittest {
static assert(And!(IsPointer, IsPointer).apply!(int*));
static assert(!And!(IsPointer, Not!(IsPointer).apply).apply!(int));
}
/** Combines a list of type predicates using logical AND.
* The resulting predicate is callable through the field $(D apply)
*/
template And(alias FList)
{
template lambda(X)
{
static if (FList.isEmpty)
enum lambda = true;
else
enum lambda = FList.head!(X) && And!(FList.tail).apply!(X);
}
alias apply = lambda;
}
unittest {
static assert (!And!(
TypeFunList!(IsPointer,
TypeFunList!(Not!(IsPointer).apply)
)).apply!(int*));
}
|