/usr/share/plasma/plasmoids/org.kde.plasma.userswitcher/contents/ui/main.qml is in plasma-widgets-addons 4:5.12.4-0ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 | /*
* Copyright 2015 Kai Uwe Broulik <kde@privat.broulik.de>
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; either version 2 of the License, or
* (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program; if not, write to the Free Software
* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 2.010-1301, USA.
*/
import QtQuick 2.2
import QtQuick.Controls 1.1 as QtControls
import QtQuick.Layouts 1.1
import QtQuick.Window 2.1
import org.kde.plasma.plasmoid 2.0
import org.kde.plasma.core 2.0 as PlasmaCore
import org.kde.plasma.components 2.0 as PlasmaComponents
import org.kde.plasma.extras 2.0 as PlasmaExtras
import org.kde.kcoreaddons 1.0 as KCoreAddons // kuser
import org.kde.kquickcontrolsaddons 2.0 // kcmshell
import org.kde.plasma.private.sessions 2.0 as Sessions
Item {
id: root
readonly property bool isVertical: plasmoid.formFactor === PlasmaCore.Types.Vertical
readonly property string displayedName: showFullName ? kuser.fullName : kuser.loginName
readonly property bool showFace: plasmoid.configuration.showFace
readonly property bool showName: plasmoid.configuration.showName
readonly property bool showFullName: plasmoid.configuration.showFullName
// TTY number and X display
readonly property bool showTechnicalInfo: plasmoid.configuration.showTechnicalInfo
Plasmoid.switchWidth: units.gridUnit * 10
Plasmoid.switchHeight: units.gridUnit * 12
Plasmoid.toolTipTextFormat: Text.StyledText
Plasmoid.toolTipSubText: i18n("You are logged in as <b>%1</b>", displayedName)
Binding {
target: plasmoid
property: "icon"
value: kuser.faceIconUrl
// revert to the plasmoid icon if no face given
when: kuser.faceIconUrl.toString() !== ""
}
KCoreAddons.KUser {
id: kuser
}
Plasmoid.compactRepresentation: MouseArea {
id: compactRoot
// Taken from DigitalClock to ensure uniform sizing when next to each other
readonly property bool tooSmall: plasmoid.formFactor === PlasmaCore.Types.Horizontal && Math.round(2 * (compactRoot.height / 5)) <= theme.smallestFont.pixelSize
Layout.minimumWidth: isVertical ? 0 : compactRow.implicitWidth
Layout.maximumWidth: isVertical ? Infinity : Layout.minimumWidth
Layout.preferredWidth: isVertical ? undefined : Layout.minimumWidth
Layout.minimumHeight: isVertical ? label.height : theme.smallestFont.pixelSize
Layout.maximumHeight: isVertical ? Layout.minimumHeight : Infinity
Layout.preferredHeight: isVertical ? Layout.minimumHeight : theme.mSize(theme.defaultFont).height * 2
onClicked: plasmoid.expanded = !plasmoid.expanded
Row {
id: compactRow
anchors.centerIn: parent
spacing: units.smallSpacing
PlasmaCore.IconItem {
id: icon
width: height
height: compactRoot.height
Layout.preferredWidth: height
source: visible ? (kuser.faceIconUrl.toString() || "user-identity") : ""
visible: root.showFace
usesPlasmaTheme: false
}
PlasmaComponents.Label {
id: label
text: root.displayedName
height: compactRoot.height
horizontalAlignment: Text.AlignHCenter
verticalAlignment: Text.AlignVCenter
wrapMode: Text.NoWrap
fontSizeMode: Text.VerticalFit
font.pixelSize: tooSmall ? theme.defaultFont.pixelSize : units.roundToIconSize(units.gridUnit * 2)
minimumPointSize: theme.smallestFont.pointSize
visible: root.showName
}
}
}
Plasmoid.fullRepresentation: Item {
id: fullRoot
Layout.preferredWidth: units.gridUnit * 12
Layout.preferredHeight: Math.min(Screen.height * 0.5, column.contentHeight)
PlasmaCore.DataSource {
id: pmEngine
engine: "powermanagement"
connectedSources: ["PowerDevil", "Sleep States"]
function performOperation(what) {
var service = serviceForSource("PowerDevil")
var operation = service.operationDescription(what)
service.startOperationCall(operation)
}
}
Sessions.SessionsModel {
id: sessionsModel
}
PlasmaComponents.Highlight {
id: delegateHighlight
visible: false
z: -1 // otherwise it shows ontop of the icon/label and tints them slightly
}
ColumnLayout {
id: column
// there doesn't seem a more sensible way of getting this due to the expanding ListView
readonly property int contentHeight: currentUserItem.height + userList.contentHeight + units.smallSpacing
+ (newSessionButton.visible ? newSessionButton.height : 0)
+ (lockScreenButton.visible ? lockScreenButton.height : 0)
+ leaveButton.height
anchors.fill: parent
spacing: 0
ListDelegate {
id: currentUserItem
text: root.displayedName
subText: i18n("Current user")
icon: kuser.faceIconUrl.toString() || "user-identity"
interactive: false
interactiveIcon: KCMShell.authorize("user_manager.desktop").length > 0
onIconClicked: KCMShell.open("user_manager")
usesPlasmaTheme: false
}
PlasmaExtras.ScrollArea {
Layout.fillWidth: true
Layout.fillHeight: true
ListView {
id: userList
model: sessionsModel
highlight: PlasmaComponents.Highlight {}
highlightMoveDuration: 0
delegate: ListDelegate {
width: userList.width
text: {
if (!model.session) {
return i18nc("Nobody logged in on that session", "Unused")
}
if (model.realName && root.showFullName) {
return model.realName
}
return model.name
}
icon: model.icon || "user-identity"
subText: {
if (!root.showTechnicalInfo) {
return ""
}
if (model.isTty) {
return i18nc("User logged in on console number", "TTY %1", model.vtNumber)
} else if (model.displayNumber) {
return i18nc("User logged in on console (X display number)", "on %1 (%2)", model.vtNumber, model.displayNumber)
}
return ""
}
onClicked: sessionsModel.switchUser(model.vtNumber, sessionsModel.shouldLock)
onContainsMouseChanged: {
if (containsMouse) {
userList.currentIndex = index
} else {
userList.currentIndex = -1
}
}
usesPlasmaTheme: false
}
}
}
ListDelegate {
id: newSessionButton
text: i18n("New Session")
icon: "system-switch-user"
highlight: delegateHighlight
visible: sessionsModel.canStartNewSession
onClicked: sessionsModel.startNewSession(sessionsModel.shouldLock)
}
ListDelegate {
id: lockScreenButton
text: i18n("Lock Screen")
icon: "system-lock-screen"
highlight: delegateHighlight
enabled: pmEngine.data["Sleep States"]["LockScreen"]
visible: enabled
onClicked: pmEngine.performOperation("lockScreen")
}
ListDelegate {
id: leaveButton
text: i18nc("Show a dialog with options to logout/shutdown/restart", "Leave...")
highlight: delegateHighlight
icon: "system-shutdown"
onClicked: pmEngine.performOperation("requestShutDown")
}
}
Component.onCompleted: {
plasmoid.expandedChanged.connect(function (expanded) {
if (expanded) {
sessionsModel.reload();
}
});
}
}
}
|