/usr/lib/x86_64-linux-gnu/qt5/qml/org/kde/okular/DocumentView.qml is in qml-module-org-kde-okular 4:17.12.3-0ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 | /*
* Copyright 2015 by Marco Martin <mart@kde.org>
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as
* published by the Free Software Foundation; either version 2,
* or (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details
*
* You should have received a copy of the GNU General Public
* License along with this program; if not, write to the
* Free Software Foundation, Inc.,
* 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
*/
import QtQuick 2.2
import QtQuick.Controls 1.2 as QtControls
import org.kde.okular 2.0
import "./private"
/**
* A touchscreen optimized view for a document
*
* It supports changing pages by a swipe gesture, pinch zoom
* and flicking to scroll around
*/
QtControls.ScrollView {
id: root
property DocumentItem document
property PageItem page: mouseArea.currPageDelegate.pageItem
signal clicked
//NOTE: on some themes it tries to set the flickable to interactive
//but we need it always non interactive as we need to manage
//dragging by ourselves
Component.onCompleted: flick.interactive = false
Flickable {
id: flick
interactive: false
onWidthChanged: resizeTimer.restart()
onHeightChanged: resizeTimer.restart()
Component.onCompleted: {
flick.contentWidth = flick.width
flick.contentHeight = flick.width / mouseArea.currPageDelegate.pageRatio
}
Connections {
target: root.document
onPathChanged: resizeTimer.restart()
}
Timer {
id: resizeTimer
interval: 250
onTriggered: {
flick.contentWidth = flick.width
flick.contentHeight = flick.width / mouseArea.currPageDelegate.pageRatio
}
}
PinchArea {
width: flick.contentWidth
height: flick.contentHeight
property real initialWidth
property real initialHeight
onPinchStarted: {
initialWidth = mouseArea.currPageDelegate.implicitWidth * mouseArea.currPageDelegate.scaleFactor
initialHeight = mouseArea.currPageDelegate.implicitHeight * mouseArea.currPageDelegate.scaleFactor
}
onPinchUpdated: {
// adjust content pos due to drag
flick.contentX += pinch.previousCenter.x - pinch.center.x
flick.contentY += pinch.previousCenter.y - pinch.center.y
// resize content
//use the scale property during pinch, for speed reasons
if (initialHeight * pinch.scale > flick.height &&
initialHeight * pinch.scale < flick.height * 3) {
mouseArea.scale = pinch.scale;
}
resizeTimer.stop();
flick.returnToBounds();
}
onPinchFinished: {
flick.resizeContent(Math.max(flick.width+1, initialWidth * mouseArea.scale), Math.max(flick.height, initialHeight * mouseArea.scale), pinch.center);
mouseArea.scale = 1;
flick.returnToBounds();
}
MouseArea {
id: mouseArea
width: parent.width
height: parent.height
property real oldMouseX
property real oldMouseY
property real startMouseX
property real startMouseY
property bool incrementing: true
property Item currPageDelegate: page1
property Item prevPageDelegate: page2
property Item nextPageDelegate: page3
onPressed: {
var pos = mapToItem(flick, mouse.x, mouse.y);
startMouseX = oldMouseX = pos.x;
startMouseY = oldMouseY = pos.y;
}
onPositionChanged: {
var pos = mapToItem(flick, mouse.x, mouse.y);
flick.contentY = Math.max(0, Math.min(flick.contentHeight - flick.height, flick.contentY - (pos.y - oldMouseY)));
if ((pos.x - oldMouseX > 0 && flick.atXBeginning) ||
(pos.x - oldMouseX < 0 && flick.atXEnd)) {
currPageDelegate.x += pos.x - oldMouseX;
mouseArea.incrementing = currPageDelegate.x <= 0;
} else {
flick.contentX = Math.max(0, Math.min(flick.contentWidth - flick.width, flick.contentX - (pos.x - oldMouseX)));
}
oldMouseX = pos.x;
oldMouseY = pos.y;
}
onReleased: {
if (root.document.currentPage > 0 &&
currPageDelegate.x > width/6) {
switchAnimation.running = true;
} else if (root.document.currentPage < document.pageCount-1 &&
currPageDelegate.x < -width/6) {
switchAnimation.running = true;
} else {
resetAnim.running = true;
}
}
onCanceled: {
resetAnim.running = true;
}
onDoubleClicked: {
flick.contentWidth = flick.width
flick.contentHeight = flick.width / mouseArea.currPageDelegate.pageRatio
}
onClicked: {
var pos = mapToItem(flick, mouse.x, mouse.y);
if (Math.abs(startMouseX - pos.x) < 20 &&
Math.abs(startMouseY - pos.y) < 20) {
root.clicked();
}
}
onWheel: {
if (wheel.modifiers & Qt.ControlModifier) {
//generate factors between 0.8 and 1.2
var factor = (((wheel.angleDelta.y / 120)+1) / 5 )+ 0.8;
var newWidth = flick.contentWidth * factor;
var newHeight = flick.contentHeight * factor;
if (newWidth < flick.width || newHeight < flick.height ||
newHeight > flick.height * 3) {
return;
}
flick.resizeContent(newWidth, newHeight, Qt.point(wheel.x, wheel.y));
flick.returnToBounds();
resizeTimer.stop();
} else {
flick.contentY = Math.min(flick.contentHeight-flick.height, Math.max(0, flick.contentY - wheel.angleDelta.y));
}
}
PageView {
id: page1
document: root.document
z: 2
}
PageView {
id: page2
document: root.document
z: 1
}
PageView {
id: page3
document: root.document
z: 0
}
Binding {
target: mouseArea.currPageDelegate
property: "pageNumber"
value: root.document.currentPage
}
Binding {
target: mouseArea.currPageDelegate
property: "visible"
value: true
}
Binding {
target: mouseArea.prevPageDelegate
property: "pageNumber"
value: root.document.currentPage - 1
}
Binding {
target: mouseArea.prevPageDelegate
property: "visible"
value: !mouseArea.incrementing && root.document.currentPage > 0
}
Binding {
target: mouseArea.nextPageDelegate
property: "pageNumber"
value: root.document.currentPage + 1
}
Binding {
target: mouseArea.nextPageDelegate
property: "visible"
value: mouseArea.incrementing && root.document.currentPage < document.pageCount-1
}
SequentialAnimation {
id: switchAnimation
ParallelAnimation {
NumberAnimation {
target: flick
properties: "contentY"
to: 0
easing.type: Easing.InQuad
//hardcoded number, we would need units from kirigami
//which cannot depend from here
duration: 250
}
NumberAnimation {
target: mouseArea.currPageDelegate
properties: "x"
to: mouseArea.incrementing ? -mouseArea.currPageDelegate.width : mouseArea.currPageDelegate.width
easing.type: Easing.InQuad
//hardcoded number, we would need units from kirigami
//which cannot depend from here
duration: 250
}
}
ScriptAction {
script: {
mouseArea.currPageDelegate.z = 0;
mouseArea.prevPageDelegate.z = 1;
mouseArea.nextPageDelegate.z = 2;
}
}
ScriptAction {
script: {
mouseArea.currPageDelegate.x = 0
var oldCur = mouseArea.currPageDelegate;
var oldPrev = mouseArea.prevPageDelegate;
var oldNext = mouseArea.nextPageDelegate;
if (mouseArea.incrementing) {
root.document.currentPage++;
mouseArea.currPageDelegate = oldNext;
mouseArea.prevPageDelegate = oldCur;
mouseArea. nextPageDelegate = oldPrev;
} else {
root.document.currentPage--;
mouseArea.currPageDelegate = oldPrev;
mouseArea.prevPageDelegate = oldCur;
mouseArea. nextPageDelegate = oldNext;
}
mouseArea.currPageDelegate.z = 2;
mouseArea.prevPageDelegate.z = 1;
mouseArea.nextPageDelegate.z = 0;
}
}
}
NumberAnimation {
id: resetAnim
target: mouseArea.currPageDelegate
properties: "x"
to: 0
easing.type: Easing.InQuad
duration: 250
}
}
}
}
}
|