/usr/share/ada/adainclude/xmlada_dom/dom-core-elements.adb is in libxmlada-dom7-dev 17.1.2017-5.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 | ------------------------------------------------------------------------------
-- XML/Ada - An XML suite for Ada95 --
-- --
-- Copyright (C) 2001-2017, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or modify it --
-- under terms of the GNU General Public License as published by the Free --
-- Software Foundation; either version 3, or (at your option) any later --
-- version. This library is distributed in the hope that it will be useful, --
-- but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHAN- --
-- TABILITY or FITNESS FOR A PARTICULAR PURPOSE. --
-- --
-- --
-- --
-- --
-- --
-- You should have received a copy of the GNU General Public License and --
-- a copy of the GCC Runtime Library Exception along with this program; --
-- see the files COPYING3 and COPYING.RUNTIME respectively. If not, see --
-- <http://www.gnu.org/licenses/>. --
-- --
------------------------------------------------------------------------------
with DOM.Core.Attrs; use DOM.Core.Attrs;
with DOM.Core.Documents; use DOM.Core.Documents;
with Sax.Symbols; use Sax.Symbols;
package body DOM.Core.Elements is
use Nodes_Htable;
-------------------
-- Get_Attribute --
-------------------
function Get_Attribute (Elem : Element; Name : DOM_String)
return DOM_String
is
Att : constant Attr := Get_Named_Item (Elem.Attributes, Name);
begin
if Att /= null then
return Node_Value (Att);
else
return "";
end if;
end Get_Attribute;
----------------------
-- Get_Attribute_NS --
----------------------
function Get_Attribute_NS
(Elem : Element; Namespace_URI : DOM_String; Local_Name : DOM_String)
return DOM_String
is
Att : constant Attr := Get_Named_Item_NS
(Elem.Attributes, Namespace_URI, Local_Name);
begin
if Att /= null then
return Node_Value (Att);
else
return "";
end if;
end Get_Attribute_NS;
-------------------
-- Set_Attribute --
-------------------
procedure Set_Attribute
(Elem : Element; Name : DOM_String; Value : DOM_String)
is
Att : constant Attr := Create_Attribute
(Owner_Document (Elem), Name);
begin
Set_Value (Att, Value);
Set_Named_Item_NS (Elem.Attributes, Att);
end Set_Attribute;
----------------------
-- Set_Attribute_NS --
----------------------
procedure Set_Attribute_NS
(Elem : Element;
Namespace_URI : DOM_String;
Qualified_Name : DOM_String;
Value : DOM_String)
is
Att : constant Attr := Create_Attribute_NS
(Owner_Document (Elem), Namespace_URI, Qualified_Name);
begin
Set_Value (Att, Value);
Set_Named_Item_NS (Elem.Attributes, Att);
end Set_Attribute_NS;
----------------------
-- Remove_Attribute --
----------------------
procedure Remove_Attribute (Elem : Element; Name : DOM_String) is
begin
Remove_Named_Item (Elem.Attributes, Name);
end Remove_Attribute;
-------------------------
-- Remove_Attribute_NS --
-------------------------
procedure Remove_Attribute_NS
(Elem : Element; Namespace_URI : DOM_String; Local_Name : DOM_String) is
begin
Remove_Named_Item_NS (Elem.Attributes, Namespace_URI, Local_Name);
end Remove_Attribute_NS;
------------------------
-- Get_Attribute_Node --
------------------------
function Get_Attribute_Node (Elem : Element; Name : DOM_String)
return Attr is
begin
return Get_Named_Item (Elem.Attributes, Name);
end Get_Attribute_Node;
---------------------------
-- Get_Attribute_Node_Ns --
---------------------------
function Get_Attribute_Node_NS
(Elem : Element; Namespace_URI : DOM_String; Local_Name : DOM_String)
return Attr is
begin
return Get_Named_Item_NS (Elem.Attributes, Namespace_URI, Local_Name);
end Get_Attribute_Node_NS;
------------------------
-- Set_Attribute_Node --
------------------------
function Set_Attribute_Node (Elem : Element; New_Attr : Attr) return Attr is
begin
if Owner_Element (New_Attr) /= null then
raise Inuse_Attribute_Err;
end if;
Set_Named_Item (Elem.Attributes, New_Attr);
New_Attr.Owner_Element := Elem;
return New_Attr;
end Set_Attribute_Node;
---------------------------
-- Set_Attribute_Node_NS --
---------------------------
function Set_Attribute_Node_NS (Elem : Element; New_Attr : Attr)
return Attr is
begin
if Owner_Element (New_Attr) /= null then
raise Inuse_Attribute_Err;
end if;
Set_Named_Item_NS (Elem.Attributes, New_Attr);
New_Attr.Owner_Element := Elem;
return New_Attr;
end Set_Attribute_Node_NS;
---------------------------
-- Remove_Attribute_Node --
---------------------------
function Remove_Attribute_Node (Elem : Element; Old_Attr : Attr)
return Attr is
begin
pragma Assert (Owner_Element (Old_Attr) = Elem);
Remove_Named_Item (Elem.Attributes, Old_Attr);
Old_Attr.Owner_Element := null;
return Old_Attr;
end Remove_Attribute_Node;
------------------------------
-- Remove_Attribute_Node_NS --
------------------------------
function Remove_Attribute_Node_NS (Elem : Element; Old_Attr : Attr)
return Attr renames Remove_Attribute_Node;
------------------------------
-- Get_Elements_By_Tag_Name --
------------------------------
function Get_Elements_By_Tag_Name (Elem : Element; Name : DOM_String := "*")
return Node_List
is
procedure Get_Elements_From_Node (N : Node; List : in out Node_List);
-- Depth search in N or its children/sibling for matching children.
----------------------------
-- Get_Elements_From_Node --
----------------------------
procedure Get_Elements_From_Node (N : Node; List : in out Node_List) is
L : constant Node_List := Child_Nodes (N);
begin
if N.Node_Type = Element_Node
and then (Name = "*" or else Node_Name (N) = Name)
then
Append (List, N);
end if;
for J in 0 .. L.Last loop
Get_Elements_From_Node (L.Items (J), List);
end loop;
end Get_Elements_From_Node;
L : Node_List;
begin
Get_Elements_From_Node (Elem, L);
return L;
end Get_Elements_By_Tag_Name;
---------------------------------
-- Get_Elements_By_Tag_Name_NS --
---------------------------------
function Get_Elements_By_Tag_Name_NS
(Elem : Element;
Namespace_URI : DOM_String := "*";
Local_Name : DOM_String := "*")
return Node_List
is
procedure Get_Elements_From_Node (N : Node; List : in out Node_List);
-- Depth search in N or its children/sibling for matching children.
----------------------------
-- Get_Elements_From_Node --
----------------------------
procedure Get_Elements_From_Node (N : Node; List : in out Node_List) is
L : constant Node_List := Child_Nodes (N);
begin
if N.Node_Type = Element_Node
and then (Namespace_URI = "*"
or else DOM.Core.Nodes.Namespace_URI (N) = Namespace_URI)
and then
(Local_Name = "*"
or else Symbol'(DOM.Core.Nodes.Local_Name (N)) = Local_Name)
then
Append (List, N);
end if;
for J in 0 .. L.Last loop
Get_Elements_From_Node (L.Items (J), List);
end loop;
end Get_Elements_From_Node;
L : Node_List;
begin
Get_Elements_From_Node (Elem, L);
return L;
end Get_Elements_By_Tag_Name_NS;
----------------------
-- Set_Id_Attribute --
----------------------
procedure Set_Id_Attribute
(Elem : Element;
Name : DOM_String;
Is_Id : Boolean)
is
Id_Attr : constant Attr := Get_Attribute_Node (Elem, Name);
begin
if Id_Attr = null then
raise Not_Found_Err;
end if;
Id_Attr.Is_Id := Is_Id;
if Is_Id then
Document_Add_Id
(Owner_Document (Elem), Id => Id_Attr.Attr_Value, Elem => Elem);
else
Document_Remove_Id (Owner_Document (Elem), Id => Id_Attr.Attr_Value);
end if;
end Set_Id_Attribute;
-------------------------
-- Set_Id_Attribute_NS --
-------------------------
procedure Set_Id_Attribute_NS
(Elem : Element;
Namespace_URI : DOM_String;
Local_Name : DOM_String;
Is_Id : Boolean)
is
Id_Attr : constant Attr := Get_Attribute_Node_NS
(Elem, Namespace_URI, Local_Name);
begin
if Id_Attr = null then
raise Not_Found_Err;
end if;
Id_Attr.Is_Id := Is_Id;
if Is_Id then
Document_Add_Id
(Owner_Document (Elem), Id => Id_Attr.Attr_Value, Elem => Elem);
else
Document_Remove_Id (Owner_Document (Elem), Id => Id_Attr.Attr_Value);
end if;
end Set_Id_Attribute_NS;
---------------------------
-- Set_Id_Attribute_Node --
---------------------------
procedure Set_Id_Attribute_Node
(Elem : Element; Id_Attr : Attr; Is_Id : Boolean) is
begin
if Owner_Element (Id_Attr) /= Elem then
raise Not_Found_Err;
end if;
Id_Attr.Is_Id := Is_Id;
if Is_Id then
Document_Add_Id
(Owner_Document (Elem), Id => Id_Attr.Attr_Value, Elem => Elem);
else
Document_Remove_Id (Owner_Document (Elem), Id => Id_Attr.Attr_Value);
end if;
end Set_Id_Attribute_Node;
end DOM.Core.Elements;
|