/usr/lib/x86_64-linux-gnu/qt5/qml/org/kde/kirigami.2/GlobalDrawer.qml is in qml-module-org-kde-kirigami2 5.44.0-0ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 | /*
* Copyright 2015 Marco Martin <mart@kde.org>
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU Library General Public License as
* published by the Free Software Foundation; either version 2, or
* (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU Library General Public License for more details
*
* You should have received a copy of the GNU Library General Public
* License along with this program; if not, write to the
* Free Software Foundation, Inc.,
* 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
*/
import QtQuick 2.6
import QtQuick.Templates 2.0 as T2
import QtQuick.Layouts 1.2
import QtGraphicalEffects 1.0
import org.kde.kirigami 2.3
import "private"
import "templates/private"
/**
* A drawer specialization intended for the global actions of the application
* valid regardless of the application state (think about the menubar
* of a desktop application).
*
* Example usage:
* @code
* import org.kde.kirigami 2.2 as Kirigami
*
* Kirigami.ApplicationWindow {
* [...]
* globalDrawer: Kirigami.GlobalDrawer {
* actions: [
* Kirigami.Action {
* text: "View"
* iconName: "view-list-icons"
* Kirigami.Action {
* text: "action 1"
* }
* Kirigami.Action {
* text: "action 2"
* }
* Kirigami.Action {
* text: "action 3"
* }
* },
* Kirigami.Action {
* text: "Sync"
* iconName: "folder-sync"
* }
* ]
* }
* [...]
* }
* @endcode
*
*/
OverlayDrawer {
id: root
edge: Qt.application.layoutDirection == Qt.RightToLeft ? Qt.RightEdge : Qt.LeftEdge
/**
* title: string
* A title to be displayed on top of the drawer
*/
property alias title: heading.text
/**
* icon: var
* An icon to be displayed alongside the title.
* It can be a QIcon, a fdo-compatible icon name, or any url understood by Image
*/
property alias titleIcon: headingIcon.source
/**
* bannerImageSource: string
* An image to be used as background for the title and icon for
* a decorative purpose.
* It accepts any url format supported by Image
*/
property alias bannerImageSource: bannerImage.source
/**
* actions: list<Action>
* The list of actions can be nested having a tree structure.
* A tree depth bigger than 2 is discouraged.
*
* Example usage:
* @code
* import org.kde.kirigami 2.2 as Kirigami
*
* Kirigami.ApplicationWindow {
* [...]
* globalDrawer: Kirigami.GlobalDrawer {
* actions: [
* Kirigami.Action {
* text: "View"
* iconName: "view-list-icons"
* Kirigami.Action {
* text: "action 1"
* }
* Kirigami.Action {
* text: "action 2"
* }
* Kirigami.Action {
* text: "action 3"
* }
* },
* Kirigami.Action {
* text: "Sync"
* iconName: "folder-sync"
* }
* ]
* }
* [...]
* }
* @endcode
*/
property list<QtObject> actions
/**
* content: list<Item> default property
* Any random Item can be instantiated inside the drawer and
* will be displayed underneath the actions list.
*
* Example usage:
* @code
* import org.kde.kirigami 2.2 as Kirigami
*
* Kirigami.ApplicationWindow {
* [...]
* globalDrawer: Kirigami.GlobalDrawer {
* actions: [...]
* Button {
* text: "Button"
* onClicked: //do stuff
* }
* }
* [...]
* }
* @endcode
*/
default property alias content: mainContent.data
/**
* topContent: list<Item> default property
* Items that will be instantiated inside the drawer and
* will be displayed on top of the actions list.
*
* Example usage:
* @code
* import org.kde.kirigami 2.2 as Kirigami
*
* Kirigami.ApplicationWindow {
* [...]
* globalDrawer: Kirigami.GlobalDrawer {
* actions: [...]
* topContent: [Button {
* text: "Button"
* onClicked: //do stuff
* }]
* }
* [...]
* }
* @endcode
*/
property alias topContent: topContent.data
/**
* resetMenuOnTriggered: bool
*
* On the actions menu, whenever a leaf action is triggered, the menu
* will reset to its parent.
*/
property bool resetMenuOnTriggered: true
/**
* currentSubMenu: Action
*
* Points to the action acting as a submenu
*/
readonly property Action currentSubMenu: stackView.currentItem ? stackView.currentItem.current: null
/**
* Notifies that the banner has been clicked
*/
signal bannerClicked()
/**
* Reverts the menu back to its initial state
*/
function resetMenu() {
stackView.pop(stackView.get(0, T2.StackView.DontLoad));
if (root.modal) {
root.drawerOpen = false;
}
}
rightPadding: !Settings.isMobile && mainFlickable.contentHeight > mainFlickable.height ? Units.gridUnit : Units.smallSpacing
contentItem: ScrollView {
id: scrollView
//ensure the attached property exists
Theme.inherit: true
anchors.fill: parent
implicitWidth: Math.min (Units.gridUnit * 20, root.parent.width * 0.8)
horizontalScrollBarPolicy: Qt.ScrollBarAlwaysOff
Flickable {
id: mainFlickable
contentWidth: width
contentHeight: mainColumn.Layout.minimumHeight
ColumnLayout {
id: mainColumn
width: mainFlickable.width
spacing: 0
height: Math.max(root.height, Layout.minimumHeight)
Image {
id: bannerImage
Layout.fillWidth: true
Layout.preferredWidth: title.implicitWidth
Layout.preferredHeight: bannerImageSource != "" ? 10 * Units.gridUnit : Layout.minimumHeight
Layout.minimumHeight: title.height > 0 ? title.height + Units.smallSpacing * 2 : 0
MouseArea {
anchors.fill: parent
onClicked: root.bannerClicked()
}
fillMode: Image.PreserveAspectCrop
asynchronous: true
anchors {
left: parent.left
right: parent.right
top: parent.top
}
EdgeShadow {
edge: Qt.BottomEdge
visible: bannerImageSource != ""
anchors {
left: parent.left
right: parent.right
bottom: parent.top
}
}
LinearGradient {
anchors {
left: parent.left
right: parent.right
top: parent.top
}
visible: bannerImageSource != "" && root.title != ""
height: title.height * 1.3
start: Qt.point(0, 0)
end: Qt.point(0, height)
gradient: Gradient {
GradientStop {
position: 0.0
color: Qt.rgba(0, 0, 0, 0.8)
}
GradientStop {
position: 1.0
color: "transparent"
}
}
}
RowLayout {
id: title
anchors {
left: parent.left
top: parent.top
margins: Units.smallSpacing * 2
}
Icon {
id: headingIcon
Layout.minimumWidth: Units.iconSizes.large
Layout.minimumHeight: width
visible: valid
isMask: false
//TODO: find a better way to control selective coloring on Android
enabled: !Settings.isMobile
}
Heading {
id: heading
Layout.fillWidth: true
Layout.rightMargin: heading.height
visible: text.length > 0
level: 1
color: bannerImageSource != "" ? "white" : Theme.textColor
elide: Text.ElideRight
}
}
}
ColumnLayout {
id: topContent
spacing: 0
Layout.alignment: Qt.AlignHCenter
Layout.leftMargin: root.leftPadding
Layout.rightMargin: root.rightPadding
Layout.bottomMargin: Units.smallSpacing
Layout.topMargin: root.topPadding
Layout.fillWidth: true
Layout.fillHeight: true
//NOTE: why this? just Layout.fillWidth: true doesn't seem sufficient
//as items are added only after this column creation
Layout.minimumWidth: parent.width - root.leftPadding - root.rightPadding
visible: children.length > 0 && childrenRect.height > 0
}
T2.StackView {
id: stackView
Layout.fillWidth: true
Layout.minimumHeight: currentItem ? currentItem.implicitHeight : 0
Layout.maximumHeight: Layout.minimumHeight
initialItem: menuComponent
//NOTE: it's important those are NumberAnimation and not XAnimators
// as while the animation is running the drawer may close, and
//the animator would stop when not drawing see BUG 381576
popEnter: Transition {
NumberAnimation { property: "x"; from: (stackView.mirrored ? -1 : 1) * -stackView.width; to: 0; duration: 400; easing.type: Easing.OutCubic }
}
popExit: Transition {
NumberAnimation { property: "x"; from: 0; to: (stackView.mirrored ? -1 : 1) * stackView.width; duration: 400; easing.type: Easing.OutCubic }
}
pushEnter: Transition {
NumberAnimation { property: "x"; from: (stackView.mirrored ? -1 : 1) * stackView.width; to: 0; duration: 400; easing.type: Easing.OutCubic }
}
pushExit: Transition {
NumberAnimation { property: "x"; from: 0; to: (stackView.mirrored ? -1 : 1) * -stackView.width; duration: 400; easing.type: Easing.OutCubic }
}
replaceEnter: Transition {
NumberAnimation { property: "x"; from: (stackView.mirrored ? -1 : 1) * stackView.width; to: 0; duration: 400; easing.type: Easing.OutCubic }
}
replaceExit: Transition {
NumberAnimation { property: "x"; from: 0; to: (stackView.mirrored ? -1 : 1) * -stackView.width; duration: 400; easing.type: Easing.OutCubic }
}
}
Item {
Layout.fillWidth: true
Layout.fillHeight: root.actions.length>0
Layout.minimumHeight: Units.smallSpacing
}
ColumnLayout {
id: mainContent
Layout.alignment: Qt.AlignHCenter
Layout.leftMargin: root.leftPadding
Layout.rightMargin: root.rightPadding
Layout.fillWidth: true
Layout.fillHeight: true
//NOTE: why this? just Layout.fillWidth: true doesn't seem sufficient
//as items are added only after this column creation
Layout.minimumWidth: parent.width - root.leftPadding - root.rightPadding
visible: children.length > 0
}
Item {
Layout.minimumWidth: Units.smallSpacing
Layout.minimumHeight: root.bottomPadding
}
Component {
id: menuComponent
ColumnLayout {
spacing: 0
property alias model: actionsRepeater.model
property Action current
property int level: 0
Layout.maximumHeight: Layout.minimumHeight
BasicListItem {
id: backItem
visible: level > 0
supportsMouseEvents: true
icon: (LayoutMirroring.enabled ? "go-previous-symbolic-rtl" : "go-previous-symbolic")
label: MnemonicData.richTextLabel
MnemonicData.enabled: backItem.enabled && backItem.visible
MnemonicData.controlType: MnemonicData.MenuItem
MnemonicData.label: qsTr("Back")
separatorVisible: false
onClicked: stackView.pop()
}
Shortcut {
sequence: backItem.MnemonicData.sequence
onActivated: backItem.clicked()
}
Repeater {
id: actionsRepeater
model: actions
delegate: BasicListItem {
id: listItem
supportsMouseEvents: true
checked: modelData.checked
icon: modelData.iconName
label: MnemonicData.richTextLabel
MnemonicData.enabled: listItem.enabled && listItem.visible
MnemonicData.controlType: MnemonicData.MenuItem
MnemonicData.label: modelData.text
separatorVisible: false
visible: model ? model.visible || model.visible===undefined : modelData.visible
enabled: model ? model.enabled : modelData.enabled
opacity: enabled ? 1.0 : 0.3
Icon {
Shortcut {
sequence: listItem.MnemonicData.sequence
onActivated: listItem.clicked()
}
isMask: true
anchors {
verticalCenter: contentItem.verticalCenter
right: contentItem.right
rightMargin: !Settings.isMobile && mainFlickable.contentHeight > mainFlickable.height ? Units.gridUnit : 0
}
height: Units.iconSizes.smallMedium
selected: listItem.checked || listItem.pressed
width: height
source: (LayoutMirroring.enabled ? "go-next-symbolic-rtl" : "go-next-symbolic")
visible: modelData.children!==undefined && modelData.children.length > 0
}
onClicked: {
modelData.trigger();
if (modelData.children!==undefined && modelData.children.length > 0) {
stackView.push(menuComponent, {model: modelData.children, level: level + 1, current: modelData });
} else if (root.resetMenuOnTriggered) {
root.resetMenu();
}
checked = Qt.binding(function() { return modelData.checked });
}
}
}
}
}
}
}
}
}
|